[gentoo-commits] gentoo-x86 commit in media-sound/ncmpcpp: ChangeLog ncmpcpp-0.6.ebuild ncmpcpp-0.6_beta5.ebuild

[Jeroen Roovers (jer)]

jer         14/10/27 19:28:08

  Modified:             ChangeLog
  Added:                ncmpcpp-0.6.ebuild
  Removed:              ncmpcpp-0.6_beta5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.88                 media-sound/ncmpcpp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/ncmpcpp/ChangeLog?rev=1.88&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/ncmpcpp/ChangeLog?rev=1.88&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/ncmpcpp/ChangeLog?r1=1.87&r2=1.88

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ChangeLog,v
retrieving revision 1.87
retrieving revision 1.88
diff -u -r1.87 -r1.88
--- ChangeLog	7 Oct 2014 08:17:57 -0000	1.87
+++ ChangeLog	27 Oct 2014 19:28:08 -0000	1.88
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/ncmpcpp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ChangeLog,v 1.87 2014/10/07 08:17:57 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ChangeLog,v 1.88 2014/10/27 19:28:08 jer Exp $
+
+*ncmpcpp-0.6 (27 Oct 2014)
+
+  27 Oct 2014; Jeroen Roovers <jer@g.o> -ncmpcpp-0.6_beta5.ebuild,
+  +ncmpcpp-0.6.ebuild:
+  Version bump.
 
 *ncmpcpp-0.6_beta5 (07 Oct 2014)
 



1.1                  media-sound/ncmpcpp/ncmpcpp-0.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/ncmpcpp/ncmpcpp-0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/ncmpcpp/ncmpcpp-0.6.ebuild?rev=1.1&content-type=text/plain

Index: ncmpcpp-0.6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ncmpcpp-0.6.ebuild,v 1.1 2014/10/27 19:28:08 jer Exp $

EAPI=5
inherit bash-completion-r1 eutils

DESCRIPTION="featureful ncurses based MPD client inspired by ncmpc"
HOMEPAGE="http://ncmpcpp.rybczak.net/"
SRC_URI="http://ncmpcpp.rybczak.net/stable/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
IUSE="clock curl outputs taglib unicode visualizer"

RDEPEND="
	>=media-libs/libmpdclient-2.1
	curl? ( net-misc/curl )
	dev-libs/boost[nls]
	sys-libs/ncurses[unicode?]
	sys-libs/readline
	taglib? ( media-libs/taglib )
	visualizer? ( sci-libs/fftw:3.0 )
"
DEPEND="
	${RDEPEND}
	virtual/pkgconfig
"

src_prepare() {
	sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
	sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
}

src_configure() {
	econf \
		$(use_enable clock) \
		$(use_enable outputs) \
		$(use_enable unicode) \
		$(use_enable visualizer) \
		$(use_with curl) \
		$(use_with taglib) \
		$(use_with visualizer fftw) \
		--docdir=/usr/share/doc/${PF}
}

src_install() {
	default

	newbashcomp doc/${PN}-completion.bash ${PN}
}

pkg_postinst() {
	echo
	elog "Example configuration files have been installed at"
	elog "${ROOT}usr/share/doc/${PF}"
	elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/keys"
	elog "as user configuration files."
	echo
	if use visualizer; then
	elog "If you want to use the visualizer, you need mpd with fifo enabled."
	echo
	fi
}