[gentoo-commits] gentoo-x86 commit in x11-wm/awesome: awesome-3.5_rc1-r1.ebuild ChangeLog awesome-3.5_rc1.ebuild

[Robin H. Johnson (robbat2)]

robbat2     12/11/28 00:20:30

  Modified:             ChangeLog
  Added:                awesome-3.5_rc1-r1.ebuild
  Removed:              awesome-3.5_rc1.ebuild
  Log:
  Upstream added a new dep, lgi, that was underdocumented. Also block building luadocs unless you have lua-5.2 per upstream emails on awesome ML.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.140                x11-wm/awesome/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/awesome/ChangeLog?rev=1.140&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/awesome/ChangeLog?rev=1.140&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/awesome/ChangeLog?r1=1.139&r2=1.140

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v
retrieving revision 1.139
retrieving revision 1.140
diff -p -w -b -B -u -u -r1.139 -r1.140
--- ChangeLog	24 Nov 2012 21:28:03 -0000	1.139
+++ ChangeLog	28 Nov 2012 00:20:30 -0000	1.140
@@ -1,6 +1,13 @@
 # ChangeLog for x11-wm/awesome
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v 1.139 2012/11/24 21:28:03 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/ChangeLog,v 1.140 2012/11/28 00:20:30 robbat2 Exp $
+
+*awesome-3.5_rc1-r1 (28 Nov 2012)
+
+  28 Nov 2012; Robin H. Johnson <robbat2@g.o> +awesome-3.5_rc1-r1.ebuild,
+  -awesome-3.5_rc1.ebuild:
+  Upstream added a new dep, lgi, that was underdocumented. Also block building
+  luadocs unless you have lua-5.2 per upstream emails on awesome ML.
 
 *awesome-3.5_rc1 (24 Nov 2012)
 



1.1                  x11-wm/awesome/awesome-3.5_rc1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/awesome/awesome-3.5_rc1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/awesome/awesome-3.5_rc1-r1.ebuild?rev=1.1&content-type=text/plain

Index: awesome-3.5_rc1-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/awesome/awesome-3.5_rc1-r1.ebuild,v 1.1 2012/11/28 00:20:30 robbat2 Exp $

EAPI="3"
CMAKE_MIN_VERSION="2.8"
inherit cmake-utils eutils

DESCRIPTION="A dynamic floating and tiling window manager"
HOMEPAGE="http://awesome.naquadah.org/"
MY_PV="${PV/_/-}"
MY_P="${PN}-${MY_PV}"
SRC_URI="http://awesome.naquadah.org/download/${MY_P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="dbus doc elibc_FreeBSD gnome"

COMMON_DEPEND=">=dev-lang/lua-5.1
	dev-libs/libev
	>=dev-libs/libxdg-basedir-1
	media-libs/imlib2[png]
	x11-libs/cairo[xcb]
	|| ( <x11-libs/libX11-1.3.99.901[xcb] >=x11-libs/libX11-1.3.99.901 )
	>=x11-libs/libxcb-1.6
	>=x11-libs/pango-1.19.3
	>=x11-libs/startup-notification-0.10_p20110426
	>=x11-libs/xcb-util-0.3.8
	dbus? ( >=sys-apps/dbus-1 )
	elibc_FreeBSD? ( dev-libs/libexecinfo )
	>=dev-lua/lgi-0.6.1"

# graphicsmagick's 'convert -channel' has no Alpha support, bug #352282
DEPEND="${COMMON_DEPEND}
	>=app-text/asciidoc-8.4.5
	app-text/xmlto
	dev-util/gperf
	virtual/pkgconfig
	media-gfx/imagemagick[png]
	>=x11-proto/xcb-proto-1.5
	>=x11-proto/xproto-7.0.15
	doc? (
		app-doc/doxygen
		dev-lua/luadoc
		media-gfx/graphviz
	)"

RDEPEND="${COMMON_DEPEND}
	|| (
		x11-misc/gxmessage
		x11-apps/xmessage
	)"

# bug #321433: Need one of these to for awsetbg.
# imagemagick provides 'display' and is further down the default list, but
# listed here for completeness.  'display' however is only usable with
# x11-apps/xwininfo also present.
RDEPEND="${RDEPEND}
	|| (
	( x11-apps/xwininfo
	  || ( media-gfx/imagemagick[X] media-gfx/graphicsmagick[imagemagick,X] )
	)
	x11-misc/habak
	media-gfx/feh
	x11-misc/hsetroot
	media-gfx/qiv
	media-gfx/xv
	x11-misc/xsri
	media-gfx/xli
	x11-apps/xsetroot
	)"

DOCS="AUTHORS BUGS PATCHES README STYLE"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# Upstreamed
	#epatch \
	#	"${FILESDIR}/${PN}-3.4.2-backtrace.patch"

	# bug  #408025
	epatch "${FILESDIR}/${PN}-3.5_rc1-convert-path.patch"
}

src_configure() {
	mycmakeargs=(
		-DPREFIX="${EPREFIX}"/usr
		-DSYSCONFDIR="${EPREFIX}"/etc
		$(cmake-utils_use_with dbus DBUS)
		)
	
	# The lua docs now officially require ldoc.lua and NOT luadoc
	# As the modules documentation has been updated to the Lua 5.2 style
	has_version >=dev-lang/lua-5.2 && mycmakeargs+="$(cmake-utils_use doc GENERATE_LUADOC)"

	cmake-utils_src_configure
}

src_compile() {
	local myargs="all"

	if use doc ; then
		myargs="${myargs} doc"
	fi
	cmake-utils_src_make ${myargs}
}

src_install() {
	cmake-utils_src_install

	if use doc ; then
		(
			cd "${CMAKE_BUILD_DIR}"/doc
			mv html doxygen
			dohtml -r doxygen || die
		)
	fi
	rm -rf "${ED}"/usr/share/doc/${PN} || die "Cleanup of dupe docs failed"

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}"/${PN}-session ${PN} || die

	# GNOME-based awesome
	if use gnome ; then
		# GNOME session
		insinto /usr/share/gnome-session/sessions
		doins "${FILESDIR}/${PN}-gnome.session" || die
		# Application launcher
		insinto /usr/share/applications
		doins "${FILESDIR}/${PN}-gnome.desktop" || die
		# X Session
		insinto /usr/share/xsessions/
		doins "${FILESDIR}/${PN}-gnome-xsession.desktop" || die
	fi
}