[gentoo-commits] gentoo-x86 commit in dev-go/go-tools: go-tools-1.4.2_p20150520-r1.ebuild go-tools-9999.ebuild ChangeLog

[Zac Medico (zmedico)]

zmedico     15/06/03 07:05:58

  Modified:             go-tools-9999.ebuild ChangeLog
  Added:                go-tools-1.4.2_p20150520-r1.ebuild
  Log:
  Add favicon to the godoc web interface (bug 551030).
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key FDE8EF85AE5719A3)

Revision  Changes    Path
1.6                  dev-go/go-tools/go-tools-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/go-tools-9999.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/go-tools-9999.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/go-tools-9999.ebuild?r1=1.5&r2=1.6

Index: go-tools-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-go/go-tools/go-tools-9999.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- go-tools-9999.ebuild	28 May 2015 07:11:30 -0000	1.5
+++ go-tools-9999.ebuild	3 Jun 2015 07:05:58 -0000	1.6
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-go/go-tools/go-tools-9999.ebuild,v 1.5 2015/05/28 07:11:30 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-go/go-tools/go-tools-9999.ebuild,v 1.6 2015/06/03 07:05:58 zmedico Exp $
 
 EAPI=5
 inherit git-r3
@@ -11,6 +11,7 @@
 GO_PN=golang.org/x/${MY_PN}
 HOMEPAGE="https://godoc.org/${GO_PN}"
 EGIT_REPO_URI="https://go.googlesource.com/${MY_PN}"
+SRC_URI="http://golang.org/favicon.ico -> go-favicon.ico"
 LICENSE="BSD"
 SLOT="0"
 IUSE=""
@@ -21,6 +22,11 @@
 EGIT_CHECKOUT_DIR="${S}"
 STRIP_MASK="*.a"
 
+src_unpack() {
+	git-r3_src_unpack
+	cp "${DISTDIR}"/go-favicon.ico "${S}"/godoc/static/favicon.ico || die
+}
+
 src_prepare() {
 	# disable broken tests
 	sed -e 's:TestWeb(:_\0:' -i cmd/godoc/godoc_test.go || die
@@ -41,6 +47,11 @@
 		-e 's:TestStdKen(:_\0:' -i go/types/stdlib_test.go || die
 	sed -e 's:TestRepoRootForImportPath(:_\0:' -i go/vcs/vcs_test.go || die
 	sed -e 's:TestStdlib(:_\0:' -i refactor/lexical/lexical_test.go || die
+
+	# Add favicon to the godoc web interface (bug 551030)
+	sed -e 's:"example.html",:\0\n\t"favicon.ico",:' -i godoc/static/makestatic.go || die
+	sed -e 's:<link type="text/css":<link rel="icon" type="image/png" href="/lib/godoc/favicon.ico">\n\0:' -i \
+		godoc/static/godoc.html || die
 }
 
 src_compile() {
@@ -49,6 +60,12 @@
 	cp -sR "${EPREFIX}"/usr/lib/go "${GOROOT}" || die
 	rm -rf "${GOROOT}/src/${GO_PN}" \
 		"${GOROOT}/pkg/linux_${ARCH}/${GO_PN}" || die
+
+	# Generate static.go with favicon included
+	pushd godoc/static >/dev/null
+	GOROOT="${GOROOT}" GOPATH=${WORKDIR} go run makestatic.go || die
+	popd >/dev/null
+
 	GOROOT="${GOROOT}" GOPATH=${WORKDIR} go install -v -x -work ${GO_PN}/... || die
 }
 



1.8                  dev-go/go-tools/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-go/go-tools/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	28 May 2015 07:11:30 -0000	1.7
+++ ChangeLog	3 Jun 2015 07:05:58 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for dev-go/go-tools
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-go/go-tools/ChangeLog,v 1.7 2015/05/28 07:11:30 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-go/go-tools/ChangeLog,v 1.8 2015/06/03 07:05:58 zmedico Exp $
+
+*go-tools-1.4.2_p20150520-r1 (03 Jun 2015)
+
+  03 Jun 2015; Zac Medico <zmedico@g.o>
+  +go-tools-1.4.2_p20150520-r1.ebuild, go-tools-9999.ebuild:
+  Add favicon to the godoc web interface (bug 551030).
 
   28 May 2015; Zac Medico <zmedico@g.o> go-tools-1.4.2_p20150520.ebuild,
   go-tools-9999.ebuild:



1.1                  dev-go/go-tools/go-tools-1.4.2_p20150520-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/go-tools-1.4.2_p20150520-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-go/go-tools/go-tools-1.4.2_p20150520-r1.ebuild?rev=1.1&content-type=text/plain

Index: go-tools-1.4.2_p20150520-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-go/go-tools/go-tools-1.4.2_p20150520-r1.ebuild,v 1.1 2015/06/03 07:05:58 zmedico Exp $

EAPI=5

KEYWORDS="~amd64"
DESCRIPTION="Go Tools"
MY_PN=${PN##*-}
GO_PN=golang.org/x/${MY_PN}
HOMEPAGE="https://godoc.org/${GO_PN}"
EGIT_COMMIT="3d1847243ea4f07666a91110f48e79e43396603d"
SRC_URI="https://github.com/golang/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz
	http://golang.org/favicon.ico -> go-favicon.ico"
LICENSE="BSD"
SLOT="0"
IUSE=""
DEPEND=">=dev-lang/go-1.4
	dev-go/go-net"
RDEPEND=""
S="${WORKDIR}/src/${GO_PN}"
EGIT_CHECKOUT_DIR="${S}"
STRIP_MASK="*.a"

src_unpack() {
	default
	mkdir -p src/${GO_PN%/*} || die
	mv ${MY_PN}-${EGIT_COMMIT} src/${GO_PN} || die
	cp "${DISTDIR}"/go-favicon.ico "${S}"/godoc/static/favicon.ico || die
}

src_prepare() {
	# disable broken tests
	sed -e 's:TestWeb(:_\0:' -i cmd/godoc/godoc_test.go || die
	sed -e 's:TestVet(:_\0:' -i cmd/vet/vet_test.go || die
	sed -e 's:TestImport(:_\0:' -i go/gcimporter/gcimporter_test.go || die
	sed -e 's:TestImportStdLib(:_\0:' -i go/importer/import_test.go || die
	sed -e 's:TestStdlib(:_\0:' -i go/loader/stdlib_test.go || die
	sed -e 's:TestStdlib(:_\0:' -i go/ssa/stdlib_test.go || die
	sed -e 's:TestGorootTest(:_\0:' \
		-e 's:TestFoo(:_\0:' \
		-e 's:TestTestmainPackage(:_\0:' \
		-i go/ssa/interp/interp_test.go || die
	sed -e 's:TestBar(:_\0:' \
		-e 's:TestFoo(:_\0:' -i go/ssa/interp/testdata/a_test.go || die
	sed -e 's:TestCheck(:_\0:' -i go/types/check_test.go || die
	sed -e 's:TestStdlib(:_\0:' \
		-e 's:TestStdFixed(:_\0:' \
		-e 's:TestStdKen(:_\0:' -i go/types/stdlib_test.go || die
	sed -e 's:TestRepoRootForImportPath(:_\0:' -i go/vcs/vcs_test.go || die
	sed -e 's:TestStdlib(:_\0:' -i refactor/lexical/lexical_test.go || die

	# Add favicon to the godoc web interface (bug 551030)
	sed -e 's:"example.html",:\0\n\t"favicon.ico",:' -i godoc/static/makestatic.go || die
	sed -e 's:<link type="text/css":<link rel="icon" type="image/png" href="/lib/godoc/favicon.ico">\n\0:' -i \
		godoc/static/godoc.html || die
}

src_compile() {
	# Create a writable GOROOT in order to avoid sandbox violations.
	GOROOT="${WORKDIR}/goroot"
	cp -sR "${EPREFIX}"/usr/lib/go "${GOROOT}" || die
	rm -rf "${GOROOT}/src/${GO_PN}" \
		"${GOROOT}/pkg/linux_${ARCH}/${GO_PN}" || die

	# Generate static.go with favicon included
	pushd godoc/static >/dev/null
	GOROOT="${GOROOT}" GOPATH=${WORKDIR} go run makestatic.go || die
	popd >/dev/null

	GOROOT="${GOROOT}" GOPATH=${WORKDIR} go install -v -x -work ${GO_PN}/... || die
}

src_test() {
	GOROOT="${GOROOT}" GOPATH=${WORKDIR} \
		go test -x -v ${GO_PN}/... || die $?
}

src_install() {
	local x
	exeinto /usr/lib/go/bin
	doexe "${WORKDIR}"/bin/*

	# godoc ends up in ${GOROOT}/bin
	dodir /usr/bin
	while read -r -d '' x; do
		doexe "${x}"
		ln "${ED}"usr/{lib/go/bin,bin}/${x##*/} || die
	done < <(find "${GOROOT}/bin" -type f -print0)

	# cover and vet end up in ${GOROOT}/pkg/tool/linux_amd64
	exeinto /usr/lib/go/pkg/tool/linux_amd64
	find "${GOROOT}/pkg/tool/linux_amd64" -type f -exec doexe {} \;

	insinto /usr/lib/go
	find "${WORKDIR}"/{pkg,src} -name '.git*' -exec rm -rf {} \; 2>/dev/null
	doins -r "${WORKDIR}"/{pkg,src}
}