[gentoo-commits] gentoo-x86 commit in net-fs/cvmfs: cvmfs-2.1.20.0_p05.ebuild cvmfs-9999.ebuild cvmfs-2.1.19.ebuild ChangeLog cvmfs-2.1.14.ebuild cvmfs-2.1.17.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    15/07/31 20:09:57

  Modified:             cvmfs-9999.ebuild cvmfs-2.1.19.ebuild ChangeLog
  Added:                cvmfs-2.1.20.0_p05.ebuild
  Removed:              cvmfs-2.1.14.ebuild cvmfs-2.1.17.ebuild
  Log:
  Version bump, add geoip dependencies
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.4                  net-fs/cvmfs/cvmfs-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild?r1=1.3&r2=1.4

Index: cvmfs-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- cvmfs-9999.ebuild	5 Feb 2014 18:00:36 -0000	1.3
+++ cvmfs-9999.ebuild	31 Jul 2015 20:09:57 -0000	1.4
@@ -1,40 +1,40 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild,v 1.3 2014/02/05 18:00:36 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild,v 1.4 2015/07/31 20:09:57 bicatali Exp $
 
 EAPI=5
 
-#if LIVE
 EGIT_REPO_URI="https://github.com/cvmfs/cvmfs.git"
 EGIT_BRANCH="devel"
-inherit git-r3
-#endif
 
-inherit cmake-utils
+inherit git-r3 cmake-utils
 
 DESCRIPTION="HTTP read-only file system for distributing software"
 HOMEPAGE="http://cernvm.cern.ch/portal/filesystem"
-SRC_URI="https://ecsft.cern.ch/dist/${PN}/${P}/${P}.tar.gz"
+
+SRC_URI=
+KEYWORDS=
 
 LICENSE="BSD"
 SLOT="0"
 
-KEYWORDS="~amd64 ~x86"
 IUSE="+client debug doc test server"
 
 CDEPEND="
 	dev-cpp/gtest
-	dev-db/sqlite:3
-	dev-libs/openssl
-	net-libs/pacparser
-	net-misc/curl[adns]
+	dev-db/sqlite:3=
+	dev-libs/openssl:0
+	net-libs/pacparser:0=
+	net-misc/curl:0=[adns]
 	sys-apps/attr
-	sys-libs/zlib
+	sys-libs/zlib:0=
 	client? (
-		dev-cpp/sparsehash
-		dev-libs/leveldb
-		sys-fs/fuse )
-	server? ( >=dev-cpp/tbb-4.2 )"
+		>=dev-cpp/sparsehash-1.12
+		dev-libs/leveldb:0=
+		sys-fs/fuse:0= )
+	server? (
+		>=dev-python/geoip-python-1.3.1
+		>=dev-cpp/tbb-4.2:0= )"
 
 RDEPEND="${CDEPEND}
 	client? ( net-fs/autofs )
@@ -44,11 +44,6 @@
 	virtual/pkgconfig
 	doc? ( app-doc/doxygen[dot] )"
 
-#if LIVE
-KEYWORDS=
-SRC_URI=
-#endif
-
 src_prepare() {
 	sed -i -e 's/COPYING//' CMakeLists.txt || die
 	rm bootstrap.sh || die
@@ -65,15 +60,15 @@
 			-e 's/ar/$(AR)/' \
 			-e 's/ranlib/$(RANLIB)/' \
 			externals/vjson/src/Makefile || die
-		mkdir -p "${S}_build"/externals/build_vjson
-		cp externals/vjson/src/* "${S}_build"/externals/build_vjson/ || die
+		mkdir -p "${WORKDIR}/${P}_build"/externals/build_vjson
+		cp externals/vjson/src/* "${WORKDIR}/${P}_build"/externals/build_vjson/ || die
 	fi
-
 	cmake-utils_src_prepare
 }
 
 src_configure() {
 	local mycmakeargs=(
+		-DGEOIP_BUILTIN=OFF
 		-DGOOGLETEST_BUILTIN=OFF
 		-DLEVELDB_BUILTIN=OFF
 		-DLIBCURL_BUILTIN=OFF



1.2                  net-fs/cvmfs/cvmfs-2.1.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.19.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.19.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.19.ebuild?r1=1.1&r2=1.2

Index: cvmfs-2.1.19.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.19.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- cvmfs-2.1.19.ebuild	30 Apr 2014 16:38:54 -0000	1.1
+++ cvmfs-2.1.19.ebuild	31 Jul 2015 20:09:57 -0000	1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.19.ebuild,v 1.1 2014/04/30 16:38:54 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.19.ebuild,v 1.2 2015/07/31 20:09:57 bicatali Exp $
 
 EAPI=5
 
@@ -19,7 +19,7 @@
 CDEPEND="
 	dev-cpp/gtest
 	dev-db/sqlite:3=
-	dev-libs/openssl
+	dev-libs/openssl:0
 	net-libs/pacparser:0=
 	net-misc/curl:0=[adns]
 	sys-apps/attr



1.12                 net-fs/cvmfs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/cvmfs/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	30 Apr 2014 16:38:54 -0000	1.11
+++ ChangeLog	31 Jul 2015 20:09:57 -0000	1.12
@@ -1,6 +1,16 @@
 # ChangeLog for net-fs/cvmfs
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/ChangeLog,v 1.11 2014/04/30 16:38:54 bicatali Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/ChangeLog,v 1.12 2015/07/31 20:09:57 bicatali Exp $
+
+*cvmfs-2.1.20.0_p05 (31 Jul 2015)
+
+  31 Jul 2015; Sébastien Fabbro <bicatali@g.o>
+  +cvmfs-2.1.20.0_p05.ebuild, +files/cvmfs-2.1.20.0_p05-cares-underlink.patch,
+  +files/cvmfs-2.1.20.0_p05-geoip-missing-cmake.patch, -cvmfs-2.1.14.ebuild,
+  -cvmfs-2.1.17.ebuild, -files/FindCARes.cmake, -files/Findleveldb.cmake,
+  -files/cvmfs-2.1.10-no-config.patch, -files/cvmfs-2.1.10-openrc.patch,
+  cvmfs-2.1.19.ebuild, cvmfs-9999.ebuild:
+  Version bump, add geoip dependencies
 
 *cvmfs-2.1.19 (30 Apr 2014)
 



1.1                  net-fs/cvmfs/cvmfs-2.1.20.0_p05.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.20.0_p05.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.20.0_p05.ebuild?rev=1.1&content-type=text/plain

Index: cvmfs-2.1.20.0_p05.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.20.0_p05.ebuild,v 1.1 2015/07/31 20:09:57 bicatali Exp $

EAPI=5

inherit cmake-utils

MYP=${PN}-${PV/_p/-fix}

DESCRIPTION="HTTP read-only file system for distributing software"
HOMEPAGE="http://cernvm.cern.ch/portal/filesystem"
SRC_URI="https://github.com/cvmfs/${PN}/archive/${MYP}.tar.gz"

LICENSE="BSD"
SLOT="0"

KEYWORDS="~amd64 ~x86"
IUSE="+client debug doc test server"

CDEPEND="
	dev-cpp/gtest
	dev-db/sqlite:3=
	dev-libs/openssl:0
	net-libs/pacparser:0=
	net-misc/curl:0=[adns]
	sys-apps/attr
	sys-libs/zlib:0=
	client? (
		>=dev-cpp/sparsehash-1.12
		dev-libs/leveldb:0=
		sys-fs/fuse:0= )
	server? (
		>=dev-python/geoip-python-1.3.1
		>=dev-cpp/tbb-4.2:0= )"

RDEPEND="${CDEPEND}
	client? ( net-fs/autofs )"
#	server? ( www-servers/apache[ssl] )"

DEPEND="${CDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen[dot] )"

S="${WORKDIR}/${PN}-${MYP}"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-geoip-missing-cmake.patch \
		"${FILESDIR}"/${P}-cares-underlink.patch
	# gentoo stuff
	sed -i -e 's/COPYING//' CMakeLists.txt || die
	rm bootstrap.sh || die
	sed -i \
		-e "s:cvmfs-\${CernVM-FS_VERSION_STRING}:${PF}:" \
		CMakeLists.txt || die

	# hack for bundled vjson
	# vjson not worth unbundling, already upstream obsolete
	# upstream replaced by gason with a new api
	if use server; then
		sed -i \
			-e 's/g++/$(CXX)/g' \
			-e 's/-O2/$(CXXFLAGS)/g' \
			-e 's/ar/$(AR)/' \
			-e 's/ranlib/$(RANLIB)/' \
			externals/vjson/src/Makefile || die
		mkdir -p "${WORKDIR}/${P}_build"/externals/build_vjson
		cp externals/vjson/src/* "${WORKDIR}/${P}_build"/externals/build_vjson/ || die
	fi
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DGEOIP_BUILTIN=OFF
		-DGOOGLETEST_BUILTIN=OFF
		-DLEVELDB_BUILTIN=OFF
		-DLIBCURL_BUILTIN=OFF
		-DPACPARSER_BUILTIN=OFF
		-DSPARSEHASH_BUILTIN=OFF
		-DSQLITE3_BUILTIN=OFF
		-DTBB_PRIVATE_LIB=OFF
		-DZLIB_BUILTIN=OFF
		$(cmake-utils_use debug BUILD_SERVER_DEBUG)
		$(cmake-utils_use server BUILD_SERVER)
		$(cmake-utils_use client BUILD_CVMFS)
		$(cmake-utils_use client BUILD_LIBCVMFS)
		$(cmake-utils_use client INSTALL_MOUNT_SCRIPTS)
		$(cmake-utils_use test BUILD_UNITTESTS)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc; then
		cd doc
		doxygen cvmfs.doxy || die
	fi
}

src_install() {
	cmake-utils_src_install
	use doc && dohtml -r doc/html/*
}

pkg_config() {
	if use client; then
		einfo "Setting up CernVM-FS client"
		cvmfs_config setup
		einfo "Now edit ${EROOT%/}/etc/cvmfs/default.local and run"
		einfo "  ${EROOT%/}/usr/init.d/autofs restart"
	fi
}