[gentoo-commits] gentoo-x86 commit in sys-apps/pcmciautils: pcmciautils-018_p8-r1.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/09/01 05:17:12

  Modified:             ChangeLog
  Added:                pcmciautils-018_p8-r1.ebuild
  Log:
  Fix handling of USE="staticsocket" wrt #521856 by Mehmet Giritli
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.51                 sys-apps/pcmciautils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcmciautils/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcmciautils/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcmciautils/ChangeLog?r1=1.50&r2=1.51

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pcmciautils/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog	30 Jul 2014 19:41:09 -0000	1.50
+++ ChangeLog	1 Sep 2014 05:17:12 -0000	1.51
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pcmciautils
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcmciautils/ChangeLog,v 1.50 2014/07/30 19:41:09 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcmciautils/ChangeLog,v 1.51 2014/09/01 05:17:12 ssuominen Exp $
+
+*pcmciautils-018_p8-r1 (01 Sep 2014)
+
+  01 Sep 2014; Samuli Suominen <ssuominen@g.o>
+  +pcmciautils-018_p8-r1.ebuild:
+  Fix handling of USE="staticsocket" wrt #521856 by Mehmet Giritli
 
   30 Jul 2014; Samuli Suominen <ssuominen@g.o> pcmciautils-018_p8.ebuild:
   Use shorter get_udevdir() instead of the longer deprecated udev_get_udevdir()



1.1                  sys-apps/pcmciautils/pcmciautils-018_p8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcmciautils/pcmciautils-018_p8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcmciautils/pcmciautils-018_p8-r1.ebuild?rev=1.1&content-type=text/plain

Index: pcmciautils-018_p8-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcmciautils/pcmciautils-018_p8-r1.ebuild,v 1.1 2014/09/01 05:17:12 ssuominen Exp $

EAPI=5
inherit eutils flag-o-matic linux-info toolchain-funcs udev

DEB_REV=${PV#*_p}
MY_PV=${PV%_p*}

DESCRIPTION="PCMCIA userspace utilities for Linux"
HOMEPAGE="http://packages.qa.debian.org/pcmciautils"
SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${MY_PV}.orig.tar.gz
	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${MY_PV}-${DEB_REV}.debian.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~sh ~x86"
IUSE="debug staticsocket"

RDEPEND="virtual/modutils"
DEPEND="${RDEPEND}
	virtual/yacc
	sys-devel/flex"

S=${WORKDIR}/${PN}-${MY_PV}

pkg_setup() {
	CONFIG_CHECK="~PCMCIA"
	linux-info_pkg_setup

	kernel_is lt 2 6 32 && ewarn "${P} requires at least kernel 2.6.32."

	mypcmciaopts=(
		STARTUP=$(usex staticsocket false true)
		exec_prefix=/usr
		UDEV=true
		DEBUG=false
		STATIC=false
		V=true
		udevdir="$(get_udevdir)"
		CC="$(tc-getCC)"
		LD="$(tc-getCC)"
		AR="$(tc-getAR)"
		STRIP=true
		RANLIB="$(tc-getRANLIB)"
		OPTIMIZATION="${CFLAGS} ${CPPFLAGS}"
		DESTDIR="${D}"
		)

	use debug && append-cppflags -DDEBUG
}

src_prepare() {
	epatch \
		"${WORKDIR}"/debian/patches/no-modprobe-rules.patch \
		"${WORKDIR}"/debian/patches/remove-libsysfs-dep.patch

	sed -i \
		-e '/CFLAGS/s:-fomit-frame-pointer::' \
		-e '/dir/s:sbin:bin:g' \
		Makefile || die
}

src_compile() {
	emake "${mypcmciaopts[@]}"
}

src_install() {
	emake "${mypcmciaopts[@]}" install

	dodoc doc/*.txt
}