[gentoo-commits] gentoo-x86 commit in media-gfx/graphite2: ChangeLog graphite2-0.9.4-r1.ebuild graphite2-0.9.4.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    11/07/27 15:51:25

  Modified:             ChangeLog
  Added:                graphite2-0.9.4-r1.ebuild
  Removed:              graphite2-0.9.4.ebuild
  Log:
  Revision bump to fix multilib strictness. Fixes bug #376627.
  
  (Portage version: 2.2.0_alpha47/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  media-gfx/graphite2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphite2/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	27 Jul 2011 10:06:52 -0000	1.3
+++ ChangeLog	27 Jul 2011 15:51:25 -0000	1.4
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/graphite2
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphite2/ChangeLog,v 1.3 2011/07/27 10:06:52 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphite2/ChangeLog,v 1.4 2011/07/27 15:51:25 scarabeus Exp $
+
+*graphite2-0.9.4-r1 (27 Jul 2011)
+
+  27 Jul 2011; Tomáš Chvátal <scarabeus@g.o>
+  +files/graphite2-multilib-strict.patch, -graphite2-0.9.4.ebuild,
+  +graphite2-0.9.4-r1.ebuild:
+  Revision bump to fix multilib strictness. Fixes bug #376627.
 
   27 Jul 2011; Tomáš Chvátal <scarabeus@g.o> graphite2-0.9.4.ebuild:
   Fix CFLAGS parameters. Should fix build on gcc-4.6. Fixes bug #376567.



1.1                  media-gfx/graphite2/graphite2-0.9.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/graphite2-0.9.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/graphite2-0.9.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: graphite2-0.9.4-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphite2/graphite2-0.9.4-r1.ebuild,v 1.1 2011/07/27 15:51:25 scarabeus Exp $

EAPI=4

inherit base cmake-utils perl-module

DESCRIPTION="Library providing rendering capabilities for complex non-Roman writing systems"
HOMEPAGE="http://graphite.sil.org/"
SRC_URI="mirror://sourceforge/silgraphite/${PN}/${P}.tgz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="doc perl"

RDEPEND="
	dev-libs/glib:2
	media-libs/fontconfig
	perl? ( dev-lang/perl )
"
DEPEND="${RDEPEND}
	doc? (
		app-doc/doxygen
		dev-texlive/texlive-latex
	)
	perl? ( virtual/perl-Module-Build )
"

PATCHES=(
	"${FILESDIR}/${PN}-includes-libs-perl.patch"
	"${FILESDIR}/${PN}-disablefonttest.patch"
	"${FILESDIR}/${PN}-multilib-strict.patch"
)

pkg_setup() {
	use perl && perl-module_pkg_setup
}

src_prepare() {
	base_src_prepare

	# fix CFLAGS
	sed -i \
		-e 's:-nodefaultlibs -nostdlibs::' \
		src/CMakeLists.txt || die

	# fix perl linking
	if use perl; then
		_check_build_dir init
		sed -i \
			-e "s:@BUILD_DIR@:\"${CMAKE_BUILD_DIR}/src\":" \
			perl/Build.PL || die
	fi
}

src_configure() {
	local mycmakeargs=(
		"-DVM_MACHINE_TYPE=direct"
	)

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	use doc && Icmake-utils_src_compile docs
	if use perl; then
		cd perl
		perl-module_src_prep
		perl-module_src_compile
	fi
}

src_test() {
	cmake-utils_src_test
	if use perl; then
		cd perl
		perl-module_src_test
	fi
}

src_install() {
	cmake-utils_src_install
	if use perl; then
		cd perl
		perl-module_src_install
		fixlocalpod
	fi

	find "${ED}" -name '*.la' -exec rm -f {} +

	use doc && dodoc ${CMAKE_BUILD_DIR}/{manual.html,doxygen/latex/refman.pdf}
}