[gentoo-commits] repo/gentoo:master commit in: net-im/pidgin/

[Lars Wendler]

commit:     29e998c03ce3404f327da66ba5a23b3e0b2c7672
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 30 06:31:32 2021 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Fri Apr 30 06:31:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=29e998c0

net-im/pidgin: Removed old

Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 net-im/pidgin/Manifest             |   1 -
 net-im/pidgin/pidgin-2.14.2.ebuild | 295 -------------------------------------
 2 files changed, 296 deletions(-)

diff --git a/net-im/pidgin/Manifest b/net-im/pidgin/Manifest
index af195517eab..298dd3907ee 100644
--- a/net-im/pidgin/Manifest
+++ b/net-im/pidgin/Manifest
@@ -1,6 +1,5 @@
 DIST pidgin-2.10.9-irc_join_sleep.patch 534 BLAKE2B 0215cebb93993e19e700e4d4974351ab5e9a00ea094775076d8f439569b34c0ec2faaed360965867df58bc42677516983ce11a2601dd322c1bdf2f288253a5b8 SHA512 8de0d6f05e48cd5a3e894576e06c7fb82e4bfc778cce8bb179fa22e2a05f5c2390a0e4c5b626ee4b910a18eab170d8f4be200f435ce408a86575af99e51e3bdf
 DIST pidgin-2.14.1.tar.bz2 8849275 BLAKE2B 27cd58a79f36c0176147c2e5bac7c4c18ec74c446c556e2326465c3607a95c3a58c1bdbbf9b4fb9741783ae982a6ce8fe0556ccff5b1608c9bba98626560412c SHA512 6ce5c58f32fa680d7f67e37a42b0f77c8253018cee21df2895d52166d9eb6ecaf0458b1610adbd46f337d00e75933db7578c2f9808654bd22838ba5db0a13030
-DIST pidgin-2.14.2.tar.bz2 8933924 BLAKE2B 8ca40cb9398f9f2e55b3dbb6aff12a55bfc27974c959476af8a7c779fa46df616e91474512b632658b280bf520eb43c9ddf62270b1553e17566b5c6a173bc88f SHA512 f1048644f39c37e210560f876412c0c63039c6045ba8e9477a00f05841078f6c9f6f97806e0c7824a8e60d2477dc835670920f5df58c5b434be76e6603e0005c
 DIST pidgin-2.14.3.tar.bz2 8688849 BLAKE2B 5d1f28ca5c452b13d2a6d6ab0c9101f14da3b5a291a838dab4b7cda99c76b3e411414b186ae493f08bd9764c65eab4b41eb9a45d340fe885f8bf9bf092911d43 SHA512 70f426900ce76afcdad76bcd06ebc320f562fe4089ec87c639d8d0d90823077f5e815932b62c3ff3da6270b3acfde3c8222d9b8c5cbb211421239c9dcc69b909
 DIST pidgin-2.14.4.tar.bz2 8724096 BLAKE2B 674b8cc306b5179c95a546f13e7ec7c2a13a22ff2ab502460435e2449e1a9fdb9e33baf2d8b81867a40251e3fe004dce5a0a371deab70587c694a10c6419f89d SHA512 78550b7c4678242861bc0b0a3c32ab03c9fd6e4f509a9b83f872f2e201fe69617c8407d4cc90205e74598f1b8fdddfeddc8f59b47179524a7af7a241eaf1fa0b
 DIST pidgin-eds-3.6.patch.bz2 2352 BLAKE2B 1d69dc55f43b9efe5d5278a017642702d67a297fe2587467ec0fdca7f9888e26640efe9ac2a18f77ae9c523bf125a2cec6d0bf621f0b2b16f55d30df1bf470df SHA512 a0195679ab55ed9c7ea18ace6dbf0fc994698f1f4eea9d8335dfdcdcd6a68975c0191bd22f150bf5a9a0a691ce7e9e73d79598e1e8be541efa1d9824a633d877

diff --git a/net-im/pidgin/pidgin-2.14.2.ebuild b/net-im/pidgin/pidgin-2.14.2.ebuild
deleted file mode 100644
index 4f3358fca71..00000000000
--- a/net-im/pidgin/pidgin-2.14.2.ebuild
+++ /dev/null
@@ -1,295 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-GENTOO_DEPEND_ON_PERL=no
-PYTHON_COMPAT=( python3_{7..9} )
-
-inherit autotools gnome2-utils flag-o-matic toolchain-funcs multilib perl-module python-single-r1 xdg
-
-DESCRIPTION="GTK Instant Messenger client"
-HOMEPAGE="https://pidgin.im/"
-SRC_URI="
-	mirror://sourceforge/${PN}/${P}.tar.bz2
-	https://dev.gentoo.org/~polynomial-c/${PN}-eds-3.6.patch.bz2
-	https://gist.githubusercontent.com/imcleod/77f38d11af11b2413ada/raw/46e9d6cb4d2f839832dad2d697bb141a88028e04/pidgin-irc-join-sleep.patch -> ${PN}-2.10.9-irc_join_sleep.patch"
-
-LICENSE="GPL-2"
-SLOT="0/2" # libpurple version
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
-IUSE="aqua dbus debug doc eds gadu gnutls groupwise +gstreamer +gtk idn
-meanwhile ncurses networkmanager nls perl pie prediction python sasl spell tcl
-tk +xscreensaver zephyr zeroconf"
-
-# dbus requires python to generate C code for dbus bindings (thus DEPEND only).
-# finch uses libgnt that links with libpython - {R,}DEPEND. But still there is
-# no way to build dbus and avoid libgnt linkage with python. If you want this
-# send patch upstream.
-# purple-url-handler and purple-remote require dbus-python thus in reality we
-# rdepend on python if dbus enabled. But it is possible to separate this dep.
-RDEPEND="
-	>=dev-libs/glib-2.16
-	>=dev-libs/libxml2-2.6.18
-	ncurses? (
-		>=dev-libs/libgnt-$(ver_cut 1-2)
-		sys-libs/ncurses:0=[unicode]
-		dbus? ( ${PYTHON_DEPS} )
-		python? ( ${PYTHON_DEPS} )
-	)
-	gtk? (
-		>=x11-libs/gtk+-2.10:2[aqua=]
-		x11-libs/libSM
-		>=x11-libs/pango-1.4.0
-		xscreensaver? ( x11-libs/libXScrnSaver )
-		spell? ( >=app-text/gtkspell-2.0.2:2 )
-		eds? ( >=gnome-extra/evolution-data-server-3.6:= )
-		prediction? ( >=dev-db/sqlite-3.3:3 )
-	)
-	gstreamer? (
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-		>=net-libs/farstream-0.2.7:0.2
-	)
-	zeroconf? ( net-dns/avahi[dbus] )
-	dbus? (
-		>=dev-libs/dbus-glib-0.71
-		>=sys-apps/dbus-0.90
-		$(python_gen_cond_dep '
-			dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
-		')
-	)
-	perl? ( >=dev-lang/perl-5.16:= )
-	gadu? ( >=net-libs/libgadu-1.11.0 )
-	gnutls? ( net-libs/gnutls:= )
-	!gnutls? (
-		dev-libs/nspr
-		dev-libs/nss
-	)
-	meanwhile? ( net-libs/meanwhile )
-	tcl? ( dev-lang/tcl:0= )
-	tk? ( dev-lang/tk:0= )
-	sasl? ( dev-libs/cyrus-sasl:2 )
-	networkmanager? ( net-misc/networkmanager )
-	idn? ( net-dns/libidn:= )
-"
-
-# We want nls in case gtk is enabled, bug #
-NLS_DEPEND=">=dev-util/intltool-0.41.1 sys-devel/gettext"
-
-DEPEND="${RDEPEND}
-	gtk? (
-		x11-base/xorg-proto
-		${NLS_DEPEND}
-	)
-	dbus? ( ${PYTHON_DEPS} )
-"
-BDEPEND="
-	dev-lang/perl
-	dev-perl/XML-Parser
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen )
-	!gtk? ( nls? ( ${NLS_DEPEND} ) )
-"
-
-DOCS=( AUTHORS HACKING NEWS README ChangeLog )
-
-REQUIRED_USE="
-	dbus? ( ${PYTHON_REQUIRED_USE} )
-	networkmanager? ( dbus )
-	python? ( ${PYTHON_REQUIRED_USE} )
-"
-
-# Enable Default protocols
-DYNAMIC_PRPLS="irc,jabber,oscar,simple"
-
-# List of plugins
-#   app-accessibility/pidgin-festival
-#   net-im/librvp
-#   x11-plugins/guifications
-#	x11-plugins/msn-pecan
-#   x11-plugins/pidgin-encryption
-#   x11-plugins/pidgin-extprefs
-#   x11-plugins/pidgin-hotkeys
-#   x11-plugins/pidgin-latex
-#   x11-plugins/pidgintex
-#   x11-plugins/pidgin-libnotify
-#	x11-plugins/pidgin-mbpurple
-#	x11-plugins/pidgin-bot-sentry
-#   x11-plugins/pidgin-otr
-#   x11-plugins/pidgin-rhythmbox
-#   x11-plugins/purple-plugin_pack
-#   x11-themes/pidgin-smileys
-#	x11-plugins/pidgin-knotify
-# Plugins in Sunrise:
-#	x11-plugins/pidgin-audacious-remote
-#	x11-plugins/pidgin-autoanswer
-#	x11-plugins/pidgin-birthday-reminder
-#	x11-plugins/pidgin-blinklight
-#	x11-plugins/pidgin-convreverse
-#	x11-plugins/pidgin-embeddedvideo
-#	x11-plugins/pidgin-extended-blist-sort
-#	x11-plugins/pidgin-gfire
-#	x11-plugins/pidgin-lastfm
-#	x11-plugins/pidgin-sendscreenshot
-#	x11-plugins/pidgimpd
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2.14.0-gold.patch"
-	"${WORKDIR}/${PN}-eds-3.6.patch"
-	"${FILESDIR}/${PN}-2.10.9-fix-gtkmedia.patch"
-	"${FILESDIR}/${PN}-2.10.10-eds-3.6-configure.ac.patch"
-	"${FILESDIR}/${PN}-2.10.11-tinfo.patch"
-	"${DISTDIR}/${PN}-2.10.9-irc_join_sleep.patch" # 577286
-	"${FILESDIR}/${PN}-2.13.0-disable-one-jid-test.patch" # 593338
-	"${FILESDIR}/${PN}-2.13.0-metainfo.patch"
-)
-
-pkg_pretend() {
-	if ! use gtk && ! use ncurses ; then
-		elog "You did not pick the ncurses or gtk use flags, only libpurple"
-		elog "will be built."
-	fi
-
-	# dbus is enabled, no way to disable linkage with python => python is enabled
-	#REQUIRED_USE="gtk? ( nls ) dbus? ( python )"
-	if use gtk && ! use nls ; then
-		ewarn "gtk build => nls is enabled!"
-	fi
-	if use dbus && ! use python ; then
-		elog "dbus is enabled, no way to disable linkage with python => python is enabled"
-	fi
-}
-
-pkg_setup() {
-	if use python || use dbus ; then
-		python-single-r1_pkg_setup
-	fi
-}
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	# Stabilize things, for your own good
-	strip-flags
-	replace-flags -O? -O2
-	use pie && append-cflags -fPIE -pie
-
-	use gadu 	&& DYNAMIC_PRPLS+=",gg"
-	use groupwise 	&& DYNAMIC_PRPLS+=",novell"
-	use meanwhile 	&& DYNAMIC_PRPLS+=",sametime"
-	use zephyr 	&& DYNAMIC_PRPLS+=",zephyr"
-	use zeroconf 	&& DYNAMIC_PRPLS+=",bonjour"
-
-	local myconf=(
-		--disable-mono
-		--disable-static
-		--with-dynamic-prpls="${DYNAMIC_PRPLS}"
-		--with-system-ssl-certs="${EPREFIX}/etc/ssl/certs/"
-		--x-includes="${EPREFIX}"/usr/include/X11
-		$(use_enable ncurses consoleui)
-		$(use_enable gtk gtkui)
-		$(use_enable gtk sm)
-		$(usex gtk '--enable-nls' "$(use_enable nls)")
-		$(use gtk && use_enable xscreensaver screensaver)
-		$(use gtk && use_enable prediction cap)
-		$(use gtk && use_enable eds gevolution)
-		$(use gtk && use_enable spell gtkspell)
-		$(use_enable perl)
-		$(use_enable tk)
-		$(use_enable tcl)
-		$(use_enable debug)
-		$(use_enable dbus)
-		$(use_enable meanwhile)
-		$(use_enable gstreamer)
-		$(use_with gstreamer gstreamer 1.0)
-		$(use_enable gstreamer farstream)
-		$(use_enable gstreamer vv)
-		$(use_enable sasl cyrus-sasl )
-		$(use_enable doc doxygen)
-		$(use_enable networkmanager nm)
-		$(use_enable zeroconf avahi)
-		$(use_enable idn)
-	)
-
-	if use gnutls; then
-		einfo "Disabling NSS, using GnuTLS"
-		myconf+=(
-			--enable-nss=no
-			--enable-gnutls=yes
-			--with-gnutls-includes="${EPREFIX}/usr/include/gnutls"
-			--with-gnutls-libs="${EPREFIX}/usr/$(get_libdir)"
-		)
-	else
-		einfo "Disabling GnuTLS, using NSS"
-		myconf+=(
-			--enable-gnutls=no
-			--enable-nss=yes
-		)
-	fi
-
-	if use dbus || { use ncurses && use python ; } ; then
-		myconf+=( --with-python3=${PYTHON} )
-	else
-		myconf+=( --without-python3 )
-	fi
-
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	# setting this here because gnome2.eclass is not EAPI-7 ready
-	export GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL="1"
-	default
-
-	if use gtk ; then
-		# Fix tray paths for e16 (x11-wm/enlightenment) and other
-		# implementations that are not compliant with new hicolor theme yet, #323355
-		local d f pixmapdir
-		for d in 16 22 32 48 ; do
-			pixmapdir="${ED}/usr/share/pixmaps/pidgin/tray/hicolor/${d}x${d}/actions"
-			mkdir "${pixmapdir}" || die
-			pushd "${pixmapdir}" >/dev/null || die
-			for f in ../status/*; do
-				ln -s ${f} || die
-			done
-			popd >/dev/null || die
-		done
-	fi
-	use perl && perl_delete_localpod
-
-	if use python && use dbus ; then
-		python_fix_shebang "${ED}"
-		python_optimize
-	fi
-
-	dodoc ${DOCS[@]} finch/plugins/pietray.py
-	docompress -x /usr/share/doc/${PF}/pietray.py
-
-	find "${ED}" -type f -name "*.la" -delete || die
-}
-
-src_test() {
-	# make default build logs slightly more useful
-	emake check VERBOSE=1
-}
-
-pkg_preinst() {
-	gnome2_gconf_savelist
-	xdg_pkg_preinst
-}
-
-pkg_postinst() {
-	gnome2_gconf_install
-	gnome2_schemas_update
-	xdg_pkg_postinst
-}
-
-pkg_postrm() {
-	gnome2_gconf_uninstall
-	gnome2_schemas_update
-	xdg_pkg_postrm
-}