[gentoo-commits] gentoo-x86 commit in sci-visualization/qtiplot: ChangeLog qtiplot-0.9.2.ebuild qtiplot-0.9.1.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    07/12/03 11:20:15

  Modified:             ChangeLog
  Added:                qtiplot-0.9.2.ebuild
  Removed:              qtiplot-0.9.1.ebuild
  Log:
  Version bump. Removed 0.9.1 because many issues and missing doc upstream. python-2.5 now only needed if python flag set.
  (Portage version: 2.1.4_rc4)

Revision  Changes    Path
1.13                 sci-visualization/qtiplot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/qtiplot/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/qtiplot/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/qtiplot/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-visualization/qtiplot/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	28 Nov 2007 23:28:27 -0000	1.12
+++ ChangeLog	3 Dec 2007 11:20:14 -0000	1.13
@@ -1,6 +1,15 @@
 # ChangeLog for sci-visualization/qtiplot
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/qtiplot/ChangeLog,v 1.12 2007/11/28 23:28:27 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/qtiplot/ChangeLog,v 1.13 2007/12/03 11:20:14 bicatali Exp $
+
+*qtiplot-0.9.2 (03 Dec 2007)
+
+  03 Dec 2007; Sébastien Fabbro <bicatali@g.o>
+  -files/qtiplot-0.9.1-systemlibs.patch,
+  +files/qtiplot-0.9.2-systemlibs.patch, -qtiplot-0.9.1.ebuild,
+  +qtiplot-0.9.2.ebuild:
+  Version bump. Removed 0.9.1 because many issues and missing doc upstream.
+  python-2.5 now only needed if python flag set.
 
 *qtiplot-0.9.1 (28 Nov 2007)
 



1.1                  sci-visualization/qtiplot/qtiplot-0.9.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/qtiplot/qtiplot-0.9.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/qtiplot/qtiplot-0.9.2.ebuild?rev=1.1&content-type=text/plain

Index: qtiplot-0.9.2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/qtiplot/qtiplot-0.9.2.ebuild,v 1.1 2007/12/03 11:20:14 bicatali Exp $

inherit eutils multilib qt4 python

DESCRIPTION="Qt based clone of the Origin plotting package"
HOMEPAGE="http://soft.proindependent.com/qtiplot.html"
SRC_URI="http://soft.proindependent.com/src/${P}.tar.bz2
	doc? ( http://soft.proindependent.com/doc/manual-en.tar.bz2
		linguas_es? ( http://soft.proindependent.com/doc/manual-es.zip ) )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="python doc"

LANGUAGES="de es fr ja ru sv"
for l in ${LANGUAGES}; do
	IUSE="${IUSE} linguas_${l}"
done

CDEPEND=">=x11-libs/qwt-5.0.2
	>=x11-libs/qwtplot3d-0.2.7
	>=dev-cpp/muParser-1.28
	>=sci-libs/liborigin-20071119
	>=sci-libs/gsl-1.10"

DEPEND="${RDEPEND}
	python? ( >=dev-python/sip-4.5.2 )
	doc? ( linguas_es? ( app-arch/unzip ) )"

RDEPEND="${CDEPEND}
	python? ( >=dev-lang/python-2.5
		dev-python/PyQt4
		dev-python/pygsl
		sci-libs/scipy )"

# manual-en.html never changes version
# could also uses docbook2html, but the dep is quite heavy
RESTRICT=" doc? ( mirror )"

QT4_BUILT_WITH_USE_CHECK="qt3support"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-systemlibs.patch

	for l in ${LANGUAGES}; do
		use linguas_${l} || \
			sed -i -e "s:translations/qtiplot_${l}.ts::" ${PN}/${PN}.pro
	done
	use python || sed -i -e 's/^\(SCRIPTING_LANGS += Python\)/#\1/' ${PN}.pro

	# the lib$$suff did not work in the fitRational*.pro files
	sed -i \
		-e "s|/usr/lib\$\${libsuff}|$(get_libdir)|g" \
		fitPlugins/fit*/fitRational*.pro \
		|| die "sed fitRational* failed"
}

src_compile() {
	eqmake4 ${PN}.pro || die "eqmake4 failed"
	emake || die "emake failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die 'emake install failed'

	newicon qtiplot_logo.png qtiplot.png
	make_desktop_entry qtiplot QtiPlot qtiplot Science
	doman qtiplot.1

	if use doc; then
		insinto "/usr/share/doc/${PF}"
		doins -r "${WORKDIR}"/manual-en
		use linguas_es && doins -r "${WORKDIR}"/manual-es
	fi

	for l in ${LANGUAGES}; do
		if use linguas_${l}; then
			insinto /usr/share/${PN}/translations
			doins ${PN}/translations/*${l}*.qm
		fi
	done

	if use python; then
		cd "${S}"/${PN}
		insinto /etc
		doins qtiplotrc.py
		python_version
		insinto /usr/$(get_libdir)/python${PYVER}/site-packages/
		doins qtiUtil.py
	fi
}

pkg_postinst() {
	use python && python_mod_optimize \
		"${ROOT}"/usr/$(get_libdir)/python${PYVER}/site-packages/qtiUtil
}

pkg_postrm() {
	use python && python_mod_cleanup \
		"${ROOT}"/usr/$(get_libdir)/python${PYVER}/site-packages/qtiUtil
}



-- 
gentoo-commits@g.o mailing list