[gentoo-commits] gentoo-x86 commit in games-action/xblast: ChangeLog xblast-2.10.4.ebuild

[Alfredo Tupone (tupone)]

tupone      07/10/28 09:36:53

  Modified:             ChangeLog
  Added:                xblast-2.10.4.ebuild
  Log:
  bump to 2.10.4
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.12                 games-action/xblast/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-action/xblast/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-action/xblast/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-action/xblast/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-action/xblast/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	1 Dec 2006 19:52:26 -0000	1.11
+++ ChangeLog	28 Oct 2007 09:36:53 -0000	1.12
@@ -1,6 +1,11 @@
 # ChangeLog for games-action/xblast
-# Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-action/xblast/ChangeLog,v 1.11 2006/12/01 19:52:26 wolf31o2 Exp $
+# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-action/xblast/ChangeLog,v 1.12 2007/10/28 09:36:53 tupone Exp $
+
+*xblast-2.10.4 (28 Oct 2007)
+
+  28 Oct 2007; Tupone Alfredo <tupone@g.o> +xblast-2.10.4.ebuild:
+  bump to 2.10.4
 
   01 Dec 2006; Chris Gianelloni <wolf31o2@g.o> xblast-2.10.2.ebuild:
   Removing old virtual/x11 dependency.



1.1                  games-action/xblast/xblast-2.10.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-action/xblast/xblast-2.10.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-action/xblast/xblast-2.10.4.ebuild?rev=1.1&content-type=text/plain

Index: xblast-2.10.4.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/xblast/xblast-2.10.4.ebuild,v 1.1 2007/10/28 09:36:53 tupone Exp $

inherit games

# Change these as releases changes
IMAGES="images-2005-01-06"
LEVELS="levels-2005-01-06"
MODELS="models-2005-01-06"
MUSICS="musics-2005-01-06"
SOUNDS="sounds"

DESCRIPTION="Bomberman clone w/network support for up to 6 players"
HOMEPAGE="http://xblast.sourceforge.net/"
SRC_URI="mirror://sourceforge/xblast/${P}.tar.gz
	mirror://sourceforge/xblast/${IMAGES}.tar.gz
	mirror://sourceforge/xblast/${LEVELS}.tar.gz
	mirror://sourceforge/xblast/${MODELS}.tar.gz
	mirror://sourceforge/xblast/${MUSICS}.tar.gz
	mirror://sourceforge/xblast/${SOUNDS}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND="x11-libs/libICE
	x11-libs/libX11
	media-libs/libpng"
DEPEND="${RDEPEND}
	x11-libs/libXt"

src_compile() {
	export MY_DATADIR="${GAMES_DATADIR}/${PN}"
	egamesconf \
		--with-otherdatadir="${MY_DATADIR}" \
		--enable-sound \
		|| die
	emake || die "emake failed"
}

src_install() {
	local IMAGE_INSTALL_DIR="${GAMES_DATADIR}/${PN}/image"

	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog NEWS README

	# Images
	dodir "${IMAGE_INSTALL_DIR}"
	cp -pPR "${WORKDIR}/${IMAGES}"/* "${D}/${IMAGE_INSTALL_DIR}" \
		|| die "cp failed"

	# Levels
	insinto "${GAMES_DATADIR}/xblast/level"
	doins "${WORKDIR}/${LEVELS}"/* || die "doins failed"

	# Models
	insinto "${GAMES_DATADIR}/xblast/image/sprite"
	doins "${WORKDIR}/${MODELS}"/* || die "doins failed"

	# Music and sound
	insinto "${GAMES_DATADIR}/xblast/sounds"
	doins "${WORKDIR}/${MUSICS}"/* "${WORKDIR}/${SOUNDS}"/* \
		|| die "doins failed"

	# Cleanup
	find "${D}" -name Imakefile -exec rm \{\} \;

	prepgamesdirs
}



-- 
gentoo-commits@g.o mailing list