[gentoo-commits] repo/gentoo:master commit in: app-text/poppler/

[Manuel Rüger]

commit:     efcac15619ac56783ca32034237b95567690662d
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 22 11:49:49 2017 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Thu Jun 22 11:50:09 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=efcac156

app-text/poppler: Version bump to 0.56.0

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 app-text/poppler/Manifest              |   1 +
 app-text/poppler/poppler-0.56.0.ebuild | 141 +++++++++++++++++++++++++++++++++
 2 files changed, 142 insertions(+)

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index ade19e01b9d..45993c10e3a 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -1,2 +1,3 @@
 DIST poppler-0.45.0.tar.xz 1674464 SHA256 96dd1a6024bcdaa4530a3b49687db3d5c24ddfd072ccb37c6de0e42599728798 SHA512 b703bed35da3572801834740bf61d59b6a3ee3b88bc1b3181bde3472264be4f6b89ceacb56179d7093329946abd6ba2501acfaf209d4f543352ff9fd38c47f1b WHIRLPOOL 687b1ba816dbff1b0a69cb05914dd7fb161bfd8c0fa4e26b77bb0ad26e27f7d7d94085a1022716a8d7a7563145f0acead9fccbbd332959d0216b81b27f3632e8
 DIST poppler-0.55.0.tar.xz 1700440 SHA256 537f2bc60d796525705ad9ca8e46899dcc99c2e9480b80051808bae265cdc658 SHA512 ea3008f2945da862236fcc64d320367e04e3c71d4cc5e996e0c50ac49457e5e42eb06af92486fe7f15c04f07a88367f5344f8dc76549c57c4a19e2fbb60f55d6 WHIRLPOOL 9aec88be85548d217f90fedb12530b5a61e2bf8172154146b3003d6ebbe53b6b2af947ec6f07ddde499a6b0863090470d1b379485984e27068e6741ef3bbf101
+DIST poppler-0.56.0.tar.xz 1701488 SHA256 869dbadf99ed882e776acbdbc06689d8a81872a2963440b1e8516cd7a2577173 SHA512 74d2ca63afcb7e155c153b4ddc71621b7f4f2c60d4fcafd873176d5ac59fafedc35b200a22c7af2013d7f75e670a1cc23d6ba878167a02209917f8d30002d528 WHIRLPOOL 3b7b4330306f46bc6c1f72205a8cff95f23a82011260a629762ad52bdcbc89e5c071da8aeb48c15ff21e7b38893aa01b3421d9d232938ac8a61745f798271b04

diff --git a/app-text/poppler/poppler-0.56.0.ebuild b/app-text/poppler/poppler-0.56.0.ebuild
new file mode 100644
index 00000000000..088e5a72c43
--- /dev/null
+++ b/app-text/poppler/poppler-0.56.0.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils toolchain-funcs xdg-utils
+
+if [[ "${PV}" == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.freedesktop.org/git/${PN}/${PN}"
+	SLOT="0/9999"
+else
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SLOT="0/67"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="cairo cjk curl cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt4 qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=media-libs/fontconfig-2.6.0
+	>=media-libs/freetype-2.3.9
+	sys-libs/zlib
+	cairo? (
+		dev-libs/glib:2
+		>=x11-libs/cairo-1.10.0
+		introspection? ( >=dev-libs/gobject-introspection-1.32.1:= )
+	)
+	curl? ( net-misc/curl )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.19:0 )
+	png? ( media-libs/libpng:0= )
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:0 )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( >=app-text/poppler-data-0.4.7 )
+"
+
+DOCS=(AUTHORS NEWS README README-XPDF TODO)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.26.0-qt5-dependencies.patch"
+	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
+	"${FILESDIR}/${PN}-0.53.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.33.0-openjpeg2.patch"
+	"${FILESDIR}/${PN}-0.40-FindQt4.patch"
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if [[ ${CC} == clang ]] ; then
+		sed -i -e 's/-fno-check-new//' cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT4_TESTS=OFF
+		-DBUILD_QT5_TESTS=OFF
+		-DBUILD_CPP_TESTS=OFF
+		-DENABLE_SPLASH=ON
+		-DENABLE_ZLIB=ON
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_XPDF_HEADERS=ON
+		-DENABLE_LIBCURL="$(usex curl)"
+		-DENABLE_CPP="$(usex cxx)"
+		-DENABLE_UTILS="$(usex utils)"
+		-DSPLASH_CMYK=OFF
+		-DUSE_FIXEDPOINT=OFF
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo="$(usex cairo)"
+		-DWITH_GObjectIntrospection="$(usex introspection)"
+		-DWITH_JPEG="$(usex jpeg)"
+		-DWITH_NSS3="$(usex nss)"
+		-DWITH_PNG="$(usex png)"
+		-DWITH_Qt4="$(usex qt4)"
+		$(cmake-utils_use_find_package qt5 Qt5Core)
+		-DWITH_TIFF="$(usex tiff)"
+	)
+	if use jpeg; then
+		mycmakeargs+=(-DENABLE_DCTDECODER=libjpeg)
+	else
+		mycmakeargs+=(-DENABLE_DCTDECODER=none)
+	fi
+	if use jpeg2k; then
+		mycmakeargs+=(-DENABLE_LIBOPENJPEG=openjpeg2)
+	else
+		mycmakeargs+=(-DENABLE_LIBOPENJPEG=none)
+	fi
+	if use lcms; then
+		mycmakeargs+=(-DENABLE_CMS=lcms2)
+	else
+		mycmakeargs+=(-DENABLE_CMS=)
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != 9999 ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}