[gentoo-commits] repo/gentoo:master commit in: net-proxy/mitmproxy/

[Matthew Smith]

commit:     342f79bd6f029449c4f21976fa42dc7f617e0310
Author:     Matthew Smith <matthew <AT> gentoo <DOT> org>
AuthorDate: Sat May 21 08:08:28 2022 +0000
Commit:     Matthew Smith <matthew <AT> gentoo <DOT> org>
CommitDate: Sat May 21 08:14:55 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=342f79bd

net-proxy/mitmproxy: add 8.1.0

Signed-off-by: Matthew Smith <matthew <AT> gentoo.org>

 net-proxy/mitmproxy/Manifest               |  1 +
 net-proxy/mitmproxy/mitmproxy-8.1.0.ebuild | 70 ++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/net-proxy/mitmproxy/Manifest b/net-proxy/mitmproxy/Manifest
index a0033a4e08ea..497a6258aa77 100644
--- a/net-proxy/mitmproxy/Manifest
+++ b/net-proxy/mitmproxy/Manifest
@@ -1,2 +1,3 @@
 DIST mitmproxy-7.0.4.tar.gz 27312748 BLAKE2B a23db472adab33db615b0daa93694211450e8899885dc75601d40a4964cc505437db6a106622eb8051263db23280261134937b6567482dd584eed29cc592e42b SHA512 4224b44e609f84b974b5419c6ceb576845957968c786ee437bffb5fa5df685ce0712d5ef8c402d40c568406242f44692cc7f04037fadd19ecece8b112d73b7ae
 DIST mitmproxy-8.0.0.tar.gz 27902148 BLAKE2B 73ef46fea3a668cb4cf9992e8de969c7ccac78ac84997a82aa59c841d7b5d1dfc6df5a3bd76f910f318c191421a99bb7a24fd53b50e8529968acdae1e934f322 SHA512 abb0855322ca74ef34756db860f491b49057fd8d4fb26ffafc4038e40fe30444c6736fcff7b683e32c21a2d7339ebfeeb6eaf7b9e586b965d191a59eddfe15b6
+DIST mitmproxy-8.1.0.tar.gz 27940706 BLAKE2B 6d4293f30257e88eafea21127d4f499a7734f3d450c07114f83652d73a8aaadf1523737fee96e04b1bd39d47b73263d7f62f177b5c02357b258c898ccc58a9d1 SHA512 47e0924b1fc2999cbc038295dbb43a78eef4120a31c9445aba7b1f31e90aa4d859c5e2665a429f16c5cf7a6f9f29a7d6a50bb09a1e54c2e1693714c28d5153e1

diff --git a/net-proxy/mitmproxy/mitmproxy-8.1.0.ebuild b/net-proxy/mitmproxy/mitmproxy-8.1.0.ebuild
new file mode 100644
index 000000000000..c30ef41ab876
--- /dev/null
+++ b/net-proxy/mitmproxy/mitmproxy-8.1.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10} )
+PYTHON_REQ_USE="sqlite"
+inherit distutils-r1
+
+DESCRIPTION="An interactive, SSL-capable, man-in-the-middle HTTP proxy"
+HOMEPAGE="https://mitmproxy.org/"
+SRC_URI="https://github.com/mitmproxy/mitmproxy/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=app-arch/brotli-1.0.0[python,${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.2.10[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/certifi-2015.11.20.1[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-37.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/h2-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperframe-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/kaitaistruct-0.7[${PYTHON_USEDEP}]
+	>=dev-python/ldap3-2.8[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.6.5[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.14.0[${PYTHON_USEDEP}]
+	>=dev-python/publicsuffix-2.20190205[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-22.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/pyperclip-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/ruamel-yaml-0.16[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/urwid-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/wsproto-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/zstandard-0.11.0[${PYTHON_USEDEP}]
+	dev-libs/openssl:0
+	>=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5.8[${PYTHON_USEDEP}]
+		>=dev-python/parver-0.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.17.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.9.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# loosen dependencies
+	sed -i \
+		-e '/>/s/>.*/",/g' \
+		-e '/python_requires/d' \
+		setup.py || die
+
+	# remove failing test
+	sed -i 's/test_get_version/_&/g' test/mitmproxy/test_version.py || die
+
+	distutils-r1_python_prepare_all
+}