[gentoo-commits] gentoo-x86 commit in net-libs/qmf: qmf-4.0.2.ebuild ChangeLog

[Davide Pesavento (pesa)]

pesa        13/07/01 10:12:05

  Modified:             ChangeLog
  Added:                qmf-4.0.2.ebuild
  Log:
  Version bump. Added icu and zlib USE flags.
  
  (Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.7                  net-libs/qmf/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/qmf/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/qmf/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/qmf/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/qmf/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	2 Mar 2013 22:57:44 -0000	1.6
+++ ChangeLog	1 Jul 2013 10:12:04 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/qmf
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/qmf/ChangeLog,v 1.6 2013/03/02 22:57:44 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/qmf/ChangeLog,v 1.7 2013/07/01 10:12:04 pesa Exp $
+
+*qmf-4.0.2 (01 Jul 2013)
+
+  01 Jul 2013; Davide Pesavento <pesa@g.o> +files/qmf-4.0.2-tests.patch,
+  +qmf-4.0.2.ebuild:
+  Version bump. Added icu and zlib USE flags.
 
   02 Mar 2013; Markos Chandras <hwoarang@g.o> qmf-2.0_p201209-r1.ebuild:
   Move Qt dependencies to the new category



1.1                  net-libs/qmf/qmf-4.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/qmf/qmf-4.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/qmf/qmf-4.0.2.ebuild?rev=1.1&content-type=text/plain

Index: qmf-4.0.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/qmf/qmf-4.0.2.ebuild,v 1.1 2013/07/01 10:12:04 pesa Exp $

EAPI=5

inherit qt4-r2

if [[ ${PV} == *9999* ]]; then
	inherit git-2
	EGIT_REPO_URI="git://gitorious.org/qt-labs/messagingframework.git
		https://git.gitorious.org/qt-labs/messagingframework.git"
else
	SRC_URI="http://dev.gentoo.org/~pesa/distfiles/${P}.tar.gz"
	S=${WORKDIR}/qt-labs-messagingframework
fi

DESCRIPTION="The Qt Messaging Framework"
HOMEPAGE="http://qt.gitorious.org/qt-labs/messagingframework"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc examples icu test zlib"

RDEPEND="
	>=dev-qt/qtcore-4.8:4
	>=dev-qt/qtgui-4.8:4
	>=dev-qt/qtsql-4.8:4
	examples? ( >=dev-qt/qtwebkit-4.8:4 )
	icu? ( dev-libs/icu:= )
	zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	test? ( >=dev-qt/qttest-4.8:4 )
	!!<net-libs/qmf-2.0_p201209
"

DOCS=(CHANGES)
PATCHES=(
	"${FILESDIR}/${PN}-4.0.2-tests.patch"
)

src_prepare() {
	qt4-r2_src_prepare

	sed -i	-e '/benchmarks/d' \
		-e '/tests/d' \
		messagingframework.pro || die

	if ! use examples; then
		sed -i -e '/examples/d' messagingframework.pro || die
	fi

	# disable automagic deps
	if ! use icu; then
		sed -i -e 's/packagesExist(icu-uc)/false:&/' \
			src/libraries/qmfclient/qmfclient.pro || die
	fi
	if ! use zlib; then
		sed -i -e 's/packagesExist(zlib)/false:&/' \
			src/plugins/messageservices/imap/imap.pro || die
	fi

	# fix libdir
	find "${S}" -name '*.pro' -type f -print0 | xargs -0 \
		sed -i -re "s:/lib(/|$):/$(get_libdir)\1:" || die
	sed -i -e "s:/lib/:/$(get_libdir)/:" \
		src/libraries/qmfclient/support/qmailnamespace.cpp || die
}

src_configure() {
	eqmake4 QMF_INSTALL_ROOT="${EPREFIX}/usr"
}

src_test() {
	echo ">>> Test phase [QTest]: ${CATEGORY}/${PF}"
	cd "${S}"/tests

	einfo "Building tests"
	eqmake4 QMF_INSTALL_ROOT="${EPREFIX}/usr"
	emake

	einfo "Running tests"
	export QMF_DATA=${T}
	local fail=false test=
	for test in tst_*; do
		# skip test that requires messageserver to be running
		[[ ${test} == tst_qmailstorageaction ]] && continue

		if ! LC_ALL=C ./${test}/${test}; then
			eerror "${test#tst_} test failed!"
			fail=true
		fi
		echo
	done
	${fail} && die "some tests have failed!"
}

src_install() {
	qt4-r2_src_install

	if use doc; then
		emake docs

		dohtml -r doc/html/*
		dodoc doc/html/qmf.qch
		docompress -x /usr/share/doc/${PF}/qmf.qch
	fi
}