[gentoo-commits] gentoo-x86 commit in games-puzzle/sgt-puzzles: ChangeLog sgt-puzzles-8906.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/04/01 16:41:45

  Modified:             ChangeLog
  Added:                sgt-puzzles-8906.ebuild
  Log:
  version bump with patch from Denilson (bug #301789)
  (Portage version: 2.1.7.17/cvs/Linux i686)

Revision  Changes    Path
1.3                  games-puzzle/sgt-puzzles/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	11 Sep 2009 12:02:01 -0000	1.2
+++ ChangeLog	1 Apr 2010 16:41:45 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for games-puzzle/sgt-puzzles
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v 1.2 2009/09/11 12:02:01 tupone Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/ChangeLog,v 1.3 2010/04/01 16:41:45 mr_bones_ Exp $
+
+*sgt-puzzles-8906 (01 Apr 2010)
+
+  01 Apr 2010; Michael Sterrett <mr_bones_@g.o>
+  +sgt-puzzles-8906.ebuild, +files/sgt-puzzles-8906-gentoo.patch:
+  version bump with patch from Denilson (bug #301789)
 
   11 Sep 2009; Tupone Alfredo <tupone@g.o>
   +files/sgt-puzzles-8605-gentoo.patch, sgt-puzzles-8605.ebuild:



1.1                  games-puzzle/sgt-puzzles/sgt-puzzles-8906.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-8906.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-8906.ebuild?rev=1.1&content-type=text/plain

Index: sgt-puzzles-8906.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-puzzle/sgt-puzzles/sgt-puzzles-8906.ebuild,v 1.1 2010/04/01 16:41:45 mr_bones_ Exp $

EAPI=2
inherit eutils games
if [[ ${PV} == "99999999" ]] ; then
	ESVN_REPO_URI="svn://svn.tartarus.org/sgt/puzzles/trunk"
	inherit subversion
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-r${PV}.tar.gz"
	S=${WORKDIR}/puzzles-r${PV}
	KEYWORDS="~amd64 ~x86"
fi

DESCRIPTION="Simon Tatham's Portable Puzzle Collection"
HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"

LICENSE="MIT"
SLOT="0"
IUSE="doc"

RDEPEND="x11-libs/gtk+:2"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( >=app-doc/halibut-1.0 )"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	./mkfiles.pl
	sed -i \
		-e 's:= -O2 -Wall -Werror -ansi -pedantic -g:= $(CPPFLAGS):' \
		-e '/LDFLAGS/s:=:=$(LDFLAGS) :' \
		Makefile || die
}

src_compile() {
	emake || die
	if use doc ; then
		halibut --text --html --info --pdf --ps puzzles.but
	fi
}

src_install() {
	dodir "${GAMES_BINDIR}"
	emake DESTDIR="${D}" gamesdir="${GAMES_BINDIR}" install || die
	dodoc README HACKING

	local file name
	for file in *.R ; do
		[[ ${file} == "nullgame.R" ]] && continue
		name=$(sed -n 's/^[a-z]*\.exe://p' "${file}")
		file=${file%.R}
		newicon icons/${file}-48d24.png ${PN}-${file}.png || die
		make_desktop_entry "${GAMES_BINDIR}/${file}" "${name}" "${PN}-${file}"
	done

	dodoc puzzles.txt puzzles.chm
	if use doc ; then
		dohtml *.html
		doinfo puzzles.info
		dodoc puzzles.pdf puzzles.ps
	fi

	prepgamesdirs
}