Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Tomas Chvatal (scarabeus)" <scarabeus@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in x11-base/xorg-server: xorg-server-1.7.4.901.ebuild ChangeLog
Date: Sat, 30 Jan 2010 17:45:38
Message-Id: E1NbHO3-00008F-Qb@stork.gentoo.org
1 scarabeus 10/01/30 17:45:35
2
3 Modified: ChangeLog
4 Added: xorg-server-1.7.4.901.ebuild
5 Log:
6 Version bump.
7 (Portage version: 2.2_rc62/cvs/Linux i686)
8
9 Revision Changes Path
10 1.486 x11-base/xorg-server/ChangeLog
11
12 file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-base/xorg-server/ChangeLog?rev=1.486&view=markup
13 plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-base/xorg-server/ChangeLog?rev=1.486&content-type=text/plain
14 diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-base/xorg-server/ChangeLog?r1=1.485&r2=1.486
15
16 Index: ChangeLog
17 ===================================================================
18 RCS file: /var/cvsroot/gentoo-x86/x11-base/xorg-server/ChangeLog,v
19 retrieving revision 1.485
20 retrieving revision 1.486
21 diff -u -r1.485 -r1.486
22 --- ChangeLog 23 Jan 2010 19:30:40 -0000 1.485
23 +++ ChangeLog 30 Jan 2010 17:45:35 -0000 1.486
24 @@ -1,6 +1,12 @@
25 # ChangeLog for x11-base/xorg-server
26 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
27 -# $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/ChangeLog,v 1.485 2010/01/23 19:30:40 scarabeus Exp $
28 +# $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/ChangeLog,v 1.486 2010/01/30 17:45:35 scarabeus Exp $
29 +
30 +*xorg-server-1.7.4.901 (30 Jan 2010)
31 +
32 + 30 Jan 2010; Tomáš Chvátal <scarabeus@g.o>
33 + +xorg-server-1.7.4.901.ebuild:
34 + Version bump.
35
36 23 Jan 2010; Tomáš Chvátal <scarabeus@g.o>
37 -xorg-server-1.6.3.901-r2.ebuild:
38
39
40
41 1.1 x11-base/xorg-server/xorg-server-1.7.4.901.ebuild
42
43 file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-base/xorg-server/xorg-server-1.7.4.901.ebuild?rev=1.1&view=markup
44 plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-base/xorg-server/xorg-server-1.7.4.901.ebuild?rev=1.1&content-type=text/plain
45
46 Index: xorg-server-1.7.4.901.ebuild
47 ===================================================================
48 # Copyright 1999-2010 Gentoo Foundation
49 # Distributed under the terms of the GNU General Public License v2
50 # $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/xorg-server-1.7.4.901.ebuild,v 1.1 2010/01/30 17:45:35 scarabeus Exp $
51
52 EAPI="2"
53
54 # Must be before x-modular eclass is inherited
55 #SNAPSHOT="yes"
56
57 inherit x-modular multilib versionator
58
59 EGIT_REPO_URI="git://anongit.freedesktop.org/git/xorg/xserver"
60
61 OPENGL_DIR="xorg-x11"
62
63 DESCRIPTION="X.Org X servers"
64 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
65
66 IUSE_SERVERS="dmx kdrive xorg"
67 IUSE="${IUSE_SERVERS} tslib hal ipv6 minimal nptl sdl"
68 RDEPEND="hal? ( sys-apps/hal )
69 tslib? ( >=x11-libs/tslib-1.0 x11-proto/xcalibrateproto )
70 dev-libs/openssl
71 >=x11-libs/libXfont-1.3.3
72 >=x11-libs/xtrans-1.2.2
73 >=x11-libs/libXau-1.0.4
74 >=x11-libs/libxkbfile-1.0.4
75 >=x11-libs/libXdmcp-1.0.2
76 >=x11-libs/libpciaccess-0.10.3
77 >=x11-libs/pixman-0.15.20
78 media-libs/freetype
79 >=x11-misc/xbitmaps-1.0.1
80 >=x11-misc/xkeyboard-config-1.4
81 x11-apps/xkbcomp
82 >=x11-apps/iceauth-1.0.2
83 >=x11-apps/rgb-1.0.3
84 >=x11-apps/xauth-1.0.3
85 >=x11-apps/xinit-1.0.8-r3
86 >=app-admin/eselect-opengl-1.0.8
87 dmx? (
88 x11-libs/libXt
89 >=x11-libs/libdmx-1.0.99.1
90 >=x11-libs/libX11-1.1.5
91 >=x11-libs/libXaw-1.0.4
92 >=x11-libs/libXext-1.0.5
93 >=x11-libs/libXfixes-4.0.3
94 >=x11-libs/libXi-1.2.99.1
95 >=x11-libs/libXmu-1.0.3
96 >=x11-libs/libXtst-1.0.3
97 )
98 !minimal? (
99 >=x11-libs/libX11-1.1.5
100 >=x11-libs/libXext-1.0.5
101 >=x11-libs/libXres-1.0.3
102 >=media-libs/mesa-7.4[nptl=]
103 )
104 >=x11-libs/libxkbui-1.0.2
105 kdrive? (
106 >=x11-libs/libXext-1.0.5
107 sdl? ( media-libs/libsdl ) )"
108 # Xres is dmx-dependent
109 # Xaw is dmx-dependent
110 # Xpm is dmx-dependent, pulls in Xt
111 # xkbcomp is launched at startup but not checked by ./configure
112
113 ## Deps that don't have a version in configure.ac but do here:
114 # x11-proto/resourceproto
115 # x11-proto/fontsproto
116 # x11-libs/libXau
117 # x11-libs/libXfont
118 # x11-libs/libXdmcp
119 # x11-libs/libXext
120 # x11-libs/libX11
121 # x11-libs/libXrender
122 # x11-libs/libXmu
123 # x11-libs/libXfixes
124 # x11-libs/libXtst
125 # x11-proto/xineramaproto
126 # x11-proto/dmxproto
127 ## Deps that are larger here than in configure.ac
128 # x11-libs/libpciaccess-0.8.0
129 #
130
131 DEPEND="${RDEPEND}
132 !!net-dialup/dtrace
133 sys-devel/flex
134 >=x11-proto/randrproto-1.2.99.3
135 >=x11-proto/renderproto-0.11
136 >=x11-proto/fixesproto-4.1
137 >=x11-proto/damageproto-1.1
138 >=x11-proto/xextproto-7.0.99.3
139 >=x11-proto/xproto-7.0.13
140 >=x11-proto/xf86dgaproto-2.0.99.1
141 >=x11-proto/xf86rushproto-1.1.2
142 >=x11-proto/xf86vidmodeproto-2.2.99.1
143 >=x11-proto/compositeproto-0.4
144 >=x11-proto/recordproto-1.13.99.1
145 >=x11-proto/resourceproto-1.0.2
146 >=x11-proto/videoproto-2.2.2
147 >=x11-proto/scrnsaverproto-1.1
148 >=x11-proto/trapproto-3.4.3
149 >=x11-proto/xineramaproto-1.1.3
150 >=x11-proto/fontsproto-2.0.2
151 >=x11-proto/kbproto-1.0.3
152 >=x11-proto/inputproto-1.9.99.902
153 >=x11-proto/bigreqsproto-1.1.0
154 >=x11-proto/xcmiscproto-1.2.0
155 >=x11-proto/glproto-1.4.9
156 dmx? ( >=x11-proto/dmxproto-2.2.99.1 )
157 !minimal? (
158 >=x11-proto/xf86driproto-2.1.0
159 >=x11-proto/dri2proto-2.1
160 >=x11-libs/libdrm-2.3.0
161 )"
162
163 PDEPEND="xorg? ( >=x11-base/xorg-drivers-$(get_version_component_range 1-2) )"
164
165 EPATCH_FORCE="yes"
166 EPATCH_SUFFIX="patch"
167
168 # These have been sent upstream
169 UPSTREAMED_PATCHES=(
170 #"${WORKDIR}/patches/"
171
172 # Fix from bug http://bugs.freedesktop.org/show_bug.cgi?id=25400
173 "${FILESDIR}/1.7.3.901-0001-dix-if-owner-events-is-true-for-passive-grabs-add-th.patch"
174 )
175
176 PATCHES=(
177 "${UPSTREAMED_PATCHES[@]}"
178 )
179
180 pkg_setup() {
181 use minimal || ensure_a_server_is_building
182
183 # SDL only available in kdrive build
184 if use kdrive && use sdl; then
185 conf_opts="${conf_opts} --enable-xsdl"
186 else
187 conf_opts="${conf_opts} --disable-xsdl"
188 fi
189
190 # localstatedir is used for the log location; we need to override the default
191 # from ebuild.sh
192 # sysconfdir is used for the xorg.conf location; same applies
193 # --enable-install-setuid needed because sparcs default off
194 CONFIGURE_OPTIONS="
195 $(use_enable ipv6)
196 $(use_enable dmx)
197 $(use_enable kdrive)
198 $(use_enable tslib)
199 $(use_enable tslib xcalibrate)
200 $(use_enable !minimal xvfb)
201 $(use_enable !minimal xnest)
202 $(use_enable !minimal record)
203 $(use_enable !minimal xfree86-utils)
204 $(use_enable !minimal install-libxf86config)
205 $(use_enable !minimal dri)
206 $(use_enable !minimal dri2)
207 $(use_enable !minimal glx)
208 $(use_enable xorg)
209 $(use_enable nptl glx-tls)
210 $(use_enable hal config-hal)
211 --sysconfdir=/etc/X11
212 --localstatedir=/var
213 --enable-install-setuid
214 --with-fontdir=/usr/share/fonts
215 --with-xkb-output=/var/lib/xkb
216 --without-dtrace
217 ${conf_opts}"
218
219 # (#121394) Causes window corruption
220 filter-flags -fweb
221
222 # Incompatible with GCC 3.x SSP on x86, bug #244352
223 if use x86 ; then
224 if [[ $(gcc-major-version) -lt 4 ]]; then
225 filter-flags -fstack-protector
226 fi
227 fi
228
229 OLD_IMPLEM="$(eselect opengl show)"
230 eselect opengl set ${OPENGL_DIR}
231 }
232
233 src_install() {
234 x-modular_src_install
235
236 dynamic_libgl_install
237
238 server_based_install
239
240 if ! use minimal && use xorg; then
241 # Install xorg.conf.example (see bugs #151421 and #151670)
242 insinto /etc/X11
243 doins hw/xfree86/xorg.conf.example \
244 || die "couldn't install xorg.conf.example"
245 fi
246 }
247
248 pkg_postinst() {
249 switch_opengl_implem
250
251 echo
252 ewarn "You must rebuild all drivers if upgrading from xorg-server 1.6"
253 ewarn "or earlier, because the ABI changed. If you cannot start X because"
254 ewarn "of module version mismatch errors, this is your problem."
255
256 echo
257 ewarn "You can generate a list of all installed packages in the x11-drivers"
258 ewarn "category using this command:"
259 ewarn "emerge portage-utils; qlist -I -C x11-drivers/"
260
261 ebeep 5
262 epause 10
263 }
264
265 pkg_postrm() {
266 # Get rid of module dir to ensure opengl-update works properly
267 if ! has_version x11-base/xorg-server; then
268 if [[ -e ${ROOT}/usr/$(get_libdir)/xorg/modules ]]; then
269 rm -rf "${ROOT}"/usr/$(get_libdir)/xorg/modules
270 fi
271 fi
272 }
273
274 dynamic_libgl_install() {
275 # next section is to setup the dynamic libGL stuff
276 ebegin "Moving GL files for dynamic switching"
277 dodir /usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
278 local x=""
279 for x in "${D}"/usr/$(get_libdir)/xorg/modules/extensions/lib{glx,dri,dri2}*; do
280 if [ -f ${x} -o -L ${x} ]; then
281 mv -f ${x} "${D}"/usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
282 fi
283 done
284 eend 0
285 }
286
287 server_based_install() {
288 if ! use xorg; then
289 rm "${D}"/usr/share/man/man1/Xserver.1x \
290 "${D}"/usr/$(get_libdir)/xserver/SecurityPolicy \
291 "${D}"/usr/$(get_libdir)/pkgconfig/xorg-server.pc \
292 "${D}"/usr/share/man/man1/Xserver.1x
293 fi
294 }
295
296 switch_opengl_implem() {
297 # Switch to the xorg implementation.
298 # Use new opengl-update that will not reset user selected
299 # OpenGL interface ...
300 echo
301 eselect opengl set ${OLD_IMPLEM}
302 }
303
304 ensure_a_server_is_building() {
305 for server in ${IUSE_SERVERS}; do
306 use ${server} && return;
307 done
308 eerror "You need to specify at least one server to build."
309 eerror "Valid servers are: ${IUSE_SERVERS}."
310 die "No servers were specified to build."
311 }
Report Message
Find on MARC Find on Google Groups