[gentoo-commits] gentoo-x86 commit in app-misc/tasque: tasque-0.1.8.ebuild metadata.xml ChangeLog

[Peter Alfredsen (loki_val)]

loki_val    09/01/23 20:13:19

  Added:                tasque-0.1.8.ebuild metadata.xml ChangeLog
  Log:
  Add Tasque. Ebuild by Andreas Proschofsky, bugs by me :-).
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-misc/tasque/tasque-0.1.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/tasque/tasque-0.1.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/tasque/tasque-0.1.8.ebuild?rev=1.1&content-type=text/plain

Index: tasque-0.1.8.ebuild
===================================================================
# Copyright 2000-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/tasque/tasque-0.1.8.ebuild,v 1.1 2009/01/23 20:13:19 loki_val Exp $

EAPI=2

inherit gnome.org mono autotools

DESCRIPTION="Tasky is a simple task management app (TODO list) for the Linux Desktop"
HOMEPAGE="http://live.gnome.org/Tasque"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="+rememberthemilk eds +sqlite hiveminder debug"

RDEPEND=">=dev-dotnet/gtk-sharp-2.12.7-r5
	>=dev-dotnet/gnome-sharp-2.24.0
	>=dev-dotnet/notify-sharp-0.4.0_pre20080912
	>=dev-dotnet/dbus-sharp-0.6
	>=dev-dotnet/dbus-glib-sharp-0.4
	eds? ( >=dev-dotnet/evolution-sharp-0.18.1 )
	sqlite? ( dev-db/sqlite:3 )
	"

DEPEND="${RDEPEND}"

pkg_setup() {
	BACKEND=false
	for usef in eds sqlite hiveminder rememberthemilk
	do
		use $usef && BACKEND=true
	done
	if [[ "${BACKEND}" != "true" ]]
	then
		eerror "You must select one of the following backends by enabling their useflag:"
		eerror "eds			( integrates with the evolution schedule )"
		eerror "sqlite		( uses a local, file-backed database to keep track of your TODO list )"
		eerror "rememberthemilk	( integrates with www.rememberthemilk.com )"
		eerror "hiveminder		( integrates with www.hiveminder.com )"
		die "Please select a backend"
	fi
}


src_prepare() {
	#http://bugzilla.gnome.org/show_bug.cgi?id=566355
	epatch "${FILESDIR}"/${P}-debug-fixup.patch
	eautoreconf
}

src_configure() {
	#http://bugzilla.gnome.org/show_bug.cgi?id=568910
	export	GTK_DOTNET_20_LIBS=" " \
		GTK_DOTNET_20_CFLAGS=" "
	econf	--disable-backend-icecore \
		--enable-backend-rtm \
		$(use_enable sqlite backend-sqlite) \
		$(use_enable eds backend-eds) \
		$(use_enable hiveminder backend-hiveminder) \
		$(use_enable debug)
}

src_install() {
	make DESTDIR="${D}" install || die "emake failed"
	dodoc NEWS TODO README AUTHORS || die "docs installation failed"
}



1.1                  app-misc/tasque/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/tasque/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/tasque/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>dotnet</herd>
	<maintainer>
		<email>suka@g.o</email>
		<name>Andreas Proschofsky</name>
	</maintainer>
	<use>
		<flag name='rememberthemilk'>
			Allows you to use http://www.rememberthemilk.com/ as your storage backend.
		</flag>
		<flag name='hiveminder'>
			Allows you to use http://www.hiveminder.com/ as your storage backend.
		</flag>
	</use>
</pkgmetadata>



1.1                  app-misc/tasque/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/tasque/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/tasque/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-misc/tasque
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/tasque/ChangeLog,v 1.1 2009/01/23 20:13:19 loki_val Exp $

*tasque-0.1.8 (23 Jan 2009)

  23 Jan 2009; Peter Alfredsen <loki_val@g.o>
  +files/tasque-0.1.8-debug-fixup.patch, +metadata.xml,
  +tasque-0.1.8.ebuild:
  Add Tasque. Ebuild by Andreas Proschofsky, bugs by me :-).