[gentoo-commits] repo/gentoo:master commit in: dev-python/sip/

[Davide Pesavento]

commit:     3b5cdd5604f885c8b0b68be0dc00fddaa5cfe8ac
Author:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 19 19:37:06 2021 +0000
Commit:     Davide Pesavento <pesa <AT> gentoo <DOT> org>
CommitDate: Sat Jun 19 19:37:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3b5cdd56

dev-python/sip: stop installing .dist-info

Closes: https://bugs.gentoo.org/796251
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Davide Pesavento <pesa <AT> gentoo.org>

 dev-python/sip/sip-4.19.25-r1.ebuild               | 93 ++++++++++++++++++++++
 .../{sip-5.5.0-r1.ebuild => sip-5.5.0-r2.ebuild}   |  3 +-
 dev-python/sip/sip-6.1.1.ebuild                    |  3 +-
 3 files changed, 97 insertions(+), 2 deletions(-)

diff --git a/dev-python/sip/sip-4.19.25-r1.ebuild b/dev-python/sip/sip-4.19.25-r1.ebuild
new file mode 100644
index 00000000000..6c1abd79157
--- /dev/null
+++ b/dev-python/sip/sip-4.19.25-r1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit python-r1 toolchain-funcs
+
+DESCRIPTION="Python bindings generator for C/C++ libraries"
+HOMEPAGE="https://www.riverbankcomputing.com/software/sip/"
+
+MY_P=${PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${PN}/${PV}/${MY_P}.tar.gz"
+fi
+S=${WORKDIR}/${MY_P}
+
+# Sub-slot based on SIP_API_MAJOR_NR from siplib/sip.h
+SLOT="0/12"
+LICENSE="|| ( GPL-2 GPL-3 SIP )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-4.18-darwin.patch )
+
+src_prepare() {
+	# Sub-slot sanity check
+	local sub_slot=${SLOT#*/}
+	local sip_api_major_nr=$(sed -nre 's:^#define SIP_API_MAJOR_NR\s+([0-9]+):\1:p' siplib/sip.h || die)
+	if [[ ${sub_slot} != ${sip_api_major_nr} ]]; then
+		eerror
+		eerror "Ebuild sub-slot (${sub_slot}) does not match SIP_API_MAJOR_NR (${sip_api_major_nr})"
+		eerror "Please update SLOT variable as follows:"
+		eerror "    SLOT=\"${SLOT%%/*}/${sip_api_major_nr}\""
+		eerror
+		die "sub-slot sanity check failed"
+	fi
+
+	default
+}
+
+src_configure() {
+	configuration() {
+		local incdir=$(python_get_includedir)
+		local myconf=(
+			"${EPYTHON}"
+			"${S}"/configure.py
+			--sysroot="${ESYSROOT}/usr"
+			--bindir="${EPREFIX}/usr/bin"
+			--destdir="$(python_get_sitedir)"
+			--incdir="${incdir#${SYSROOT}}"
+			--no-dist-info
+			AR="$(tc-getAR) cqs"
+			CC="$(tc-getCC)"
+			CFLAGS="${CFLAGS}"
+			CFLAGS_RELEASE=
+			CXX="$(tc-getCXX)"
+			CXXFLAGS="${CXXFLAGS}"
+			CXXFLAGS_RELEASE=
+			LINK="$(tc-getCXX)"
+			LINK_SHLIB="$(tc-getCXX)"
+			LFLAGS="${LDFLAGS}"
+			LFLAGS_RELEASE=
+			RANLIB=
+			STRIP=
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+	}
+	python_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake DESTDIR="${D}" install
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir installation
+
+	einstalldocs
+	use doc && dodoc -r doc/html
+}

diff --git a/dev-python/sip/sip-5.5.0-r1.ebuild b/dev-python/sip/sip-5.5.0-r2.ebuild
similarity index 90%
rename from dev-python/sip/sip-5.5.0-r1.ebuild
rename to dev-python/sip/sip-5.5.0-r2.ebuild
index 26eee4168c3..3fef4177058 100644
--- a/dev-python/sip/sip-5.5.0-r1.ebuild
+++ b/dev-python/sip/sip-5.5.0-r2.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_COMPAT=( python3_{8..10} )
 inherit distutils-r1
 
 DESCRIPTION="Python bindings generator for C/C++ libraries"
@@ -21,6 +21,7 @@ LICENSE="|| ( GPL-2 GPL-3 SIP )"
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
 
 RDEPEND="
+	!<dev-python/sip-4.19.25-r1[${PYTHON_USEDEP}]
 	!=dev-python/sip-5.5.0-r0[${PYTHON_USEDEP}]
 	dev-python/packaging[${PYTHON_USEDEP}]
 	dev-python/toml[${PYTHON_USEDEP}]

diff --git a/dev-python/sip/sip-6.1.1.ebuild b/dev-python/sip/sip-6.1.1.ebuild
index 26eee4168c3..3fef4177058 100644
--- a/dev-python/sip/sip-6.1.1.ebuild
+++ b/dev-python/sip/sip-6.1.1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_COMPAT=( python3_{8..10} )
 inherit distutils-r1
 
 DESCRIPTION="Python bindings generator for C/C++ libraries"
@@ -21,6 +21,7 @@ LICENSE="|| ( GPL-2 GPL-3 SIP )"
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
 
 RDEPEND="
+	!<dev-python/sip-4.19.25-r1[${PYTHON_USEDEP}]
 	!=dev-python/sip-5.5.0-r0[${PYTHON_USEDEP}]
 	dev-python/packaging[${PYTHON_USEDEP}]
 	dev-python/toml[${PYTHON_USEDEP}]