[gentoo-commits] gentoo-x86 commit in net-analyzer/argus: argus-3.0.5.5.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         11/08/30 19:35:01

  Modified:             ChangeLog
  Added:                argus-3.0.5.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.34                 net-analyzer/argus/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/argus/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	6 Jul 2011 14:58:25 -0000	1.33
+++ ChangeLog	30 Aug 2011 19:35:01 -0000	1.34
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/argus
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus/ChangeLog,v 1.33 2011/07/06 14:58:25 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus/ChangeLog,v 1.34 2011/08/30 19:35:01 jer Exp $
+
+*argus-3.0.5.5 (30 Aug 2011)
+
+  30 Aug 2011; Jeroen Roovers <jer@g.o> +argus-3.0.5.5.ebuild:
+  Version bump.
 
 *argus-3.0.5.4 (06 Jul 2011)
 



1.1                  net-analyzer/argus/argus-3.0.5.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus/argus-3.0.5.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/argus/argus-3.0.5.5.ebuild?rev=1.1&content-type=text/plain

Index: argus-3.0.5.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus/argus-3.0.5.5.ebuild,v 1.1 2011/08/30 19:35:01 jer Exp $

EAPI="2"

inherit autotools eutils

DESCRIPTION="network Audit Record Generation and Utilization System"
HOMEPAGE="http://www.qosient.com/argus/"
SRC_URI="http://qosient.com/argus/dev/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="debug tcpd"

#	sasl? ( >=dev-libs/cyrus-sasl-2.1.22 )
RDEPEND="net-libs/libpcap
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )"

DEPEND="${RDEPEND}
	>=sys-devel/bison-1.28
	>=sys-devel/flex-2.4.6"

src_prepare() {
	sed -e 's:/etc/argus.conf:/etc/argus/argus.conf:' \
		-i argus/argus.c \
		-i support/Config/argus.conf \
		-i man/man8/argus.8 \
		-i man/man5/argus.conf.5 || die

	sed -e 's:#\(ARGUS_SETUSER_ID=\).*:\1argus:' \
		-e 's:#\(ARGUS_SETGROUP_ID=\).*:\1argus:' \
		-e 's:\(#ARGUS_CHROOT_DIR=\).*:\1/var/lib/argus:' \
			-i support/Config/argus.conf || die
	epatch "${FILESDIR}"/${PN}-3.0.4-disable-tcp-wrappers-automagic.patch
	eautoreconf
}

src_configure() {
	use debug && touch .debug # enable debugging
	econf $(use_with tcpd wrappers)
}

src_install () {
	doman man/man5/* man/man8/*
	dosbin bin/argus{,bug} || die

	dodoc ChangeLog CREDITS README || die

	insinto /etc/argus
	doins support/Config/argus.conf || die

	newinitd "${FILESDIR}/argus.initd" argus || die
	dodir /var/lib/argus
}

pkg_preinst() {
	enewgroup argus
	enewuser argus -1 -1 /var/lib/argus argus
}

pkg_postinst() {
	elog "Note, if you modify ARGUS_DAEMON value in argus.conf it's quite"
	elog "possible that init script will fail to work."
}