[gentoo-commits] gentoo-x86 commit in media-sound/google-musicmanager: google-musicmanager-1.0.55.7425_beta-r2.ebuild ChangeLog google-musicmanager-1.0.55.7425_beta-r1.ebuild

[Christoph Junghans (ottxor)]

ottxor      13/02/26 03:27:46

  Modified:             ChangeLog
  Added:                google-musicmanager-1.0.55.7425_beta-r2.ebuild
  Removed:              google-musicmanager-1.0.55.7425_beta-r1.ebuild
  Log:
  fixed icons (thx to floppym, bug #459086)
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key C2000586)

Revision  Changes    Path
1.26                 media-sound/google-musicmanager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/google-musicmanager/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/google-musicmanager/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/google-musicmanager/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/google-musicmanager/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	9 Feb 2013 21:51:12 -0000	1.25
+++ ChangeLog	26 Feb 2013 03:27:46 -0000	1.26
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/google-musicmanager
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/google-musicmanager/ChangeLog,v 1.25 2013/02/09 21:51:12 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/google-musicmanager/ChangeLog,v 1.26 2013/02/26 03:27:46 ottxor Exp $
+
+*google-musicmanager-1.0.55.7425_beta-r2 (26 Feb 2013)
+
+  26 Feb 2013; Christoph Junghans <ottxor@g.o>
+  +google-musicmanager-1.0.55.7425_beta-r2.ebuild,
+  -google-musicmanager-1.0.55.7425_beta-r1.ebuild:
+  fixed icons (thx to floppym, bug #459086)
 
 *google-musicmanager-1.0.55.7425_beta-r1 (09 Feb 2013)
 



1.1                  media-sound/google-musicmanager/google-musicmanager-1.0.55.7425_beta-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/google-musicmanager/google-musicmanager-1.0.55.7425_beta-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/google-musicmanager/google-musicmanager-1.0.55.7425_beta-r2.ebuild?rev=1.1&content-type=text/plain

Index: google-musicmanager-1.0.55.7425_beta-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/google-musicmanager/google-musicmanager-1.0.55.7425_beta-r2.ebuild,v 1.1 2013/02/26 03:27:46 ottxor Exp $

EAPI=5

inherit eutils unpacker

MY_URL="http://dl.google.com/linux/musicmanager/deb/pool/main/${P:0:1}/${PN}-beta"
MY_PKG="${PN}-beta_${PV/_beta}-r0_i386.deb"

DESCRIPTION="Google Music Manager is a application for adding music to your Google Music library."
HOMEPAGE="http://music.google.com"
SRC_URI="x86? ( ${MY_URL}/${MY_PKG} )
	amd64? ( ${MY_URL}/${MY_PKG/i386/amd64} )"

LICENSE="Google-TOS Apache-2.0 MIT LGPL-2.1 gSOAP BSD FDL-1.2 MPL-1.1 openssl ZLIB libtiff"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="log"

RESTRICT="strip mirror"

RDEPEND="
	dev-libs/expat
	dev-libs/glib:2
	media-libs/flac
	media-libs/fontconfig
	media-libs/freetype:2
	media-libs/libogg
	media-libs/libvorbis
	net-dns/libidn
	sys-libs/glibc
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXi
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/qt-core:4
	x11-libs/qt-gui:4
	x11-libs/qt-webkit:4
	log? ( dev-libs/log4cxx )
	"

DEPEND="app-arch/xz-utils
	app-admin/chrpath"

INSTALL_BASE="opt/google/musicmanager"

QA_TEXTRELS="${INSTALL_BASE}/libmpgdec.so.0"

QA_FLAGS_IGNORED="${INSTALL_BASE}/.*"

S="${WORKDIR}/${INSTALL_BASE}"

pkg_nofetch() {
	einfo "This version is no longer available from Google."
	einfo "Note that Gentoo cannot mirror the distfiles due to license reasons, so we have to follow the bump."
	einfo "Please file a version bump bug on http://bugs.gentoo.org (search existing bugs for ${PN} first!)."
}

pkg_setup() {
	if type -p ifconfig > /dev/null && ! ifconfig | grep -q "^eth[0-9]" ; then
		ewarn "${PN} needs at least one network interface named eth[0-9] (bug #455896)"
	fi
}

src_install() {
	insinto "/${INSTALL_BASE}"
	doins config.xml product_logo*

	exeinto "/${INSTALL_BASE}"
	chrpath -d MusicManager || die
	doexe MusicManager google-musicmanager minidump_upload
	#TODO unbundle this
	doexe libaacdec.so libaudioenc.so.0 libmpgdec.so.0 libid3tag.so

	dosym /"${INSTALL_BASE}"/google-musicmanager /opt/bin/google-musicmanager

	local icon size
	for icon in product_logo_*.png; do
		size=${icon#product_logo_}
		size=${size%.png}
		newicon -s "${size}" "${icon}" ${PN}.png
	done
	domenu ${PN}.desktop
}