[gentoo-commits] gentoo-x86 commit in dev-java/bcpg: bcpg-1.52.ebuild ChangeLog

[Patrice Clement (monsieurp)]

monsieurp    15/08/01 16:41:31

  Modified:             ChangeLog
  Added:                bcpg-1.52.ebuild
  Log:
  Version bump. Fixes bug 535882.
  
  Signed-off-by: Patrice Clement <monsieurp@g.o>
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 93491BB8)

Revision  Changes    Path
1.4                  dev-java/bcpg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcpg/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcpg/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcpg/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/bcpg/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	3 Aug 2014 09:59:14 -0000	1.3
+++ ChangeLog	1 Aug 2015 16:41:30 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/bcpg
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/bcpg/ChangeLog,v 1.3 2014/08/03 09:59:14 sera Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/bcpg/ChangeLog,v 1.4 2015/08/01 16:41:30 monsieurp Exp $
+
+*bcpg-1.52 (01 Aug 2015)
+
+  01 Aug 2015; Patrice Clement <monsieurp@g.o> +bcpg-1.52.ebuild:
+  Version bump. Fixes bug 535882.
 
   03 Aug 2014; Ralph Sennhauser <sera@g.o> -bcpg-1.49-r1.ebuild:
   Remove old



1.1                  dev-java/bcpg/bcpg-1.52.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcpg/bcpg-1.52.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/bcpg/bcpg-1.52.ebuild?rev=1.1&content-type=text/plain

Index: bcpg-1.52.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/bcpg/bcpg-1.52.ebuild,v 1.1 2015/08/01 16:41:30 monsieurp Exp $

EAPI="5"

JAVA_PKG_IUSE="doc source test"

inherit java-pkg-2 java-ant-2

MY_P="${PN}-jdk15on-${PV/./}"

DESCRIPTION="Java cryptography APIs"
HOMEPAGE="http://www.bouncycastle.org/java.html"
SRC_URI="http://www.bouncycastle.org/download/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos"

# Tests are currently broken. Appears to need older version of bcprov; but since bcprov is not slotted, this can cause conflicts.
# Needs further investigation; though, only a small part has tests and there are no tests for bcpg itself.
RESTRICT="test"

CDEPEND="
	>=dev-java/bcprov-${PV}:0[test?]"

DEPEND=">=virtual/jdk-1.6
	app-arch/unzip
	test? (
		dev-java/junit:0
	)
	${CDEPEND}"

RDEPEND=">=virtual/jre-1.6
	${CDEPEND}"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	default
	cd "${S}"
	unpack ./src.zip
}

java_prepare() {
	mkdir "${S}"/classes

	if use test; then
		java-pkg_jar-from --build-only junit
	fi

	java-pkg_jar-from bcprov
}

src_compile() {
	find org -name "*.java" > "${T}"/src.list

	local cp="bcprov.jar"
	if use test ; then
		cp="${cp}:junit.jar"
	else
		sed -i '/\/test\//d' "${T}"/src.list || die "Failed to remove test classes"
	fi

	ejavac -d "${S}"/classes -cp ${cp} "@${T}"/src.list

	cd "${S}"/classes || die

	jar -cf "${S}"/${PN}.jar * || die "Failed to create jar."
}

src_test() {
	local cp="${PN}.jar:bcprov.jar:junit.jar"
	local pkg="org.bouncycastle"

	java -cp ${cp} ${pkg}.openpgp.test.AllTests | tee openpgp.tests

	grep -q FAILURES *.tests && die "Tests failed."
}

src_install() {
	java-pkg_dojar "${S}"/${PN}.jar

	use source && java-pkg_dosrc org
	use doc && java-pkg_dojavadoc docs
}