[gentoo-commits] gentoo-x86 commit in net-firewall/fwbuilder: ChangeLog fwbuilder-3.0.6.ebuild

[Patrick Lauer (patrick)]

patrick     09/09/01 10:40:27

  Modified:             ChangeLog
  Added:                fwbuilder-3.0.6.ebuild
  Log:
  Bump to 3.0.6, fixes #283001
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.87                 net-firewall/fwbuilder/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	26 Jul 2009 13:49:31 -0000	1.86
+++ ChangeLog	1 Sep 2009 10:40:27 -0000	1.87
@@ -1,6 +1,11 @@
 # ChangeLog for net-firewall/fwbuilder
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/ChangeLog,v 1.86 2009/07/26 13:49:31 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/ChangeLog,v 1.87 2009/09/01 10:40:27 patrick Exp $
+
+*fwbuilder-3.0.6 (01 Sep 2009)
+
+  01 Sep 2009; Patrick Lauer <patrick@g.o> +fwbuilder-3.0.6.ebuild:
+  Bump to 3.0.6, fixes #283001
 
   26 Jul 2009; Brent Baude <ranger@g.o> fwbuilder-3.0.3.ebuild:
   Marking fwbuilder-3.0.3 ppc64 for bug 235809



1.1                  net-firewall/fwbuilder/fwbuilder-3.0.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/fwbuilder-3.0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/fwbuilder/fwbuilder-3.0.6.ebuild?rev=1.1&content-type=text/plain

Index: fwbuilder-3.0.6.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwbuilder/fwbuilder-3.0.6.ebuild,v 1.1 2009/09/01 10:40:27 patrick Exp $

EAPI="2"

inherit qt4 multilib

DESCRIPTION="A firewall GUI"
HOMEPAGE="http://www.fwbuilder.org/"
SRC_URI="mirror://sourceforge/fwbuilder/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="+pch"

DEPEND="~net-libs/libfwbuilder-${PV}
	>=dev-java/antlr-2.7.7:0[cxx]
	x11-libs/qt-gui:4"
RDEPEND="${DEPEND}"

src_prepare() {
	qt4_src_prepare

	# Remove bundled antlr
	rm -rf src/antlr

	sed -i \
		-e '/COPYING/d' \
		doc/doc.pro || die "sed doc.pro failed"

	# we'll use our eqmake instead of bundled script to process qmake files
	sed -i \
		-e 's:^. ./runqmake.sh$:echo:' \
		configure || die "sed configure failed"

	# prevent install script from automatically stripping binaries - let portage do that
	sed -i \
		-e 's/s) stripcmd="$stripprog"$/s)/' \
		install.sh || die "sed install.sh failed"

	if ! use pch; then
		sed -i \
				-e '/^PRECOMPILED_HEADER =/,/[^\\]$/d' \
				-e '/^CONFIG += precompile_header/d' \
				src/gui/gui.pro || die "sed for gui.pro failed"
	fi
}

src_configure() {
	econf \
		--with-docdir=/usr/share/doc/${PF}

	for pro_file in $(find "${S}" -name "*.pro"); do
		eqmake4 "${pro_file}" -o "$(dirname ${pro_file})/Makefile" "CONFIG+=nostrip" || die "eqmake4 for ${pro_file} failed"
	done
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
	cd doc
	dodoc AUTHORS ChangeLog Credits README* \
		FWBuilder-Routing-LICENSE.txt PatchAcceptancePolicy.txt
	doman fwb*.1
}

pkg_postinst() {
	validate_desktop_entries

	elog "You need to emerge sys-apps/iproute2 on the machine"
	elog "that will run the firewall script."
}