[gentoo-commits] gentoo-x86 commit in lxde-base/lxpanel: lxpanel-0.5.8-r2.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    12/02/04 10:30:35

  Modified:             ChangeLog
  Added:                lxpanel-0.5.8-r2.ebuild
  Log:
  Support sysfs and proc interfaces in lxpanel. Bug #400855
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.37                 lxde-base/lxpanel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/ChangeLog?rev=1.37&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/ChangeLog?rev=1.37&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/ChangeLog?r1=1.36&r2=1.37

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v
retrieving revision 1.36
retrieving revision 1.37
diff -u -r1.36 -r1.37
--- ChangeLog	1 Jan 2012 13:39:25 -0000	1.36
+++ ChangeLog	4 Feb 2012 10:30:35 -0000	1.37
@@ -1,6 +1,12 @@
 # ChangeLog for lxde-base/lxpanel
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.36 2012/01/01 13:39:25 vostorga Exp $
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.37 2012/02/04 10:30:35 hwoarang Exp $
+
+*lxpanel-0.5.8-r2 (04 Feb 2012)
+
+  04 Feb 2012; Markos Chandras <hwoarang@g.o>
+  +files/lxpanel-0.5.8-thermal-plugin.patch, +lxpanel-0.5.8-r2.ebuild:
+  Support sysfs and proc interfaces in lxpanel. Bug #400855
 
 *lxpanel-0.5.8-r1 (01 Jan 2012)
 



1.1                  lxde-base/lxpanel/lxpanel-0.5.8-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.8-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.8-r2.ebuild?rev=1.1&content-type=text/plain

Index: lxpanel-0.5.8-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.8-r2.ebuild,v 1.1 2012/02/04 10:30:35 hwoarang Exp $

EAPI="4"

inherit autotools eutils

DESCRIPTION="Lightweight X11 desktop panel for LXDE"
HOMEPAGE="http://lxde.org/"
SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="+alsa"
RESTRICT="test"  # bug 249598

RDEPEND="x11-libs/gtk+:2
	x11-libs/libXmu
	x11-libs/libXpm
	lxde-base/lxmenu-data
	lxde-base/menu-cache
	alsa? ( media-libs/alsa-lib )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.5.1-sandbox.patch
	epatch "${FILESDIR}"/${PN}-0.5.6-broken-apps.patch
	epatch "${FILESDIR}"/${P}-battery-meter.patch
	epatch "${FILESDIR}"/${P}-thermal-plugin.patch
	eautoreconf
}

src_configure() {
	local plugins=all
	[[ ${CHOST} == *-interix* ]] && plugins=deskno,kbled,xkb

	econf $(use_enable alsa) --with-x --with-plugins=${plugins}
	# the gtk+ dep already pulls in libX11, so we might as well hardcode with-x
}

src_install () {
	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog README

	# Get rid of the .la files.
	find "${D}" -name '*.la' -delete
}

pkg_postinst() {
	elog "If you have problems with broken icons shown in the main panel,"
	elog "you will have to configure panel settings via its menu."
	elog "This will not be an issue with first time installations."
}