[gentoo-commits] repo/gentoo:master commit in: games-board/pokerth/

[Austin English]

commit:     c381fd611fb42f52876775b7479978e100ac1726
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  2 21:04:28 2016 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Tue Aug  2 21:33:14 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c381fd61

games-board/pokerth: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

 games-board/pokerth/pokerth-1.1.1-r2.ebuild | 70 +++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

diff --git a/games-board/pokerth/pokerth-1.1.1-r2.ebuild b/games-board/pokerth/pokerth-1.1.1-r2.ebuild
new file mode 100644
index 0000000..32febcd
--- /dev/null
+++ b/games-board/pokerth/pokerth-1.1.1-r2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit flag-o-matic eutils qmake-utils
+
+MY_P="PokerTH-${PV}-src"
+DESCRIPTION="Texas Hold'em poker game"
+HOMEPAGE="http://www.pokerth.net/"
+SRC_URI="mirror://sourceforge/pokerth/${MY_P}.tar.bz2"
+
+LICENSE="AGPL-3 GPL-1 GPL-2 GPL-3 BitstreamVera public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dedicated"
+
+RDEPEND="dev-db/sqlite:3
+	dev-libs/boost:=[threads(+)]
+	dev-libs/libgcrypt:0
+	dev-libs/protobuf
+	dev-libs/tinyxml[stl]
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5
+	>=net-libs/libircclient-1.6-r2
+	>=net-misc/curl-7.16
+	virtual/gsasl
+	!dedicated? (
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		media-libs/libsdl:0
+		media-libs/sdl-mixer[mod,vorbis]
+	)"
+DEPEND="${RDEPEND}
+	!dedicated? ( dev-qt/qtsql:5 )
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}/${P}-qt5.patch"
+	"${FILESDIR}/${P}-boost-1.60.patch"
+)
+
+src_prepare() {
+	default
+
+	if use dedicated ; then
+		sed -i -e 's/pokerth_game.pro//' pokerth.pro || die
+	fi
+
+	sed -i -e '/no_dead_strip_inits_and_terms/d' *pro || die
+}
+
+src_configure() {
+	eqmake5 pokerth.pro
+}
+
+src_install() {
+	dobin bin/pokerth_server
+	if ! use dedicated ; then
+		dobin ${PN}
+		insinto /usr/share/${PN}
+		doins -r data
+		domenu ${PN}.desktop
+		doicon ${PN}.png
+	fi
+	doman docs/pokerth.1
+	dodoc ChangeLog TODO docs/{gui_styling,server_setup}_howto.txt
+}