[gentoo-commits] gentoo-x86 commit in net-firewall/shorewall: ChangeLog shorewall-4.5.19.ebuild

[Constanze Hausner (constanze)]

constanze    13/08/28 16:45:58

  Modified:             ChangeLog
  Added:                shorewall-4.5.19.ebuild
  Log:
  Version bump; Add new files/ structure
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key BB80F419010E3EC3)

Revision  Changes    Path
1.244                net-firewall/shorewall/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall/ChangeLog?rev=1.244&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall/ChangeLog?rev=1.244&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall/ChangeLog?r1=1.243&r2=1.244

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/shorewall/ChangeLog,v
retrieving revision 1.243
retrieving revision 1.244
diff -u -r1.243 -r1.244
--- ChangeLog	28 Aug 2013 15:20:19 -0000	1.243
+++ ChangeLog	28 Aug 2013 16:45:58 -0000	1.244
@@ -1,6 +1,14 @@
 # ChangeLog for net-firewall/shorewall
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/shorewall/ChangeLog,v 1.243 2013/08/28 15:20:19 constanze Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/shorewall/ChangeLog,v 1.244 2013/08/28 16:45:58 constanze Exp $
+
+*shorewall-4.5.19 (28 Aug 2013)
+
+  28 Aug 2013; Constanze Hausner <constanze@g.o>
+  +files/4.5.19/shorewall.conf-SUBSYSLOCK.patch, +files/4.5.19/shorewall.confd,
+  +files/4.5.19/shorewall.initd, +files/4.5.19/shorewall.systemd,
+  +files/4.5.19/shorewallrc, +shorewall-4.5.19.ebuild:
+  Version bump; Add new files/ structure
 
   28 Aug 2013; Constanze Hausner <constanze@g.o>
   -shorewall-4.5.15.ebuild, -shorewall-4.5.17.ebuild:



1.1                  net-firewall/shorewall/shorewall-4.5.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall/shorewall-4.5.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/shorewall/shorewall-4.5.19.ebuild?rev=1.1&content-type=text/plain

Index: shorewall-4.5.19.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/shorewall/shorewall-4.5.19.ebuild,v 1.1 2013/08/28 16:45:58 constanze Exp $

EAPI="5"

inherit eutils linux-info prefix systemd versionator

MY_URL_PREFIX=
case ${P} in
	*_beta* | \
	*_rc*)
		MY_URL_PREFIX='development/'
		;;
esac

MY_PV=${PV/_rc/-RC}
MY_PV=${MY_PV/_beta/-Beta}
MY_P=${PN}-${MY_PV}
MY_P_DOCS=shorewall-docs-html-${MY_PV}

MY_MAJORMINOR=$(get_version_component_range 1-2)

DESCRIPTION='The Shoreline Firewall, commonly known as Shorewall, is'
DESCRIPTION+=' a high-level tool for configuring Netfilter.'
HOMEPAGE="http://www.shorewall.net/"
SRC_URI="
	http://www.shorewall.net/pub/shorewall/${MY_URL_PREFIX}${MY_MAJORMINOR}/shorewall-${MY_PV}/${MY_P}.tar.bz2
	doc? ( http://www.shorewall.net/pub/shorewall/${MY_URL_PREFIX}${MY_MAJORMINOR}/shorewall-${MY_PV}/${MY_P_DOCS}.tar.bz2 )
"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc"

DEPEND="
	>=dev-lang/perl-5.10
	virtual/perl-Digest-SHA
	=net-firewall/shorewall-core-${PV}
"
RDEPEND="
	${DEPEND}
	>=net-firewall/iptables-1.4.20
	sys-apps/iproute2[-minimal]
	sys-devel/bc
"

S=${WORKDIR}/${MY_P}

pkg_pretend() {
	local CONFIG_CHECK="~NF_CONNTRACK ~NF_CONNTRACK_IPV4"

	local WARNING_CONNTRACK="Without NF_CONNTRACK support, you will be unable"
	local WARNING_CONNTRACK+=" to run ${PN} on the local system."

	local WARNING_CONNTRACK_IPV4="Without NF_CONNTRACK_IPV4 support, you will"
	local WARNING_CONNTRACK_IPV4+=" be unable to run ${PN} on the local system."

	check_extra_config
}

src_prepare() {
	cp "${FILESDIR}"/${PV}/shorewallrc "${S}"/shorewallrc.gentoo || die "Copying shorewallrc_new failed"
	eprefixify "${S}"/shorewallrc.gentoo

	cp "${FILESDIR}"/${PV}/${PN}.confd "${S}"/default.gentoo || die "Copying shorewall.confd failed"
	cp "${FILESDIR}"/${PV}/${PN}.initd "${S}"/init.gentoo.sh || die "Copying shorewall.initd failed"

	epatch "${FILESDIR}"/${PV}/shorewall.conf-SUBSYSLOCK.patch
	epatch_user
}

src_configure() {
	:;
}

src_compile() {
	:;
}

src_install() {
	keepdir /var/lib/${PN}

	DESTDIR="${D}" ./install.sh shorewallrc.gentoo || die "install.sh failed"
	systemd_newunit "${FILESDIR}"/${PV}/${PN}.systemd ${PN}.service

	# Currently, install.sh from upstream is broken and will always
	# default.debian so have to do it on our own:
	newconfd "${FILESDIR}"/${PV}/${PN}.confd ${PN}

	dodoc changelog.txt releasenotes.txt
	if use doc; then
		dodoc -r Samples
		cd "${WORKDIR}"/${MY_P_DOCS}
		dohtml -r *
	fi
}

pkg_postinst() {
	if [[ -z "${REPLACING_VERSIONS}" ]]; then
		# This is a new installation
		elog "Before you can use ${PN}, you need to edit its configuration in:"
		elog ""
		elog "  ${EPREFIX}/etc/${PN}/${PN}.conf"
		elog ""
		elog "To activate ${PN} on system start, please add ${PN} to your default runlevel:"
		elog ""
		elog "  # rc-update add ${PN} default"
	fi
}