[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-collections/

[Louis Sautier]

commit:     f19ff2561a5e128930783e7e8d4748c3ab63b4cd
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 18 19:03:17 2018 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Thu Oct 18 19:04:38 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f19ff256

dev-python/jaraco-collections: bump to 1.6.0

Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 dev-python/jaraco-collections/Manifest             |  1 +
 .../jaraco-collections-1.6.0.ebuild                | 59 ++++++++++++++++++++++
 2 files changed, 60 insertions(+)

diff --git a/dev-python/jaraco-collections/Manifest b/dev-python/jaraco-collections/Manifest
index d5ab850f99f..8ecc5d91d29 100644
--- a/dev-python/jaraco-collections/Manifest
+++ b/dev-python/jaraco-collections/Manifest
@@ -1,2 +1,3 @@
 DIST jaraco.collections-1.5.3.tar.gz 11669 BLAKE2B 2dbcac99edf28f4544e354724f8d95c0cbcdd793b33bcf892b403e72410f3b5b72b6eae62a49f0e56991cfb19b4ad5da0e95a3327f11fe5ae885e9a0029a92be SHA512 6e1fa88b468b9d971a7a302ebfdf8b9762404c2fdc1b003eee6653704b9f385f0f2e0c84ac075bdc81f8693195781cc5532c4adb31bcabd87974624a14e287ed
 DIST jaraco.collections-1.5.tar.gz 10615 BLAKE2B 4331a1df4a1232817e5bde97ce22b019ecb50711c0f4dfd18d050233b820a51c420719ff2a0d013e60da4710a63ab34293ee15f091b86392ec0d5e36e8262880 SHA512 7e2d3849d26422d687cfeb560f8096fb099a9c7b99b3061a06f9ad7037c3805b577754f62e5d5ead3f6f89bcd7dbf574df2844aa3c28928941ea2c99d50fc161
+DIST jaraco.collections-1.6.0.tar.gz 11991 BLAKE2B 8f8b3da18641d6348a28ef3792afabd504771f31f1de17ebb621aff493cbb7357e11d49d8b3f4ab4fc7b9a662986d10a90d20734cd802c6d34be1d169390aa96 SHA512 9bd472b51668129f12fabb90b86ed929e135a17217bc850d67d945a786d1952cf1f11b0cd8f5d4ae16b3b19ac35cf87e0584df622877185362e93ba3915dbe6b

diff --git a/dev-python/jaraco-collections/jaraco-collections-1.6.0.ebuild b/dev-python/jaraco-collections/jaraco-collections-1.6.0.ebuild
new file mode 100644
index 00000000000..e604a649977
--- /dev/null
+++ b/dev-python/jaraco-collections/jaraco-collections-1.6.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Models and classes to supplement the stdlib collections module"
+HOMEPAGE="https://github.com/jaraco/jaraco.collections"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+PDEPEND="dev-python/jaraco-text[${PYTHON_USEDEP}]"
+RDEPEND="
+	dev-python/namespace-jaraco[${PYTHON_USEDEP}]
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	>=dev-python/six-1.7.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${PDEPEND}
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. pytest -vv --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}