[gentoo-commits] gentoo-x86 commit in app-mobilephone/obexftp: ChangeLog obexftp-0.23.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    09/02/28 00:02:28

  Modified:             ChangeLog
  Added:                obexftp-0.23.ebuild
  Log:
  Version bump, works perfectly with bluez-4.31.
  (Portage version: 2.1.6.7/cvs/Linux x86_64)

Revision  Changes    Path
1.45                 app-mobilephone/obexftp/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	11 Dec 2008 20:25:53 -0000	1.44
+++ ChangeLog	28 Feb 2009 00:02:28 -0000	1.45
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/obexftp
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.44 2008/12/11 20:25:53 mrness Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.45 2009/02/28 00:02:28 dev-zero Exp $
+
+*obexftp-0.23 (28 Feb 2009)
+
+  28 Feb 2009; Tiziano Müller <dev-zero@g.o> +obexftp-0.23.ebuild:
+  Version bump, works perfectly with bluez-4.31.
 
   11 Dec 2008; Alin Năstac <mrness@g.o>
   +files/obexftp-0.22-bluetooth.patch, -obexftp-0.22_rc9.ebuild,



1.1                  app-mobilephone/obexftp/obexftp-0.23.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/obexftp-0.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/obexftp/obexftp-0.23.ebuild?rev=1.1&content-type=text/plain

Index: obexftp-0.23.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/obexftp-0.23.ebuild,v 1.1 2009/02/28 00:02:28 dev-zero Exp $

EAPI="2"

inherit eutils perl-module flag-o-matic python

DESCRIPTION="File transfer over OBEX for mobile phones"
HOMEPAGE="http://dev.zuckschwerdt.org/openobex/wiki/ObexFtp"
SRC_URI="mirror://sourceforge/openobex/${P}.tar.bz2"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="bluetooth debug perl python ruby swig tcl"

RDEPEND="dev-libs/openobex
	bluetooth? ( net-wireless/bluez )
	perl? ( dev-lang/perl )
	python? ( >=dev-lang/python-2.4.4 )
	ruby? ( dev-lang/ruby )
	tcl? ( dev-lang/tcl )"
DEPEND="${RDEPEND}
	swig? ( dev-lang/swig )
	dev-util/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.22-ruby-libpath.patch"
}

src_configure() {
	# do not byte-compile python module
	if use python; then
		sed -i \
			-e 's/\(setup.py install\)/\1 --no-compile/' \
			swig/python/Makefile.in || die "sed failed"
	fi

	if use debug ; then
		strip-flags
		append-flags "-g -DOBEXFTP_DEBUG=5"
	fi

	econf \
		$(use_enable bluetooth) \
		$(use_enable swig) \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable tcl) \
		$(use_enable ruby) || die "econf failed"
}

src_install() {
	# -j1 because "make -fMakefile.ruby install" fails
	# upstream added -j1 to that command so it should be removed
	# from here in the next version bump
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
	dohtml doc/*.html

	# Install examples
	insinto /usr/share/doc/${PF}/examples
	doins examples/*.c
	use perl && doins examples/*.pl
	use python && doins examples/*.py
	use ruby && doins examples/*.rb
	use tcl && doins examples/*.tcl

	use perl && fixlocalpod
}

pkg_postrm() {
	use perl && perl-module_pkg_postrm
	use python && python_mod_cleanup
}

pkg_postinst() {
	use perl && perl-module_pkg_postinst
	use python && {
		python_version
		python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/${PN}
	}
}