[gentoo-commits] repo/gentoo:master commit in: net-misc/etherdfs/

[Conrad Kostecki]

commit:     80bbda5bfac7dd4b6727f17b1bfbed04bbf773f1
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Mon May 25 11:17:11 2020 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Mon May 25 11:17:11 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=80bbda5b

net-misc/etherdfs: respect users LDFLAGS

Closes: https://bugs.gentoo.org/725236
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 net-misc/etherdfs/etherdfs-20180203-r1.ebuild | 60 +++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/net-misc/etherdfs/etherdfs-20180203-r1.ebuild b/net-misc/etherdfs/etherdfs-20180203-r1.ebuild
new file mode 100644
index 00000000000..d5a7bfb7698
--- /dev/null
+++ b/net-misc/etherdfs/etherdfs-20180203-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="ethersrv-linux"
+MY_PV_TSR="0.8.2"
+MY_P="${MY_PN}-${PV}"
+
+inherit systemd toolchain-funcs
+
+DESCRIPTION="An ethernet-based file system for DOS"
+HOMEPAGE="http://etherdfs.sourceforge.net/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${MY_P}.tar.xz
+	tsr? ( mirror://sourceforge/${PN}/v${MY_PV_TSR}/${PN}.zip -> ${P}.zip )
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="tsr"
+
+BDEPEND="tsr? ( app-arch/unzip )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}/${P}-makefile.patch" )
+
+DOCS=( "ethersrv-linux.txt" "history.txt" )
+
+src_prepare() {
+	default
+
+	# Respect users LDFLAGS
+	sed -e 's/$(CFLAGS)/& $(LDFLAGS)/' -i Makefile || die
+}
+
+src_compile() {
+	tc-export CC
+
+	default
+}
+
+src_install() {
+	dobin ethersrv-linux
+
+	if use tsr; then
+		insinto /usr/share/etherdfs
+		newins ../ETHERDFS.EXE etherdfs.exe
+
+		DOCS+=( "../ETHERDFS.TXT" "../HISTORY.TXT" )
+	fi
+
+	newinitd "${FILESDIR}"/etherdfs.initd etherdfs
+	newconfd "${FILESDIR}"/etherdfs.confd etherdfs
+	systemd_dounit "${FILESDIR}"/etherdfs.service
+
+	einstalldocs
+}