[gentoo-commits] repo/gentoo:master commit in: dev-python/python-xlib/

[Andrew Ammerlaan]

commit:     ef98582ae411cc42c9933d0e6add3bc8564a38ff
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  1 09:45:02 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Wed Jun  1 10:55:28 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ef98582a

dev-python/python-xlib: update EAPI 7 -> 8, pep517, enable py3.11

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/python-xlib/python-xlib-0.31-r1.ebuild | 39 +++++++++++++++++++++++
 1 file changed, 39 insertions(+)

diff --git a/dev-python/python-xlib/python-xlib-0.31-r1.ebuild b/dev-python/python-xlib/python-xlib-0.31-r1.ebuild
new file mode 100644
index 000000000000..b9715050ed58
--- /dev/null
+++ b/dev-python/python-xlib/python-xlib-0.31-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 virtualx
+
+DESCRIPTION="A fully functional X client library for Python, written in Python"
+HOMEPAGE="https://github.com/python-xlib/python-xlib"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	doc? ( sys-apps/texinfo )
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests unittest
+
+python_compile_all() {
+	use doc && emake -C doc/info
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_install_all() {
+	use doc && doinfo doc/info/*.info
+	distutils-r1_python_install_all
+}