[gentoo-commits] gentoo-x86 commit in www-client/chromium: ChangeLog chromium-5.0.396.0.ebuild chromium-5.0.375.38.ebuild chromium-9999.ebuild chromium-5.0.375.23.ebuild chromium-5.0.342.9.ebuild

[PaweA Hajdan (phajdan.jr)]

phajdan.jr    10/05/11 11:23:48

  Modified:             ChangeLog chromium-5.0.396.0.ebuild
                        chromium-9999.ebuild
  Added:                chromium-5.0.375.38.ebuild
  Removed:              chromium-5.0.375.23.ebuild
                        chromium-5.0.342.9.ebuild
  Log:
  Version bump for beta channel relase. Fix bug #315667 by Joel
  <Joel7987@×××××.com>, used suggestion by Constantine D. Kardaris
  <ckardaris@×××××.com>. Fix bug #318511 by cyrillic
  <cyrilmaley@×××××××.com>, used suggestion by truedfx. Fix bug #318573 by
  flameeyes, also note useful comment there by Reimar Doeffinger
  <Reimar.Doeffinger@×××.de>.
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.97                 www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.97&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.97&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.96&r2=1.97

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.96
retrieving revision 1.97
diff -u -r1.96 -r1.97
--- ChangeLog	7 May 2010 08:37:53 -0000	1.96
+++ ChangeLog	11 May 2010 11:23:48 -0000	1.97
@@ -1,6 +1,20 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.96 2010/05/07 08:37:53 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.97 2010/05/11 11:23:48 phajdan.jr Exp $
+
+*chromium-5.0.375.38 (11 May 2010)
+
+  11 May 2010; Pawel Hajdan jr <phajdan.jr@g.o>
+  -chromium-5.0.342.9.ebuild, -chromium-5.0.375.23.ebuild,
+  +chromium-5.0.375.38.ebuild, chromium-5.0.396.0.ebuild,
+  chromium-9999.ebuild, -files/chromium-fix-make-build.patch,
+  -files/chromium-gcc45.patch, files/chromium-launcher.sh:
+  Version bump for beta channel relase. Fix bug #315667 by Joel
+  <Joel7987@×××××.com>, used suggestion by Constantine D. Kardaris
+  <ckardaris@×××××.com>. Fix bug #318511 by cyrillic
+  <cyrilmaley@×××××××.com>, used suggestion by truedfx. Fix bug #318573 by
+  flameeyes, also note useful comment there by Reimar Doeffinger
+  <Reimar.Doeffinger@×××.de>. Remove old and clean up patches.
 
 *chromium-5.0.396.0 (07 May 2010)
 
@@ -218,7 +232,7 @@
   -chromium-5.0.307.5.ebuild, +chromium-5.0.335.0.ebuild:
   Version bump for dev channel release. Remove old.
 
-  23 Feb 2010; Raúl Porcel <armin76@g.o> chromium-5.0.322.2.ebuild,
+  23 Feb 2010; Raúl Porcel <armin76@g.o> chromium-5.0.322.2.ebuild,
   chromium-9999.ebuild:
   Add fix for arm build
 
@@ -289,7 +303,7 @@
   Dev channel release bump, also include gnome default-apps file from pacho
   in bug #303100
 
-  01 Feb 2010; Raúl Porcel <armin76@g.o> chromium-4.0.302.2.ebuild,
+  01 Feb 2010; Raúl Porcel <armin76@g.o> chromium-4.0.302.2.ebuild,
   chromium-9999.ebuild:
   Fix build on arm
 
@@ -338,11 +352,11 @@
   +chromium-4.0.302.2.ebuild:
   Version bump for dev channel release. Remove old.
 
-  22 Jan 2010; Raúl Porcel <armin76@g.o>
+  22 Jan 2010; Raúl Porcel <armin76@g.o>
   -files/chromium-drop_armel_m32.patch, chromium-9999.ebuild:
   Drop unneded arm patch
 
-  18 Jan 2010; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
+  18 Jan 2010; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
   chromium-4.0.288.1.ebuild, chromium-4.0.295.0.ebuild:
   Add ~arm
 
@@ -371,11 +385,11 @@
   +chromium-4.0.288.1.ebuild:
   Version bump for dev channel release.
 
-  07 Jan 2010; Raúl Porcel <armin76@g.o>
+  07 Jan 2010; Raúl Porcel <armin76@g.o>
   +files/chromium-drop_armel_m32.patch, chromium-9999.ebuild:
   Add patch to fix build on ARM, enable v8 build on ARM
 
-  25 Dec 2009; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
+  25 Dec 2009; Raúl Porcel <armin76@g.o> chromium-4.0.266.0.ebuild,
   chromium-9999.ebuild:
   Add arm support, but don't keyword it as its still a big buggy
 
@@ -440,7 +454,7 @@
   Version bump, enables bookmarks sync (with --enable-sync), and fix menu
   location for adblock+ extension
 
-  15 Nov 2009; Tomáš Chvátal <scarabeus@g.o> chromium-9999.ebuild:
+  15 Nov 2009; Tomáš Chvátal <scarabeus@g.o> chromium-9999.ebuild:
   QA: Drop keywords on live ebuilds.
 
   09 Nov 2009; Bernard Cafarelli <voyageur@g.o>



1.2                  www-client/chromium/chromium-5.0.396.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.396.0.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.396.0.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.396.0.ebuild?r1=1.1&r2=1.2

Index: chromium-5.0.396.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.396.0.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- chromium-5.0.396.0.ebuild	7 May 2010 08:37:53 -0000	1.1
+++ chromium-5.0.396.0.ebuild	11 May 2010 11:23:48 -0000	1.2
@@ -1,9 +1,10 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.396.0.ebuild,v 1.1 2010/05/07 08:37:53 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.396.0.ebuild,v 1.2 2010/05/11 11:23:48 phajdan.jr Exp $
 
 EAPI="2"
-inherit eutils flag-o-matic multilib portability toolchain-funcs
+
+inherit eutils flag-o-matic multilib pax-utils toolchain-funcs
 
 DESCRIPTION="Open-source version of Google Chrome web browser"
 HOMEPAGE="http://chromium.org/"
@@ -12,7 +13,7 @@
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~x86"
-IUSE="mp3 +plugins-symlink x264"
+IUSE="+plugins-symlink"
 
 RDEPEND="app-arch/bzip2
 	>=dev-libs/libevent-1.4.13
@@ -23,7 +24,7 @@
 	>=media-libs/alsa-lib-1.0.19
 	media-libs/jpeg:0
 	media-libs/libpng
-	>=media-video/ffmpeg-0.5_p21602[mp3=,threads,x264=]
+	>=media-video/ffmpeg-0.5_p21602[threads]
 	sys-libs/zlib
 	>=x11-libs/gtk+-2.14.7
 	x11-libs/libXScrnSaver"
@@ -40,6 +41,7 @@
 		x11-themes/tango-icon-theme
 		x11-themes/xfce4-icon-theme
 	)
+	x11-apps/xmessage
 	x11-misc/xdg-utils
 	virtual/ttf-fonts"
 
@@ -50,32 +52,9 @@
 		!www-plugins/gecko-mediaplayer[gnome]
 	)"
 
-pkg_setup() {
-	if [[ "${ROOT}" == "/" ]]; then
-		# Prevent user problems like bug 299777.
-		if ! grep -q /dev/shm <<< $(get_mounts); then
-			eerror "You don't have tmpfs mounted at /dev/shm."
-			eerror "${PN} isn't going to work in that configuration."
-			eerror "Please uncomment the /dev/shm entry in /etc/fstab,"
-			eerror "run 'mount /dev/shm' and try again."
-			die "/dev/shm is not mounted"
-		fi
-		if [ `stat -c %a /dev/shm` -ne 1777 ]; then
-			eerror "/dev/shm does not have correct permissions."
-			eerror "${PN} isn't going to work in that configuration."
-			eerror "Please run chmod 1777 /dev/shm and try again."
-			die "/dev/shm has incorrect permissions"
-		fi
-	fi
-
-	elog "${PN} might crash occasionally. To get more useful backtraces"
-	elog "and submit better bug reports, please read"
-	elog "http://www.gentoo.org/proj/en/qa/backtraces.xml"
-}
-
 src_prepare() {
-	# Allow supporting more media types provided system ffmpeg supports them.
-	epatch "${FILESDIR}"/${PN}-supported-media-mime-types.patch
+	# Allow supporting more media types.
+	epatch "${FILESDIR}"/${PN}-20100122-ubuntu-html5-video-mimetypes.patch
 }
 
 src_configure() {
@@ -84,14 +63,6 @@
 	# Fails to build on arm if we don't do this
 	use arm && append-flags -fno-tree-sink
 
-	if use mp3 ; then
-		append-cflags -DGENTOO_CHROMIUM_MP3_ENABLED
-	fi
-
-	if use x264 ; then
-		append-cflags -DGENTOO_CHROMIUM_H264_ENABLED
-	fi
-
 	# CFLAGS/LDFLAGS
 	mkdir -p "${S}"/.gyp || die "cflags mkdir failed"
 	cat << EOF > "${S}"/.gyp/include.gypi || die "cflags cat failed"
@@ -159,6 +130,7 @@
 	dodir ${CHROMIUM_HOME}
 
 	exeinto ${CHROMIUM_HOME}
+	pax-mark m out/Release/chrome
 	doexe out/Release/chrome
 	doexe out/Release/chrome_sandbox
 	fperms 4755 ${CHROMIUM_HOME}/chrome_sandbox



1.50                 www-client/chromium/chromium-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.49&r2=1.50

Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- chromium-9999.ebuild	5 May 2010 12:33:26 -0000	1.49
+++ chromium-9999.ebuild	11 May 2010 11:23:48 -0000	1.50
@@ -1,9 +1,10 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.49 2010/05/05 12:33:26 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.50 2010/05/11 11:23:48 phajdan.jr Exp $
 
 EAPI="2"
-inherit eutils flag-o-matic multilib portability subversion toolchain-funcs
+
+inherit eutils flag-o-matic multilib pax-utils subversion toolchain-funcs
 
 DESCRIPTION="Open-source version of Google Chrome web browser"
 HOMEPAGE="http://chromium.org/"
@@ -14,7 +15,7 @@
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS=""
-IUSE="mp3 +plugins-symlink x264"
+IUSE="+plugins-symlink"
 
 RDEPEND="app-arch/bzip2
 	>=dev-libs/libevent-1.4.13
@@ -25,7 +26,7 @@
 	>=media-libs/alsa-lib-1.0.19
 	media-libs/jpeg:0
 	media-libs/libpng
-	>=media-video/ffmpeg-0.5_p21602[mp3=,threads,x264=]
+	>=media-video/ffmpeg-0.5_p21602[threads]
 	sys-libs/zlib
 	>=x11-libs/gtk+-2.14.7
 	x11-libs/libXScrnSaver"
@@ -42,6 +43,7 @@
 		x11-themes/tango-icon-theme
 		x11-themes/xfce4-icon-theme
 	)
+	x11-apps/xmessage
 	x11-misc/xdg-utils
 	virtual/ttf-fonts"
 
@@ -52,29 +54,6 @@
 		!www-plugins/gecko-mediaplayer[gnome]
 	)"
 
-pkg_setup() {
-	if [[ "${ROOT}" == "/" ]]; then
-		# Prevent user problems like bug 299777.
-		if ! grep -q /dev/shm <<< $(get_mounts); then
-			eerror "You don't have tmpfs mounted at /dev/shm."
-			eerror "${PN} isn't going to work in that configuration."
-			eerror "Please uncomment the /dev/shm entry in /etc/fstab,"
-			eerror "run 'mount /dev/shm' and try again."
-			die "/dev/shm is not mounted"
-		fi
-		if [ `stat -c %a /dev/shm` -ne 1777 ]; then
-			eerror "/dev/shm does not have correct permissions."
-			eerror "${PN} isn't going to work in that configuration."
-			eerror "Please run chmod 1777 /dev/shm and try again."
-			die "/dev/shm has incorrect permissions"
-		fi
-	fi
-
-	elog "${PN} might crash occasionally. To get more useful backtraces"
-	elog "and submit better bug reports, please read"
-	elog "http://www.gentoo.org/proj/en/qa/backtraces.xml"
-}
-
 src_unpack() {
 	subversion_src_unpack
 	mv "${S}" "${WORKDIR}"/depot_tools
@@ -119,8 +98,8 @@
 }
 
 src_prepare() {
-	# Allow supporting more media types provided system ffmpeg supports them.
-	epatch "${FILESDIR}"/${PN}-supported-media-mime-types.patch
+	# Allow supporting more media types.
+	epatch "${FILESDIR}"/${PN}-20100122-ubuntu-html5-video-mimetypes.patch
 }
 
 src_configure() {
@@ -128,14 +107,6 @@
 	# Fails to build on arm if we don't do this
 	use arm && append-flags -fno-tree-sink
 
-	if use mp3 ; then
-		append-cflags -DGENTOO_CHROMIUM_MP3_ENABLED
-	fi
-
-	if use x264 ; then
-		append-cflags -DGENTOO_CHROMIUM_H264_ENABLED
-	fi
-
 	# CFLAGS/LDFLAGS
 	mkdir -p "${S}"/.gyp || die "cflags mkdir failed"
 	cat << EOF > "${S}"/.gyp/include.gypi || die "cflags cat failed"
@@ -203,6 +174,7 @@
 	dodir ${CHROMIUM_HOME}
 
 	exeinto ${CHROMIUM_HOME}
+	pax-mark m out/Release/chrome
 	doexe out/Release/chrome
 	doexe out/Release/chrome_sandbox
 	fperms 4755 ${CHROMIUM_HOME}/chrome_sandbox



1.1                  www-client/chromium/chromium-5.0.375.38.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.38.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-5.0.375.38.ebuild?rev=1.1&content-type=text/plain

Index: chromium-5.0.375.38.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-5.0.375.38.ebuild,v 1.1 2010/05/11 11:23:48 phajdan.jr Exp $

EAPI="2"

inherit eutils flag-o-matic multilib pax-utils toolchain-funcs

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="+plugins-symlink"

RDEPEND="app-arch/bzip2
	>=dev-libs/libevent-1.4.13
	dev-libs/libxml2
	dev-libs/libxslt
	>=dev-libs/nss-3.12.3
	>=gnome-base/gconf-2.24.0
	>=media-libs/alsa-lib-1.0.19
	media-libs/jpeg:0
	media-libs/libpng
	>=media-video/ffmpeg-0.5_p21602[threads]
	sys-libs/zlib
	>=x11-libs/gtk+-2.14.7
	x11-libs/libXScrnSaver"
#	dev-db/sqlite:3
DEPEND="${RDEPEND}
	dev-lang/perl
	>=dev-util/gperf-3.0.3
	>=dev-util/pkgconfig-0.23
	sys-devel/flex"
RDEPEND+="
	|| (
		x11-themes/gnome-icon-theme
		x11-themes/oxygen-molecule
		x11-themes/tango-icon-theme
		x11-themes/xfce4-icon-theme
	)
	x11-apps/xmessage
	x11-misc/xdg-utils
	virtual/ttf-fonts"

# Incompatible system plugins:
# www-plugins/gecko-mediaplayer, bug #309231.
RDEPEND+="
	plugins-symlink? (
		!www-plugins/gecko-mediaplayer[gnome]
	)"

src_prepare() {
	# Prevent automatic -march=pentium4 -msse2 enabling on x86, http://crbug.com/9007
	epatch "${FILESDIR}"/${PN}-drop_sse2-r0.patch

	# Allow supporting more media types.
	epatch "${FILESDIR}"/${PN}-20100122-ubuntu-html5-video-mimetypes.patch

	# Fix build failure with libpng-1.4, bug 310959.
	epatch "${FILESDIR}"/${PN}-libpng-1.4.patch
}

src_configure() {
	export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser

	# Fails to build on arm if we don't do this
	use arm && append-flags -fno-tree-sink

	# CFLAGS/LDFLAGS
	mkdir -p "${S}"/.gyp || die "cflags mkdir failed"
	cat << EOF > "${S}"/.gyp/include.gypi || die "cflags cat failed"
{
	'target_defaults': {
		'cflags': [ '${CFLAGS// /','}' ],
		'ldflags': [ '${LDFLAGS// /','}' ],
	},
}
EOF
	export HOME="${S}"

	# Configuration options (system libraries)
	local myconf="-Duse_system_zlib=1 -Duse_system_bzip2=1 -Duse_system_ffmpeg=1 -Duse_system_libevent=1 -Duse_system_libjpeg=1 -Duse_system_libpng=1 -Duse_system_libxml=1 -Duse_system_libxslt=1"
	# -Duse_system_sqlite=1 : http://crbug.com/22208
	# Others still bundled: icu (not possible?), hunspell (changes required for sandbox support)

	# Sandbox paths
	myconf="${myconf} -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"

	# Disable the V8 snapshot. It breaks the build on hardened (bug #301880),
	# and the performance gain isn't worth it.
	myconf="${myconf} -Dv8_use_snapshot=0"

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch = amd64 ]] ; then
		myconf="${myconf} -Dtarget_arch=x64"
	elif [[ $myarch = x86 ]] ; then
		myconf="${myconf} -Dtarget_arch=ia32"
	elif [[ $myarch = arm ]] ; then
		myconf="${myconf} -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi

	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
		myconf="${myconf} -Dno_strict_aliasing=1 -Dgcc_version=44"
	fi

	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
	# Depending on GCC version the warnings are different and we don't want
	# the build to fail because of that.
	myconf="${myconf} -Dwerror="

	build/gyp_chromium -f make build/all.gyp ${myconf} --depth=. || die "gyp failed"
}

src_compile() {
	emake -r V=1 chrome chrome_sandbox BUILDTYPE=Release \
		rootdir="${S}" \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		AR=$(tc-getAR) \
		RANLIB=$(tc-getRANLIB) \
		|| die "compilation failed"
}

src_install() {
	# Chromium does not have "install" target in the build system.
	export CHROMIUM_HOME=/usr/$(get_libdir)/chromium-browser

	dodir ${CHROMIUM_HOME}

	exeinto ${CHROMIUM_HOME}
	pax-mark m out/Release/chrome
	doexe out/Release/chrome
	doexe out/Release/chrome_sandbox
	fperms 4755 ${CHROMIUM_HOME}/chrome_sandbox
	doexe out/Release/xdg-settings
	doexe "${FILESDIR}"/chromium-launcher.sh

	insinto ${CHROMIUM_HOME}
	doins out/Release/chrome.pak

	doins -r out/Release/locales
	doins -r out/Release/resources

	# chrome.1 is for chromium --help
	newman out/Release/chrome.1 chrome.1
	newman out/Release/chrome.1 chromium.1

	# Chromium looks for these in its folder
	# See media_posix.cc and base_paths_linux.cc
	dosym /usr/$(get_libdir)/libavcodec.so.52 ${CHROMIUM_HOME}
	dosym /usr/$(get_libdir)/libavformat.so.52 ${CHROMIUM_HOME}
	dosym /usr/$(get_libdir)/libavutil.so.50 ${CHROMIUM_HOME}

	# Plugins symlink, optional wrt bug #301911
	if use plugins-symlink; then
		dosym /usr/$(get_libdir)/nsbrowser/plugins ${CHROMIUM_HOME}/plugins
	fi

	# Icon and desktop entry
	newicon out/Release/product_logo_48.png ${PN}-browser.png
	dosym ${CHROMIUM_HOME}/chromium-launcher.sh /usr/bin/chromium
	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser"
	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop \
		|| die "desktop file sed failed"
	# Gnome default application entry
	dodir /usr/share/gnome-control-center/default-apps
	insinto /usr/share/gnome-control-center/default-apps
	doins "${FILESDIR}"/chromium.xml
}