[gentoo-commits] repo/gentoo:master commit in: dev-python/pycryptodome/

[Michał Górny]

commit:     8f2319d179a3c4eb1ffc4628fa2aaceed84e74b8
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 23 06:27:27 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun 23 07:19:12 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8f2319d1

dev-python/pycryptodome: Bump to 3.15.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pycryptodome/Manifest                   |  1 +
 dev-python/pycryptodome/pycryptodome-3.15.0.ebuild | 58 ++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/pycryptodome/Manifest b/dev-python/pycryptodome/Manifest
index 8907fbf55687..f06c310f15b0 100644
--- a/dev-python/pycryptodome/Manifest
+++ b/dev-python/pycryptodome/Manifest
@@ -1 +1,2 @@
 DIST pycryptodome-3.14.1.tar.gz 15339859 BLAKE2B 72748a4eaf9f34be1ac3200a0ed0285a96111f52077b6d7cc5b4fa26599b6b8c6c17d79cdce4cabd7257cef840daf71440a78d00ded65deb52fa13e6b1b1efe6 SHA512 08e904aa2f3df19fcc75a8283fc867349617afe3919532912801d8abc9610f1cb64b878b56202cbdf0759cf5506ec5f793123093e21f18ba99acbf42fa4d9cf1
+DIST pycryptodome-3.15.0.gh.tar.gz 16547902 BLAKE2B ce1a6eaca4946d656c08f960f67537e61b9c82a69777fcb0b01b91a9a649c605dcc66a2a6d9fdc5533521a669544c7695e83db856dfcf8e4b2ba7301654b5555 SHA512 fc611174cfb4ca89fb457cc0d1220326ac813de5a83a959a95c1928a5220dc8c652655ac0a2b7d116b60cb4a8317959d8c2b2f3595e19b9b359a32beb042b58c

diff --git a/dev-python/pycryptodome/pycryptodome-3.15.0.ebuild b/dev-python/pycryptodome/pycryptodome-3.15.0.ebuild
new file mode 100644
index 000000000000..9aa00023e3d2
--- /dev/null
+++ b/dev-python/pycryptodome/pycryptodome-3.15.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A self-contained cryptographic library for Python"
+HOMEPAGE="
+	https://www.pycryptodome.org/
+	https://github.com/Legrandin/pycryptodome/
+	https://pypi.org/project/pycryptodome/
+"
+SRC_URI="
+	https://github.com/Legrandin/pycryptodome/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2 Unlicense"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+DEPEND="
+	dev-libs/gmp:0=
+	>=dev-libs/libtomcrypt-1.18.2-r1:=
+"
+BDEPEND="
+	virtual/python-cffi[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	${BDEPEND}
+	!dev-python/pycrypto
+"
+
+PATCHES=(
+	"${FILESDIR}/pycryptodome-3.10.1-system-libtomcrypt.patch"
+)
+
+python_prepare_all() {
+	# make sure we're unbundling it correctly
+	rm -r src/libtom || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTHONPATH=${S}/test_vectors:${PYTHONPATH}
+	"${EPYTHON}" - <<-EOF || die
+		import sys
+		from Crypto import SelfTest
+		SelfTest.run(verbosity=2, stream=sys.stdout)
+	EOF
+}