[gentoo-commits] gentoo-x86 commit in dev-python/astroid: astroid-1.0.1-r1.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/03/22 06:40:50

  Modified:             ChangeLog
  Added:                astroid-1.0.1-r1.ebuild
  Log:
  revbump; add optional dep for testsuite, update ebuild according re python impl deps fixes Bug #501550 by an eroen
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.2                  dev-python/astroid/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astroid/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astroid/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astroid/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/astroid/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	12 Feb 2014 08:03:26 -0000	1.1
+++ ChangeLog	22 Mar 2014 06:40:50 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/astroid
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/astroid/ChangeLog,v 1.1 2014/02/12 08:03:26 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/astroid/ChangeLog,v 1.2 2014/03/22 06:40:50 idella4 Exp $
+
+*astroid-1.0.1-r1 (22 Mar 2014)
+
+  22 Mar 2014; Ian Delaney <idella4@g.o> +astroid-1.0.1-r1.ebuild:
+  revbump; add optional dep for testsuite, update ebuild according re python
+  impl deps fixes Bug #501550 by an eroen
 
 *astroid-1.0.1 (12 Feb 2014)
 



1.1                  dev-python/astroid/astroid-1.0.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astroid/astroid-1.0.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astroid/astroid-1.0.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: astroid-1.0.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/astroid/astroid-1.0.1-r1.ebuild,v 1.1 2014/03/22 06:40:50 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )

inherit distutils-r1

DESCRIPTION="Abstract Syntax Tree for logilab packages"
HOMEPAGE="http://bitbucket.org/logilab/astroid http://pypi.python.org/pypi/astroid"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x86-macos"
IUSE="test"

# Version specified in __pkginfo__.py.
# pylint supports only Cpython
PY23_USEDEP=$(python_gen_usedep 'python2*' 'python3*')
RDEPEND=">=dev-python/logilab-common-0.60.0[${PYTHON_USEDEP}]"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( ${RDEPEND}
		>=dev-python/pylint-1.1.0[${PY23_USEDEP}] )"
# Required for tests
DISTUTILS_IN_SOURCE_BUILD=1

PY23_REQUSE="|| ( $(python_gen_useflags python2* python3*) )"
REQUIRED_USE="test? ( ${PY23_REQUSE} )"

python_prepare_all() {
	# https://bitbucket.org/logilab/astroid/issue/8/
	sed -e "s/test_numpy_crash/_&/" -i test/unittest_regrtest.py

	distutils-r1_python_prepare_all
}

python_test() {
	# https://bitbucket.org/logilab/astroid/issue/1/test-suite-fails-in-0243-under-py32-pypy
	# https://bitbucket.org/logilab/astroid/issue/16/1-test-fail-test_socket_build-under-pypy
	# test_hashlib fails only in py3.2
	python setup.py build

	pushd build/lib > /dev/null
	if [[ "${EPYTHON}" == pypy* ]]; then
		sed -e 's:test_socket_build:_&:' -i ${PN}/test/unittest_builder.py || die
	elif [[ "${EPYTHON}" == 'python3.2' ]]; then
		sed -e 's:test_hashlib:_&:' -i ${PN}/test/unittest_brain.py || die
	fi
	PYTHONPATH=. pytest || die "Tests fail with ${EPYTHON}"
	popd > /dev/null
}