[gentoo-commits] repo/gentoo:master commit in: dev-games/tiled/

[Michael Palimaka]

commit:     ee8e81d011f24101b00bfc14e76b824c3fab3372
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 25 02:01:24 2022 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Fri Feb 25 02:01:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee8e81d0

dev-games/tiled: version bump 1.8.2

Closes: https://bugs.gentoo.org/833289
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>

 dev-games/tiled/Manifest           |  1 +
 dev-games/tiled/tiled-1.8.2.ebuild | 73 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 2311329195ff..23b0953ef512 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.7.2.tar.gz 16743422 BLAKE2B 0d8ae95b2fc68326d0a4989b26535cd72900ddf9674ad892c287f9d7df2f551fc46c9fa9c8991315f55ae90663a9a5b9c4239fd2ed61c240a36a60102b2710b3 SHA512 6d766adbfcb642279eb0ba27410858c54a29ed8e697445b6fb96ce210d0b1433b1ed4715e1d78af3aea8ec71a87b24eea52216bf6236159e0c8fdf87a2339a59
+DIST tiled-1.8.2.tar.gz 17032015 BLAKE2B 92919e76f4753e3f8a3a98d421376ad35fe35fd1272e64cb40f382ea57020da63b6ea553529805b3bc356043bbfc18962c2874ee4e81b9a38b8629eb0ac8e1a7 SHA512 698add45d425d16a7b68c9b4d847cafb1d2b0633157614cbcec5f4dba23c1a65597bd2211b8c9f6b37af8ea2a4ca967fc71662672d79a8ea209dd9b0e3863413

diff --git a/dev-games/tiled/tiled-1.8.2.ebuild b/dev-games/tiled/tiled-1.8.2.ebuild
new file mode 100644
index 000000000000..fe51e31d02f0
--- /dev/null
+++ b/dev-games/tiled/tiled-1.8.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9} )
+inherit python-single-r1 qmake-utils xdg-utils
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	app-arch/zstd:=
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtdeclarative-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtnetwork-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	eqmake5 \
+		LIBDIR="/usr/$(get_libdir)" \
+		PREFIX="/usr" \
+		SYSTEM_ZSTD="yes" \
+		DISABLE_PYTHON_PLUGIN="$(usex !python)" \
+		USE_FHS_PLUGIN_PATH="true"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}