[gentoo-commits] gentoo-x86 commit in app-admin/smolt: metadata.xml ChangeLog smolt-1.4.ebuild

[Sebastian Pipping (sping)]

sping       09/10/02 20:09:33

  Modified:             metadata.xml ChangeLog
  Added:                smolt-1.4.ebuild
  Log:
  Bump to 1.4
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.2                  app-admin/smolt/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/smolt/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	5 Feb 2009 21:24:36 -0000	1.1
+++ metadata.xml	2 Oct 2009 20:09:32 -0000	1.2
@@ -3,7 +3,10 @@
 <pkgmetadata>
 <herd>no-herd</herd>
 <maintainer>
-  <email>bangert@g.o</email>
+	<email>bangert@g.o</email>
+</maintainer>
+<maintainer>
+	<email>sping@g.o</email>
 </maintainer>
 <longdescription lang="en">
 Smolt is a basic hardware profiler. Its intended to be a profiler to get automated information from users. 



1.4                  app-admin/smolt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/smolt/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	22 Apr 2009 20:22:01 -0000	1.3
+++ ChangeLog	2 Oct 2009 20:09:32 -0000	1.4
@@ -1,6 +1,15 @@
 # ChangeLog for app-admin/smolt
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/smolt/ChangeLog,v 1.3 2009/04/22 20:22:01 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/smolt/ChangeLog,v 1.4 2009/10/02 20:09:32 sping Exp $
+
+*smolt-1.4 (02 Oct 2009)
+
+  02 Oct 2009; Sebastian Pipping <sping@g.o> +smolt-1.4.ebuild,
+  +files/smolt-1.4-upstream-docdir.patch,
+  +files/smolt-1.4-upstream-fix-gzip-calls.patch, metadata.xml:
+  Bump to version 1.4 (now qt4, gtk before), upgrade to EAPI 2, fix license
+  (GPL 2 or later), add more ' die' stuff. First commit to the tree ever,
+  don't shoot me please :-)
 
   22 Apr 2009; Markus Meier <maekke@g.o> smolt-1.2:
   add ~amd64, bug #264012



1.1                  app-admin/smolt/smolt-1.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/smolt-1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/smolt/smolt-1.4.ebuild?rev=1.1&content-type=text/plain

Index: smolt-1.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/smolt/smolt-1.4.ebuild,v 1.1 2009/10/02 20:09:32 sping Exp $

EAPI="2"

inherit python eutils

DESCRIPTION="The Fedora hardware profiler"
HOMEPAGE="https://fedorahosted.org/smolt/"
SRC_URI="https://fedorahosted.org/releases/s/m/${PN}/${P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="qt4"

DEPEND="virtual/python
	sys-devel/gettext"

RDEPEND="${DEPEND}
	sys-apps/hal
	>=dev-python/rhpl-0.213
	>=dev-python/urlgrabber-3.0.0
	>=dev-python/simplejson-1.7.1
	dev-python/dbus-python
	qt4? ( dev-python/PyQt4 )"

S="${S}/client"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.4-upstream-{fix-gzip-calls,docdir}.patch
}

src_install() {
	emake install DESTDIR="${D}" DOCDIR="/usr/share/doc/${PF}" \
		|| die "Install failed"

	if ! use qt4; then
		rm "${D}"/usr/bin/smoltGui \
				"${D}"/usr/share/smolt/client/{gui,smoltGui}.py \
				"${D}"/usr/share/applications/smolt.desktop \
				"${D}"/usr/share/man/man1/smoltGui.1.* \
			|| die "rm failed"
		rmdir "${D}"/usr/share/applications || die "rmdir failed"
	fi

	bzip2 -9 "${D}"/usr/share/doc/${PF}/PrivacyPolicy || die "bzip2 failed"
	dodoc ../README ../TODO || die "dodoc failed"

	newinitd "${FILESDIR}"/${PN}-init.d ${PN} || die "newinitd failed"
}

pkg_postinst() {
	python_mod_optimize "${ROOT}"/usr/share/${PN}

	if ! [ -f "${ROOT}"/etc/smolt/hw-uuid ]; then
		elog "Creating this machines UUID in ${ROOT}/etc/smolt/hw-uuid"
		cat /proc/sys/kernel/random/uuid > "${ROOT}"/etc/smolt/hw-uuid
		UUID=$(cat "${ROOT}"/etc/smolt/hw-uuid)
		elog "Your UUID is: ${UUID}"
	fi
	echo
	elog "Call smoltSendProfile as root in order to initialize your profile."
	echo
	elog "You can withdraw it from the server if you wish to with"
	elog "   smoltDeleteProfile any time later on."
	echo

	if use qt4 && has_version "<virtual/python-2.5"; then
		elog "If you want to view your profile on the web from within smoltGui,"
		elog "you should have a link mozilla-firefox -> firefox in your path."
		echo
	fi
}

pkg_postrm() {
	python_mod_cleanup /usr/share/${PN}
}