[gentoo-commits] gentoo-x86 commit in sys-apps/pcsc-lite: ChangeLog pcsc-lite-1.6.7.ebuild pcsc-lite-1.6.6-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    11/02/23 00:19:38

  Modified:             ChangeLog
  Added:                pcsc-lite-1.6.7.ebuild
  Removed:              pcsc-lite-1.6.6-r1.ebuild
  Log:
  Version bump; upstream merged my patch and made a new release. Also drop .la file.
  
  (Portage version: 2.2.0_alpha25/cvs/Linux x86_64)

Revision  Changes    Path
1.105                sys-apps/pcsc-lite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.105&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.105&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?r1=1.104&r2=1.105

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v
retrieving revision 1.104
retrieving revision 1.105
diff -u -r1.104 -r1.105
--- ChangeLog	22 Feb 2011 11:55:59 -0000	1.104
+++ ChangeLog	23 Feb 2011 00:19:38 -0000	1.105
@@ -1,6 +1,14 @@
 # ChangeLog for sys-apps/pcsc-lite
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.104 2011/02/22 11:55:59 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.105 2011/02/23 00:19:38 flameeyes Exp $
+
+*pcsc-lite-1.6.7 (23 Feb 2011)
+
+  23 Feb 2011; Diego E. Pettenò <flameeyes@g.o>
+  -pcsc-lite-1.6.6-r1.ebuild,
+  -files/pcsc-lite-1.6.6-libusb-multiinterface.patch, +pcsc-lite-1.6.7.ebuild:
+  Version bump; upstream merged my patch and made a new release. Also drop .la
+  file.
 
 *pcsc-lite-1.6.6-r1 (22 Feb 2011)
 



1.1                  sys-apps/pcsc-lite/pcsc-lite-1.6.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.6.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.6.7.ebuild?rev=1.1&content-type=text/plain

Index: pcsc-lite-1.6.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.6.7.ebuild,v 1.1 2011/02/23 00:19:38 flameeyes Exp $

EAPI="3"

inherit multilib eutils

DESCRIPTION="PC/SC Architecture smartcard middleware library"
HOMEPAGE="http://pcsclite.alioth.debian.org/"

STUPID_NUM="3516"
MY_P="${PN}-${PV/_/-}"
SRC_URI="http://alioth.debian.org/download.php/${STUPID_NUM}/${MY_P}.tar.bz2"
S="${WORKDIR}/${MY_P}"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="usb kernel_linux"

RDEPEND="usb? ( virtual/libusb:1 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"
RDEPEND="${RDEPEND}
	!<app-crypt/ccid-1.4.1-r1
	kernel_linux? ( sys-fs/udev )"

pkg_setup() {
	enewgroup pcscd
}

src_configure() {
	econf \
		--disable-maintainer-mode \
		--disable-dependency-tracking \
		--docdir="/usr/share/doc/${PF}" \
		--enable-usbdropdir="/usr/$(get_libdir)/readers/usb" \
		$(use_enable usb libusb) \
		--disable-libhal
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	find "${D}" -name '*.la' -delete

	dodoc AUTHORS DRIVERS HELP README SECURITY ChangeLog || die

	newinitd "${FILESDIR}/pcscd-init.3" pcscd || die

	if use kernel_linux; then
		insinto /lib/udev/rules.d
		doins "${FILESDIR}"/99-pcscd-hotplug.rules || die
	fi
}

pkg_postinst() {
	elog "Starting from version 1.6.5, pcsc-lite will start as user nobody in"
	elog "the pcscd group, to avoid running as root."
	elog ""
	elog "This also means you need the newest drivers available so that the"
	elog "devices get the proper owner."
	elog ""
	elog "Furthermore, a conf.d file is no longer installed by default, as"
	elog "the default configuration does not require one. If you need to"
	elog "pass further options to pcscd, create a file and set the"
	elog "EXTRA_OPTS variable."
	elog ""
	if use kernel_linux; then
		elog "HAL support has been dropped by the ebuild; if you want hotplug"
		elog "support, that's provided already by UDEV rules; you only need to"
		elog "tell the init system to hotplug it, by setting this variable in"
		elog "/etc/rc.conf:"
		elog ""
		elog "    rc_hotplug=\"pcscd\""
	fi
}