[gentoo-commits] repo/gentoo:master commit in: sys-devel/bc/

[Mike Frysinger]

commit:     d5211fff3db25183146af1d0ccadd89f5ef3f52c
Author:     Mike Frysinger <vapier <AT> chromium <DOT> org>
AuthorDate: Fri Sep  9 08:10:48 2022 +0000
Commit:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
CommitDate: Fri Sep  9 08:13:04 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d5211fff

sys-devel/bc: enable LFS flags #471102

Minor change for a minor tool, but easy enough to fill out short of
upstream ever updating the autotool usage directly.

Signed-off-by: Mike Frysinger <vapier <AT> gentoo.org>

 sys-devel/bc/bc-1.07.1-r5.ebuild | 62 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/sys-devel/bc/bc-1.07.1-r5.ebuild b/sys-devel/bc/bc-1.07.1-r5.ebuild
new file mode 100644
index 000000000000..f9c1a2daa3e5
--- /dev/null
+++ b/sys-devel/bc/bc-1.07.1-r5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Handy console-based calculator utility"
+HOMEPAGE="https://www.gnu.org/software/bc/bc.html"
+SRC_URI="mirror://gnu/bc/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="libedit readline static"
+
+RDEPEND="
+	!readline? ( libedit? ( dev-libs/libedit:= ) )
+	readline? (
+		sys-libs/readline:=
+		sys-libs/ncurses:=
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/flex
+	virtual/yacc"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.07.1-no-ed-its-sed.patch )
+
+src_prepare() {
+	default
+
+	# Avoid bad build tool usage when cross-compiling. Bug #627126
+	tc-is-cross-compiler && eapply "${FILESDIR}"/${PN}-1.07.1-use-system-bc.patch
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with readline)
+	)
+	if use readline ; then
+		myconf+=( --without-libedit )
+	else
+		myconf+=( $(use_with libedit) )
+	fi
+	use static && append-ldflags -static
+
+	# AC_SYS_LARGEFILE in configure.ac would handle this, but we don't patch
+	# autotools otherwise currently.  This change has been sent upstream, but
+	# who knows when they'll make another release.
+	append-lfs-flags
+
+	econf "${myconf[@]}"
+
+	# Do not regen docs -- configure produces a small fragment that includes
+	# the version info which causes all pages to regen (newer file). Bug #554774
+	touch -r doc doc/* || die
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}