[gentoo-commits] gentoo-x86 commit in sys-cluster/galera: galera-25.3.5.ebuild metadata.xml ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     14/07/30 06:26:05

  Added:                galera-25.3.5.ebuild metadata.xml ChangeLog
  Log:
  Bring MariaDB-Galera from the overlay into the tree. Thanks to the great work of Brian Evans <grknight@g.o>.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.1                  sys-cluster/galera/galera-25.3.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/galera/galera-25.3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/galera/galera-25.3.5.ebuild?rev=1.1&content-type=text/plain

Index: galera-25.3.5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/galera-25.3.5.ebuild,v 1.1 2014/07/30 06:26:05 robbat2 Exp $

EAPI=5

MY_P="${PN}-${PV}-src"

inherit scons-utils multilib toolchain-funcs base versionator eutils
DESCRIPTION="Synchronous multi-master replication engine that provides its service through wsrep API"
HOMEPAGE="http://www.codership.org/"
SRC_URI="https://launchpad.net/${PN}/$(get_version_component_range 2).x/${PV}/+download/${MY_P}.tar.gz"
LICENSE="GPL-2 BSD"

SLOT="0"

KEYWORDS="~amd64 ~x86"
IUSE="garbd ssl test"

CDEPEND="
	 ssl? ( dev-libs/openssl )
	>=dev-libs/boost-1.41
	"
DEPEND="${DEPEND}
	${CDEPEND}
	dev-libs/check
	>=sys-devel/gcc-4.4
	>=dev-cpp/asio-1.4.8[ssl?]
	"
#Run time only
RDEPEND="${CDEPEND}
	garbd? ( || (
		net-analyzer/netcat
		net-analyzer/netcat6
		net-analyzer/gnu-netcat
		net-analyzer/openbsd-netcat
	) )"

S="${WORKDIR}/${MY_P}"

pkg_preinst() {
	if use garbd ; then
		enewgroup garbd
		enewuser garbd
	fi
}

src_prepare() {
	# Remove bundled dev-cpp/asio
	rm -r "${S}/asio" || die

	# Respect {C,LD}FLAGS.
	epatch "${FILESDIR}/respect-flags.patch"

	#Remove optional garbd daemon
	if ! use garbd ; then
		rm -r "${S}/garb" || die
	fi

	epatch_user
}

src_configure() {
	tc-export CC CXX
	# strict_build_flags=0 disables -Werror, -pedantic, -Weffc++,
	# and -Wold-style-cast
	myesconsargs=(
		$(use_scons ssl ssl 1 0)
		$(use_scons test tests 1 0)
		strict_build_flags=0
	)
}

src_compile() {
	escons --warn=no-missing-sconscript
}

src_install() {
	dodoc scripts/packages/README scripts/packages/README-MySQL
	if use garbd ; then
		dobin garb/garbd
		newconfd "${FILESDIR}/garb.cnf" garbd
		newinitd "${FILESDIR}/garb.sh" garbd
	fi
	exeinto /usr/$(get_libdir)/${PN}
	doexe libgalera_smm.so
}



1.1                  sys-cluster/galera/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/galera/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/galera/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>mysql</herd>
<use>
  <flag name='garbd'>Install Galera Arbitrator - a stateless daemon which acts as a lightweight group member</flag>
</use>
</pkgmetadata>



1.1                  sys-cluster/galera/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/galera/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/galera/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-cluster/galera
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/ChangeLog,v 1.1 2014/07/30 06:26:05 robbat2 Exp $

*galera-25.3.5 (30 Jul 2014)

  30 Jul 2014; Robin H. Johnson <robbat2@g.o> +files/disable-tests.patch,
  +files/garb.cnf, +files/garb.sh, +files/respect-flags.patch,
  +galera-25.3.5.ebuild, +metadata.xml:
  Bring MariaDB-Galera from the overlay into the tree. Thanks to the great work
  of Brian Evans <grknight@g.o>.