[gentoo-commits] gentoo-x86 commit in net-libs/libsocialweb: libsocialweb-0.25.21-r1.ebuild libsocialweb-0.25.21.ebuild ChangeLog

[Gilles Dartiguelongue (eva)]

eva         14/01/22 21:35:47

  Modified:             libsocialweb-0.25.21.ebuild ChangeLog
  Added:                libsocialweb-0.25.21-r1.ebuild
  Log:
  EAPI bump and switch to python*-r1 eclass.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.11                 net-libs/libsocialweb/libsocialweb-0.25.21.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21.ebuild?r1=1.10&r2=1.11

Index: libsocialweb-0.25.21.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- libsocialweb-0.25.21.ebuild	30 Aug 2013 22:50:39 -0000	1.10
+++ libsocialweb-0.25.21.ebuild	22 Jan 2014 21:35:47 -0000	1.11
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21.ebuild,v 1.10 2013/08/30 22:50:39 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21.ebuild,v 1.11 2014/01/22 21:35:47 eva Exp $
 
 EAPI="4"
 GCONF_DEBUG="no"
@@ -79,5 +79,7 @@
 	gnome2_src_prepare
 	use vala && vala_src_prepare
 
-	python_convert_shebangs 2 "${S}/tools/glib-ginterface-gen.py"
+	# Fix python shebang (FIXME: should be in utils-r1)
+	sed -e "/^#!/ s/python/${PYTHON}/" \
+		-i  "${S}/tools/glib-ginterface-gen.py" || die
 }



1.24                 net-libs/libsocialweb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libsocialweb/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	30 Aug 2013 22:50:39 -0000	1.23
+++ ChangeLog	22 Jan 2014 21:35:47 -0000	1.24
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/libsocialweb
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libsocialweb/ChangeLog,v 1.23 2013/08/30 22:50:39 eva Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libsocialweb/ChangeLog,v 1.24 2014/01/22 21:35:47 eva Exp $
+
+*libsocialweb-0.25.21-r1 (22 Jan 2014)
+
+  22 Jan 2014; Gilles Dartiguelongue <eva@g.o>
+  libsocialweb-0.25.21.ebuild, +libsocialweb-0.25.21-r1.ebuild:
+  EAPI bump and switch to python*-r1 eclass.
 
   30 Aug 2013; Gilles Dartiguelongue <eva@g.o>
   libsocialweb-0.25.21.ebuild:



1.1                  net-libs/libsocialweb/libsocialweb-0.25.21-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21-r1.ebuild?rev=1.1&content-type=text/plain

Index: libsocialweb-0.25.21-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libsocialweb/libsocialweb-0.25.21-r1.ebuild,v 1.1 2014/01/22 21:35:47 eva Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python{2_6,2_7} )
VALA_MIN_API_VERSION="0.12"
VALA_USE_DEPEND="vapigen"

inherit autotools eutils gnome2 python-any-r1 vala

DESCRIPTION="Social web services integration framework"
HOMEPAGE="http://git.gnome.org/browse/libsocialweb"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="connman +gnome +introspection +networkmanager vala"

# Introspection is needed for vala bindings
REQUIRED_USE="
	?? ( connman networkmanager )
	vala? ( introspection )
"

# NOTE: coverage testing should not be enabled
RDEPEND="
	>=dev-libs/glib-2.14:2
	>=net-libs/rest-0.7.10

	gnome-base/gconf:2
	gnome-base/libgnome-keyring
	dev-libs/dbus-glib
	dev-libs/json-glib
	net-libs/libsoup:2.4

	gnome? ( >=net-libs/libsoup-gnome-2.25.1:2.4 )
	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
	networkmanager? ( net-misc/networkmanager )
	!networkmanager? ( connman? ( net-misc/connman ) )
"
DEPEND="${RDEPEND}
	>=dev-util/gtk-doc-am-1.15
	>=dev-util/intltool-0.40
	sys-devel/gettext
	virtual/pkgconfig
	vala? ( $(vala_depend) )
"

pkg_setup() {
	python-any-r1_pkg_setup
}

src_prepare() {
	# Sent upstream, gnome bug 677445
	epatch "${FILESDIR}"/${PN}-0.25.20-gold.patch
	# https://bugzilla.gnome.org/show_bug.cgi?id=686503
	epatch "${FILESDIR}"/${PN}-0.25.21-gmodule.patch

	# Fix namespacing of introspection annotations, bug #426984
	epatch "${FILESDIR}"/${PN}-0.25.20-introspection-annotations.patch

	eautoreconf

	use vala && vala_src_prepare
	gnome2_src_prepare

	# Fix python shebang (FIXME: should be in utils-r1)
	sed -e "/^#!/ s:.*:#!${PYTHON}:" \
		-i  "${S}/tools/glib-ginterface-gen.py" || die
}

src_configure() {
	local myconf

	# NetworkManager always overrides connman support
	use connman && myconf="${myconf} --with-online=connman"
	use networkmanager && myconf="${myconf} --with-online=networkmanager"

	# TODO: enable sys-apps/keyutils support (--without-kernel-keyring)
	gnome2_src_configure \
		--disable-static \
		--disable-gcov \
		--without-kernel-keyring \
		--enable-all-services \
		$(use_enable introspection) \
		$(use_enable vala vala-bindings) \
		$(use_with gnome) \
		--with-online=always \
		${myconf}
}