[gentoo-commits] repo/gentoo:master commit in: dev-python/nbdime/

[David Seifert]

commit:     0b7f0a0b8a96e97da13fbc9970b2c08613edd5a5
Author:     Marius Brehler <marbre <AT> linux <DOT> sungazer <DOT> de>
AuthorDate: Wed Mar  8 08:52:25 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Thu Mar  9 20:43:38 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0b7f0a0b

dev-python/nbdime: Version bump to 0.2.0 + add doc useflag

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/4159

 dev-python/nbdime/Manifest            |  1 +
 dev-python/nbdime/nbdime-0.2.0.ebuild | 66 +++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/dev-python/nbdime/Manifest b/dev-python/nbdime/Manifest
index 8c70c51b733..fe39dbaf96d 100644
--- a/dev-python/nbdime/Manifest
+++ b/dev-python/nbdime/Manifest
@@ -1,2 +1,3 @@
 DIST nbdime-0.1.0.tar.gz 3849944 SHA256 5af53ccf5b265546e61fbc096c4dd8122855b2aa02f8b60a99eeee01a8e33043 SHA512 e110e2e3e8b9bfbaafd26e6558ec863eb0a23f3b7a67482e497c4883fa2151ae058582b975aca90392bd2314f5e32ce3e7316db9c2c37e44c336a9fcf88176c8 WHIRLPOOL 074060d867b259b461514e84b21c0f7eb20ff2f787055e03971fd18d0aa1ba56596b15017354c5becd3f1022b5557ec740d4815d4f820af8b54349273ee8b9a4
 DIST nbdime-0.1.2.tar.gz 3864624 SHA256 4adb8ff052a7c778fb5f00872172a3790504de392eb7f23b6ae96b8a8165a695 SHA512 9f704645ef1e64b0da260841769068db6f6aba37f30b3c6506a1876af1276acb452ed78f66b9e6d7029f06ed9fabf01a1484b4b86055f27a451d623a7eda90cf WHIRLPOOL 570891b1f9067abe88009f7160f509f8cba6345742df3d0549a486b8669f84c097487d25855f76ddea3ee8d786131145467ea20bedf3d54bca30a137977b7978
+DIST nbdime-0.2.0.tar.gz 4139079 SHA256 0915df792ab82fe8c3d3c892123bae0d5fb0180bafa150e2fe4dd327ff7e3c82 SHA512 c156b706e1d6cc7885f987d746e91d7f0c2fa48885339fd79e778643382ab45e2e52565f45cc73b9a305c6f5177339e875f53ae46d73578443880a4c7522976d WHIRLPOOL 0a95351be0efe993ffee5f677b62488deade3895400350c04f4743eae4bbb4e113f6fc2295ef777ecabdc9c3e27023c1d6dec4b83dc48c119ca95ea2417f9319

diff --git a/dev-python/nbdime/nbdime-0.2.0.ebuild b/dev-python/nbdime/nbdime-0.2.0.ebuild
new file mode 100644
index 00000000000..a5ed4d14c2a
--- /dev/null
+++ b/dev-python/nbdime/nbdime-0.2.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Diff and merge of Jupyter Notebooks"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test webtools"
+
+RDEPEND="
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+	webtools? ( net-libs/nodejs[npm] )
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/recommonmark[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+	"
+# The package recommonmark is required to build the docs, not in portage yet.
+# Furthermore, backports.shutil_which is required for python2_7.
+
+python_configure_all() {
+	if ! use webtools; then
+		mydistutilsargs=( --skip-npm )
+	fi
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+python_test() {
+	# user.email and user.name are not configured in the sandbox.
+	git config --global user.email "you@×××××××.com" || die
+	git config --global user.name "Your Name" || die
+
+	distutils_install_for_testing
+
+	py.test -l || die
+}