[gentoo-commits] gentoo-x86 commit in net-libs/nodejs: nodejs-0.10.30.ebuild nodejs-0.8.28.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     14/08/01 06:02:08

  Modified:             ChangeLog
  Added:                nodejs-0.10.30.ebuild nodejs-0.8.28.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.124                net-libs/nodejs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?rev=1.124&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?rev=1.124&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/ChangeLog?r1=1.123&r2=1.124

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v
retrieving revision 1.123
retrieving revision 1.124
diff -u -r1.123 -r1.124
--- ChangeLog	23 Jul 2014 03:51:35 -0000	1.123
+++ ChangeLog	1 Aug 2014 06:02:08 -0000	1.124
@@ -1,6 +1,13 @@
 # ChangeLog for net-libs/nodejs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v 1.123 2014/07/23 03:51:35 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/ChangeLog,v 1.124 2014/08/01 06:02:08 patrick Exp $
+
+*nodejs-0.10.30 (01 Aug 2014)
+*nodejs-0.8.28 (01 Aug 2014)
+
+  01 Aug 2014; Patrick Lauer <patrick@g.o> +nodejs-0.10.30.ebuild,
+  +nodejs-0.8.28.ebuild:
+  Bump
 
 *nodejs-0.11.13-r1 (23 Jul 2014)
 



1.1                  net-libs/nodejs/nodejs-0.10.30.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.10.30.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.10.30.ebuild?rev=1.1&content-type=text/plain

Index: nodejs-0.10.30.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/nodejs-0.10.30.ebuild,v 1.1 2014/08/01 06:02:08 patrick Exp $

EAPI=5

# has known failures. sigh.
RESTRICT="test"

PYTHON_COMPAT=( python2_{6,7} )

inherit python-any-r1 pax-utils toolchain-funcs

DESCRIPTION="Evented IO for V8 Javascript"
HOMEPAGE="http://nodejs.org/"
SRC_URI="http://nodejs.org/dist/v${PV}/node-v${PV}.tar.gz"

LICENSE="Apache-1.1 Apache-2.0 BSD BSD-2 MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
IUSE="+npm +snapshot"

RDEPEND="dev-libs/openssl"
DEPEND="${PYTHON_DEPS}
	${RDEPEND}"

S=${WORKDIR}/node-v${PV}

src_prepare() {
	# fix compilation on Darwin
	# http://code.google.com/p/gyp/issues/detail?id=260
	sed -i -e "/append('-arch/d" tools/gyp/pylib/gyp/xcode_emulation.py || die

	# make sure we use python2.* while using gyp
	sed -i -e  "s/python/python2/" deps/npm/node_modules/node-gyp/gyp/gyp || die

	# less verbose install output (stating the same as portage, basically)
	sed -i -e "/print/d" tools/install.py || die

	tc-export CC CXX
}

src_configure() {
	local myconf=""
	! use npm && myconf="--without-npm"
	! use snapshot && myconf="${myconf} --without-snapshot"

	"${PYTHON}" configure --prefix="${EPREFIX}"/usr \
		--shared-openssl --shared-zlib --without-dtrace ${myconf} || die
}

src_compile() {
	local V=1
	export V
	emake out/Makefile
	emake -C out mksnapshot
	pax-mark m out/Release/mksnapshot
	emake
}

src_install() {
	"${PYTHON}" tools/install.py install "${D}"

	use npm && dohtml -r "${ED}"/usr/lib/node_modules/npm/html/*
	rm -rf "${ED}"/usr/lib/node_modules/npm/doc "${ED}"/usr/lib/node_modules/npm/html
	rm -rf "${ED}"/usr/lib/dtrace

	pax-mark -m "${ED}"/usr/bin/node
}

src_test() {
	"${PYTHON}" tools/test.py --mode=release simple message || die
}



1.1                  net-libs/nodejs/nodejs-0.8.28.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.8.28.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/nodejs/nodejs-0.8.28.ebuild?rev=1.1&content-type=text/plain

Index: nodejs-0.8.28.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/nodejs/nodejs-0.8.28.ebuild,v 1.1 2014/08/01 06:02:08 patrick Exp $

EAPI=5

PYTHON_DEPEND="2"

inherit python eutils multilib pax-utils

# omgwtf
RESTRICT="test"

DESCRIPTION="Evented IO for V8 Javascript"
HOMEPAGE="http://nodejs.org/"
SRC_URI="http://nodejs.org/dist/v${PV}/node-v${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
IUSE=""

DEPEND="dev-libs/openssl"
RDEPEND="${PYTHON_DEPS}
	${DEPEND}"

S=${WORKDIR}/node-v${PV}

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# fix compilation on Darwin
	# http://code.google.com/p/gyp/issues/detail?id=260
	sed -i -e "/append('-arch/d" tools/gyp/pylib/gyp/xcode_emulation.py || die
	python_convert_shebangs 2 tools/node-waf || die
}

src_configure() {
	# this is an autotools lookalike confuserator
	./configure --prefix="${EPREFIX}"/usr --openssl-use-sys --shared-zlib || die
}

src_compile() {
	emake || die
}

src_install() {
	local MYLIB=$(get_libdir)
	mkdir -p "${ED}"/usr/include/node
	mkdir -p "${ED}"/usr/bin
	mkdir -p "${ED}"/usr/"${MYLIB}"/node_modules/npm
	mkdir -p "${ED}"/usr/"${MYLIB}"/node
	cp 'src/eio-emul.h' 'src/ev-emul.h' 'src/node.h' 'src/node_buffer.h' 'src/node_object_wrap.h' 'src/node_version.h' "${ED}"/usr/include/node || die "Failed to copy stuff"
	cp -R deps/uv/include/* "${ED}"/usr/include/node || die "Failed to copy stuff"
	cp -R deps/v8/include/* "${ED}"/usr/include/node || die "Failed to copy stuff"
	cp 'out/Release/node' "${ED}"/usr/bin/node || die "Failed to copy stuff"
	cp -R deps/npm/* "${ED}"/usr/"${MYLIB}"/node_modules/npm || die "Failed to copy stuff"
	cp -R tools/wafadmin "${ED}"/usr/"${MYLIB}"/node/ || die "Failed to copy stuff"
	cp 'tools/node-waf' "${ED}"/usr/bin/ || die "Failed to copy stuff"

	# now add some extra stupid just because we can
	# needs to be a symlink because of hardcoded paths ... no es bueno!
	dosym /usr/"${MYLIB}"/node_modules/npm/bin/npm-cli.js /usr/bin/npm
	pax-mark -m "${ED}"/usr/bin/node
}

src_test() {
	emake test || die
}