[gentoo-commits] repo/gentoo:master commit in: dev-python/jupyter_core/

[Virgil Dupras]

commit:     6a189c83547dd889e0075ec1bc893ff01103f596
Author:     Virgil Dupras <vdupras <AT> gentoo <DOT> org>
AuthorDate: Sat May  4 20:41:57 2019 +0000
Commit:     Virgil Dupras <vdupras <AT> gentoo <DOT> org>
CommitDate: Sat May  4 22:58:03 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a189c83

dev-python/jupyter_core: drop py2

Bug: https://bugs.gentoo.org/685040
Signed-off-by: Virgil Dupras <vdupras <AT> gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

 .../jupyter_core/jupyter_core-4.4.0-r1.ebuild      | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/dev-python/jupyter_core/jupyter_core-4.4.0-r1.ebuild b/dev-python/jupyter_core/jupyter_core-4.4.0-r1.ebuild
new file mode 100644
index 00000000000..994c0dea094
--- /dev/null
+++ b/dev-python/jupyter_core/jupyter_core-4.4.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Core common functionality of Jupyter projects"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/traitlets[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-github-alt[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/ipython-4.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+# tests require installation of jupyter_core, bug #649538
+RESTRICT="test"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	py.test jupyter_core || die
+}