[gentoo-commits] gentoo-x86 commit in mail-mta/netqmail: netqmail-1.06-r2.ebuild netqmail-1.06-r1.ebuild ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     13/05/27 00:45:52

  Modified:             netqmail-1.06-r1.ebuild ChangeLog
  Added:                netqmail-1.06-r2.ebuild
  Log:
  Fix security bug #372967. Also fixes bugs #335077, #331901, #370611, #403893, #404225.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.2                  mail-mta/netqmail/netqmail-1.06-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r1.ebuild?r1=1.1&r2=1.2

Index: netqmail-1.06-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -p -w -b -B -u -u -r1.1 -r1.2
--- netqmail-1.06-r1.ebuild	15 Apr 2013 22:55:10 -0000	1.1
+++ netqmail-1.06-r1.ebuild	27 May 2013 00:45:52 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r1.ebuild,v 1.1 2013/04/15 22:55:10 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r1.ebuild,v 1.2 2013/05/27 00:45:52 robbat2 Exp $
 
 EAPI=5
 
@@ -94,7 +94,11 @@ src_prepare() {
 	ht_fix_file Makefile*
 
 	if ! use vanilla; then
-		use ssl        && epatch "${DISTDIR}"/${QMAIL_TLS_F}
+		# This patch contains relative paths and needs to be cleaned up.
+		sed 's~^--- ../../~--- ~g' \
+			<"${DISTDIR}"/${QMAIL_TLS_F} \
+			>"${T}"/${QMAIL_TLS_F}
+		use ssl        && epatch "${T}"/${QMAIL_TLS_F}
 		use highvolume && epatch "${DISTDIR}"/${QMAIL_BIGTODO_F}
 
 		if use qmail-spp; then



1.63                 mail-mta/netqmail/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-mta/netqmail/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -p -w -b -B -u -u -r1.62 -r1.63
--- ChangeLog	15 Apr 2013 22:55:10 -0000	1.62
+++ ChangeLog	27 May 2013 00:45:52 -0000	1.63
@@ -1,6 +1,15 @@
 # ChangeLog for mail-mta/netqmail
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-mta/netqmail/ChangeLog,v 1.62 2013/04/15 22:55:10 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/netqmail/ChangeLog,v 1.63 2013/05/27 00:45:52 robbat2 Exp $
+
+*netqmail-1.06-r2 (27 May 2013)
+
+  27 May 2013; Robin H. Johnson <robbat2@g.o>
+  +files/genqmail-20080406-ldflags.patch, +netqmail-1.06-r2.ebuild,
+  files/conf-common, files/conf-qmqpd, files/conf-qmtpd, files/conf-smtpd,
+  files/servercert.cnf, netqmail-1.06-r1.ebuild:
+  Fix security bug #372967. Also fixes bugs #335077, #331901, #370611, #403893,
+  #404225.
 
 *netqmail-1.06-r1 (15 Apr 2013)
 



1.1                  mail-mta/netqmail/netqmail-1.06-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r2.ebuild?rev=1.1&content-type=text/plain

Index: netqmail-1.06-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-mta/netqmail/netqmail-1.06-r2.ebuild,v 1.1 2013/05/27 00:45:52 robbat2 Exp $

EAPI=5

GENQMAIL_PV=20080406
QMAIL_SPP_PV=0.42

QMAIL_TLS_PV=20070417
QMAIL_TLS_F=${PN}-1.05-tls-smtpauth-${QMAIL_TLS_PV}.patch
QMAIL_TLS_CVE=vu555316.patch

QMAIL_BIGTODO_PV=103
QMAIL_BIGTODO_F=big-todo.${QMAIL_BIGTODO_PV}.patch

QMAIL_LARGE_DNS='qmail-103.patch'

inherit eutils qmail

DESCRIPTION="qmail -- a secure, reliable, efficient, simple message transfer agent"
HOMEPAGE="
	http://netqmail.org
	http://cr.yp.to/qmail.html
	http://qmail.org
"
SRC_URI="mirror://qmail/${P}.tar.gz
	http://dev.gentoo.org/~hollow/distfiles/${GENQMAIL_F}
	http://www.ckdhr.com/ckd/${QMAIL_LARGE_DNS}
	http://inoa.net/qmail-tls/${QMAIL_TLS_CVE}
	!vanilla? (
		highvolume? ( mirror://qmail/${QMAIL_BIGTODO_F} )
		qmail-spp? ( mirror://sourceforge/qmail-spp/${QMAIL_SPP_F} )
		ssl? ( http://shupp.org/patches/${QMAIL_TLS_F} )
	)
"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="authcram gencertdaily highvolume qmail-spp ssl vanilla"
REQUIRED_USE='vanilla? ( !ssl !qmail-spp !highvolume )'
RESTRICT="test"

DEPEND="
	!mail-mta/qmail
	net-mail/queue-repair
	ssl? ( dev-libs/openssl )
	sys-apps/groff
"
RDEPEND="
	!mail-mta/courier
	!mail-mta/esmtp
	!mail-mta/exim
	!mail-mta/mini-qmail
	!mail-mta/msmtp[mta]
	!mail-mta/nullmailer
	!mail-mta/postfix
	!mail-mta/qmail-ldap
	!mail-mta/sendmail
	!<mail-mta/ssmtp-2.64-r2
	!>=mail-mta/ssmtp-2.64-r2[mta]
	>=sys-apps/ucspi-tcp-0.88-r17
	ssl? ( >=sys-apps/ucspi-ssl-0.70-r1 )
	virtual/daemontools
	>=net-mail/dot-forward-0.71-r3
	virtual/checkpassword
	authcram? ( >=net-mail/cmd5checkpw-0.30 )
	${DEPEND}
"

pkg_setup() {
	if [[ -n "${QMAIL_PATCH_DIR}" ]]; then
		eerror
		eerror "The QMAIL_PATCH_DIR variable for custom patches"
		eerror "has been removed from ${PN}. If you need custom patches"
		eerror "you should create a copy of this ebuild in an overlay."
		eerror
		die "QMAIL_PATCH_DIR is not supported anymore"
	fi

	qmail_create_users
}

src_unpack() {
	genqmail_src_unpack
	use qmail-spp && qmail_spp_src_unpack

	unpack ${P}.tar.gz
}

src_prepare() {
	epatch "${FILESDIR}"/${PV}-exit.patch
	epatch "${FILESDIR}"/${PV}-readwrite.patch
	epatch "${DISTDIR}"/${QMAIL_LARGE_DNS}

	ht_fix_file Makefile*

	if ! use vanilla; then
		# This patch contains relative paths and needs to be cleaned up.
		sed 's~^--- ../../~--- ~g' \
			<"${DISTDIR}"/${QMAIL_TLS_F} \
			>"${T}"/${QMAIL_TLS_F}
		use ssl        && epatch "${T}"/${QMAIL_TLS_F}
		use ssl        && epatch "${DISTDIR}"/${QMAIL_TLS_CVE}
		use highvolume && epatch "${DISTDIR}"/${QMAIL_BIGTODO_F}

		if use qmail-spp; then
			if use ssl; then
				epatch "${QMAIL_SPP_S}"/qmail-spp-smtpauth-tls-20060105.diff
			else
				epatch "${QMAIL_SPP_S}"/netqmail-spp.diff
			fi
			cd "${WORKDIR}"
			epatch "${FILESDIR}"/genqmail-20080406-ldflags.patch
			cd -
		fi
	fi

	qmail_src_postunpack

	# Fix bug #33818 but for netqmail (Bug 137015)
	if ! use authcram; then
		einfo "Disabled CRAM_MD5 support"
		sed -e 's,^#define CRAM_MD5$,/*&*/,' -i "${S}"/qmail-smtpd.c
	else
		einfo "Enabled CRAM_MD5 support"
	fi
}

src_compile() {
	qmail_src_compile
	use qmail-spp && qmail_spp_src_compile
}

src_install() {
	qmail_src_install
}

pkg_postinst() {
	qmail_queue_setup
	qmail_rootmail_fixup
	qmail_tcprules_build

	qmail_config_notice
	qmail_supervise_config_notice
	elog
	elog "If you are looking for documentation, check those links:"
	elog "http://www.gentoo.org/doc/en/qmail-howto.xml"
	elog "  -- qmail/vpopmail Virtual Mail Hosting System Guide"
	elog "http://www.lifewithqmail.com/"
	elog "  -- Life with qmail"
	elog
}

pkg_preinst() {
	qmail_tcprules_fixup
}

pkg_config() {
	# avoid some weird locale problems
	export LC_ALL=C

	qmail_config_fast
	qmail_tcprules_config
	qmail_tcprules_build

	use ssl && qmail_ssl_generate
}