[gentoo-commits] gentoo-x86 commit in media-sound/pianobar: metadata.xml pianobar-2011.04.27.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    11/05/06 08:19:33

  Added:                metadata.xml pianobar-2011.04.27.ebuild ChangeLog
  Log:
  Initial import.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  media-sound/pianobar/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pianobar/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pianobar/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>sound</herd>
  <maintainer>
    <email>radhermit@g.o</email>
    <name>Tim Harder</name>
  </maintainer>
</pkgmetadata>



1.1                  media-sound/pianobar/pianobar-2011.04.27.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pianobar/pianobar-2011.04.27.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pianobar/pianobar-2011.04.27.ebuild?rev=1.1&content-type=text/plain

Index: pianobar-2011.04.27.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pianobar/pianobar-2011.04.27.ebuild,v 1.1 2011/05/06 08:19:33 radhermit Exp $

EAPI=4

inherit toolchain-funcs flag-o-matic eutils

DESCRIPTION="A console-based replacement for Pandora's flash player"
HOMEPAGE="http://6xq.net/html/00/17.html"
SRC_URI="http://6xq.net/media/00/16/${P}.tar.bz2"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aac +mp3"

DEPEND="media-libs/libao
	aac? ( media-libs/faad2 )
	mp3? ( media-libs/libmad )"
RDEPEND="${DEPEND}"

REQUIRED_USE="|| ( mp3 aac )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-linking.patch
}

src_compile() {
	local myconf=""
	! use aac && myconf+=" DISABLE_FAAD=1"
	! use mp3 && myconf+=" DISABLE_MAD=1"

	append-cflags -std=c99
	emake CC=$(tc-getCC) CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" ${myconf}
}

src_install() {
	emake DESTDIR="${D}" PREFIX=/usr install
	dodoc ChangeLog README

	insinto /usr/share/doc/${PF}/contrib
	doins -r contrib/{config-example,*.sh,eventcmd-examples}
	docompress -x /usr/share/doc/${PF}/contrib
}



1.1                  media-sound/pianobar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pianobar/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pianobar/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-sound/pianobar
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pianobar/ChangeLog,v 1.1 2011/05/06 08:19:33 radhermit Exp $

*pianobar-2011.04.27 (06 May 2011)

  06 May 2011; Tim Harder <radhermit@g.o> +pianobar-2011.04.27.ebuild,
  +files/pianobar-2011.04.27-linking.patch, +metadata.xml:
  Initial import.