[gentoo-commits] gentoo-x86 commit in dev-python/geopy: geopy-1.3.0-r1.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     14/10/04 03:02:29

  Modified:             ChangeLog
  Added:                geopy-1.3.0-r1.ebuild
  Log:
  revbump; purge test folder from installed folders to avoid file collisions, fixes Bug #524348 by H. Jarausch
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.15                 dev-python/geopy/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/geopy/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/geopy/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/geopy/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/geopy/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	2 Oct 2014 15:40:03 -0000	1.14
+++ ChangeLog	4 Oct 2014 03:02:29 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/geopy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/geopy/ChangeLog,v 1.14 2014/10/02 15:40:03 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/geopy/ChangeLog,v 1.15 2014/10/04 03:02:29 idella4 Exp $
+
+*geopy-1.3.0-r1 (04 Oct 2014)
+
+  04 Oct 2014; Ian Delaney <idella4@g.o> +geopy-1.3.0-r1.ebuild:
+  revbump; purge test folder from installed folders to avoid file collisions,
+  fixes Bug #524348 by H. Jarausch
 
 *geopy-1.3.0 (02 Oct 2014)
 



1.1                  dev-python/geopy/geopy-1.3.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/geopy/geopy-1.3.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/geopy/geopy-1.3.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: geopy-1.3.0-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/geopy/geopy-1.3.0-r1.ebuild,v 1.1 2014/10/04 03:02:29 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit distutils-r1

DESCRIPTION="A Geocoding Toolbox for Python"
HOMEPAGE="http://www.geopy.org/ https://github.com/geopy/geopy"
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

IUSE="test doc yahoo"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"

RDEPEND="yahoo? ( >=dev-python/requests-oauthlib-0.4.0[${PYTHON_USEDEP}]
		dev-python/placefinder[${PYTHON_USEDEP}] )"
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( dev-python/nose[${PYTHON_USEDEP}]
		dev-python/nose-cover3[${PYTHON_USEDEP}]
		dev-python/pylint[${PYTHON_USEDEP}] )
	 doc? ( $(python_gen_cond_dep 'dev-python/sphinx[${PYTHON_USEDEP}]' python2_7)
		>=dev-python/python-docs-2.7.6-r1:2.7 )"

python_prepare_all() {
	if use doc; then
		local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
		local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
		local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
		local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
		sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
	fi

	distutils-r1_python_prepare_all

	# purge test folder to avoid file collisions
	sed -e "s:find_packages():find_packages(exclude=['test','test.*']):" -i setup.py || die
}

python_test() {
	# intermittent fails or errors caused by an apparent race condition. suite is fine
	# The setting --processes=-1 invokes this flaw
	nosetests || die "Tests failed under ${EPYTHON}"
}

python_compile_all() {
	use doc && emake -C docs html
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/_build/html/. )
	distutils-r1_python_install_all
}