[gentoo-commits] gentoo-x86 commit in media-video/mkvtoolnix: ChangeLog mkvtoolnix-6.7.0.ebuild

[Tim Harder (radhermit)]

radhermit    14/01/22 08:18:06

  Modified:             ChangeLog
  Added:                mkvtoolnix-6.7.0.ebuild
  Log:
  Version bump (bug #498369) and use wxGTK-3.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.195                media-video/mkvtoolnix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.195&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.195&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?r1=1.194&r2=1.195

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v
retrieving revision 1.194
retrieving revision 1.195
diff -u -r1.194 -r1.195
--- ChangeLog	2 Dec 2013 09:39:57 -0000	1.194
+++ ChangeLog	22 Jan 2014 08:18:06 -0000	1.195
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mkvtoolnix
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.194 2013/12/02 09:39:57 radhermit Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.195 2014/01/22 08:18:06 radhermit Exp $
+
+*mkvtoolnix-6.7.0 (22 Jan 2014)
+
+  22 Jan 2014; Tim Harder <radhermit@g.o> +mkvtoolnix-6.7.0.ebuild:
+  Version bump (bug #498369) and use wxGTK-3.
 
 *mkvtoolnix-6.6.0 (02 Dec 2013)
 



1.1                  media-video/mkvtoolnix/mkvtoolnix-6.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-6.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-6.7.0.ebuild?rev=1.1&content-type=text/plain

Index: mkvtoolnix-6.7.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-6.7.0.ebuild,v 1.1 2014/01/22 08:18:06 radhermit Exp $

EAPI=5
WX_GTK_VER="3.0"
inherit eutils multilib toolchain-funcs versionator wxwidgets multiprocessing autotools

DESCRIPTION="Tools to create, alter, and inspect Matroska files"
HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="debug pch qt4 wxwidgets"

RDEPEND="
	>=dev-libs/libebml-1.3.0:=
	>=media-libs/libmatroska-1.4.1:=
	>=dev-libs/boost-1.46.0:=
	dev-libs/pugixml
	media-libs/flac
	media-libs/libogg
	media-libs/libvorbis
	sys-apps/file
	>=sys-devel/gcc-4.6
	sys-libs/zlib
	qt4? (
		dev-qt/qtcore:4
		dev-qt/qtgui:4
	)
	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
"
DEPEND="${RDEPEND}
	dev-lang/ruby
	virtual/pkgconfig
"

pkg_pretend() {
	# http://bugs.gentoo.org/419257
	local ver=4.6
	local msg="You need at least GCC ${ver}.x for C++11 range-based 'for' and nullptr support."
	if ! version_is_at_least ${ver} $(gcc-version); then
		eerror ${msg}
		die ${msg}
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-5.8.0-system-pugixml.patch \
		"${FILESDIR}"/${PN}-5.8.0-boost-configure.patch
	eautoreconf
}

src_configure() {
	local myconf

	if use wxwidgets ; then
		need-wxwidgets unicode
		myconf="--with-wx-config=${WX_CONFIG}"
	fi

	econf \
		$(use_enable debug) \
		$(use_enable qt4 qt) \
		$(use_enable wxwidgets) \
		$(usex pch "" --disable-precompiled-headers) \
		${myconf} \
		--disable-optimization \
		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
		--with-boost="${EPREFIX}"/usr \
		--with-boost-libdir="${EPREFIX}"/usr/$(get_libdir) \
		--without-curl
}

src_compile() {
	./drake V=1 -j$(makeopts_jobs) || die
}

src_install() {
	DESTDIR="${D}" ./drake -j$(makeopts_jobs) install || die

	dodoc AUTHORS ChangeLog README TODO
	doman doc/man/*.1

	use wxwidgets && docompress -x /usr/share/doc/${PF}/guide
}