[gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-5.0.375.99.ebuild chromium-5.0.375.70-r1.ebuild

[PaweA Hajdan (phajdan.jr)]

phajdan.jr    10/07/03 07:47:57

  Modified:             ChangeLog
  Added:                chromium-5.0.375.99.ebuild
  Removed:              chromium-5.0.375.70-r1.ebuild
  Log:
  Version bump for stable channel release. Removed old ebuild.
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.129                www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	25 Jun 2010 20:16:02 -0000	1.128
+++ ChangeLog	3 Jul 2010 07:47:57 -0000	1.129
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.128 2010/06/25 20:16:02 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.129 2010/07/03 07:47:57 phajdan.jr Exp $
+
+*chromium-5.0.375.99 (03 Jul 2010)
+
+  03 Jul 2010; Pawel Hajdan jr <phajdan.jr@g.o>
+  -chromium-5.0.375.70-r1.ebuild, +chromium-5.0.375.99.ebuild:
+  Version bump for stable channel release. Removed old ebuild.
 
   25 Jun 2010; Christoph Mende <angelos@g.o>
   chromium-5.0.375.86.ebuild:
@@ -386,7 +392,7 @@
   -chromium-5.0.307.5.ebuild, +chromium-5.0.335.0.ebuild:
   Version bump for dev channel release. Remove old.
 
-  23 Feb 2010; Raúl Porcel <armin76@g.o> chromium-5.0.322.2.ebuild,
+  23 Feb 2010; Raúl Porcel <armin76@g.o> chromium-5.0.322.2.ebuild,
   chromium-9999.ebuild:
   Add fix for arm build
 
@@ -457,7 +463,7 @@
   Dev channel release bump, also include gnome default-apps file from pacho
   in bug #303100
 
-  01 Feb 2010; Raúl Porcel <armin76@g.o> chromium-4.0.302.2.ebuild,
+  01 Feb 2010; Raúl Porcel <armin76@g.o> chromium-4.0.302.2.ebuild,
   chromium-9999.ebuild:
   Fix build on arm
 
@@ -506,11 +512,11 @@
   +chromium-4.0.302.2.ebuild:
   Version bump for dev channel release. Remove old.
 
-  22 Jan 2010; Raúl Porcel <armin76@g.o>
+  22 Jan 2010; Raúl Porcel <armin76@g.o>
   -files/chromium-drop_armel_m32.patch, chromium-9999.ebuild:
   Drop unneded arm patch
 
-  18 Jan 2010; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
+  18 Jan 2010; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
   chromium-4.0.288.1.ebuild, chromium-4.0.295.0.ebuild:
   Add ~arm
 
@@ -539,11 +545,11 @@
   +chromium-4.0.288.1.ebuild:
   Version bump for dev channel release.
 
-  07 Jan 2010; Raúl Porcel <armin76@g.o>
+  07 Jan 2010; Raúl Porcel <armin76@g.o>
   +files/chromium-drop_armel_m32.patch, chromium-9999.ebuild:
   Add patch to fix build on ARM, enable v8 build on ARM
 
-  25 Dec 2009; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
+  25 Dec 2009; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
   chromium-9999.ebuild:
   Add arm support, but don't keyword it as its still a big buggy
 
@@ -608,7 +614,7 @@
   Version bump, enables bookmarks sync (with --enable-sync), and fix menu
   location for adblock+ extension
 
-  15 Nov 2009; Tomáš Chvátal <scarabeus@g.o> chromium-9999.ebuild:
+  15 Nov 2009; Tomáš Chvátal <scarabeus@g.o> chromium-9999.ebuild:
   QA: Drop keywords on live ebuilds.
 
   09 Nov 2009; Bernard Cafarelli <voyageur@g.o>



1.1                  www-client/chromium/chromium-5.0.375.99.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.99.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.99.ebuild?rev=1.1&content-type=text/plain

Index: chromium-5.0.375.99.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.99.ebuild,v 1.1 2010/07/03 07:47:57 phajdan.jr Exp $

EAPI="2"

inherit eutils flag-o-matic multilib pax-utils toolchain-funcs

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="+plugins-symlink"

RDEPEND="app-arch/bzip2
	>=dev-libs/libevent-1.4.13
	dev-libs/libxml2
	dev-libs/libxslt
	>=dev-libs/nss-3.12.3
	>=gnome-base/gconf-2.24.0
	>=media-libs/alsa-lib-1.0.19
	media-libs/jpeg:0
	media-libs/libpng
	media-video/ffmpeg[threads]
	sys-libs/zlib
	>=x11-libs/gtk+-2.14.7
	x11-libs/libXScrnSaver"
#	dev-db/sqlite:3
DEPEND="${RDEPEND}
	dev-lang/perl
	>=dev-util/gperf-3.0.3
	>=dev-util/pkgconfig-0.23
	sys-devel/flex"
RDEPEND+="
	|| (
		x11-themes/gnome-icon-theme
		x11-themes/oxygen-molecule
		x11-themes/tango-icon-theme
		x11-themes/xfce4-icon-theme
	)
	x11-apps/xmessage
	x11-misc/xdg-utils
	virtual/ttf-fonts"

# Incompatible system plugins:
# www-plugins/gecko-mediaplayer, bug #309231.
RDEPEND+="
	plugins-symlink? (
		!www-plugins/gecko-mediaplayer[gnome]
	)"

src_prepare() {
	# Prevent automatic -march=pentium4 -msse2 enabling on x86, http://crbug.com/9007
	epatch "${FILESDIR}"/${PN}-drop_sse2-r0.patch

	# Allow supporting more media types.
	epatch "${FILESDIR}"/${PN}-20100122-ubuntu-html5-video-mimetypes.patch

	# Fix build failure with libpng-1.4, bug 310959.
	epatch "${FILESDIR}"/${PN}-libpng-1.4.patch
}

src_configure() {
	export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser

	# Workaround for bug #318969.
	# TODO: remove when http://crbug.com/43778 is fixed.
	append-flags -D__STDC_CONSTANT_MACROS

	# Fails to build on arm if we don't do this
	use arm && append-flags -fno-tree-sink

	# Configuration options (system libraries)
	local myconf="-Duse_system_zlib=1 -Duse_system_bzip2=1 -Duse_system_ffmpeg=1 -Duse_system_libevent=1 -Duse_system_libjpeg=1 -Duse_system_libpng=1 -Duse_system_libxml=1 -Duse_system_libxslt=1"
	# -Duse_system_sqlite=1 : http://crbug.com/22208
	# Others still bundled: icu (not possible?), hunspell (changes required for sandbox support)

	# Sandbox paths
	myconf="${myconf} -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"

	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
	# and the performance gain isn't worth it.
	myconf="${myconf} -Dv8_use_snapshot=0"

	# Disable tcmalloc memory allocator. It causes problems,
	# for example bug #320419.
	myconf="${myconf} -Dlinux_use_tcmalloc=0"

	# Disable gpu rendering, it is incompatible with nvidia-drivers,
	# bug #319331.
	myconf="${myconf} -Denable_gpu=0"

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch = amd64 ]] ; then
		myconf="${myconf} -Dtarget_arch=x64"
	elif [[ $myarch = x86 ]] ; then
		myconf="${myconf} -Dtarget_arch=ia32"
	elif [[ $myarch = arm ]] ; then
		myconf="${myconf} -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi

	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
		myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
	fi

	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
	# Depending on GCC version the warnings are different and we don't want
	# the build to fail because of that.
	myconf="${myconf} -Dwerror="

	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
}

src_compile() {
	emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
		rootdir="${S}" \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		AR=$(tc-getAR) \
		RANLIB=$(tc-getRANLIB) \
		|| die "compilation failed"
}

src_install() {
	# Chromium does not have "install" target in the build system.
	export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser

	dodir ${CHROMIUM_HOME}

	exeinto ${CHROMIUM_HOME}
	pax-mark m out/Release/chrome
	doexe out/Release/chrome
	doexe out/Release/chrome_sandbox
	fperms 4755 ${CHROMIUM_HOME}/chrome_sandbox
	doexe out/Release/xdg-settings
	doexe "${FILESDIR}"/chromium-launcher.sh

	insinto ${CHROMIUM_HOME}
	doins out/Release/chrome.pak

	doins -r out/Release/locales
	doins -r out/Release/resources

	# chrome.1 is for chromium --help
	newman out/Release/chrome.1 chrome.1
	newman out/Release/chrome.1 chromium.1

	# Chromium looks for these in its folder
	# See media_posix.cc and base_paths_linux.cc
	dosym /usr/$(get_libdir)/libavcodec.so.52 ${CHROMIUM_HOME}
	dosym /usr/$(get_libdir)/libavformat.so.52 ${CHROMIUM_HOME}
	dosym /usr/$(get_libdir)/libavutil.so.50 ${CHROMIUM_HOME}

	# Plugins symlink, optional wrt bug #301911
	if use plugins-symlink; then
		dosym /usr/$(get_libdir)/nsbrowser/plugins ${CHROMIUM_HOME}/plugins
	fi

	# Icon and desktop entry
	newicon out/Release/product_logo_48.png ${PN}-browser.png
	dosym ${CHROMIUM_HOME}/chromium-launcher.sh /usr/bin/chromium
	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser"
	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
		|| die "desktop file sed failed"
	# Gnome default application entry
	dodir /usr/share/gnome-control-center/default-apps
	insinto /usr/share/gnome-control-center/default-apps
	doins "${FILESDIR}"/chromium.xml
}