[gentoo-commits] gentoo-x86 commit in app-editors/mg: mg-20140220.ebuild ChangeLog

[Ulrich Mueller (ulm)]

ulm         14/03/01 22:53:40

  Modified:             ChangeLog
  Added:                mg-20140220.ebuild
  Log:
  Version bump. The dev-libs/clens dependency is replaced by dev-libs/libbsd. Dropped some keywords again.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.68                 app-editors/mg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	13 Feb 2014 14:24:37 -0000	1.67
+++ ChangeLog	1 Mar 2014 22:53:40 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/mg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v 1.67 2014/02/13 14:24:37 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/ChangeLog,v 1.68 2014/03/01 22:53:40 ulm Exp $
+
+*mg-20140220 (01 Mar 2014)
+
+  01 Mar 2014; Ulrich Müller <ulm@g.o> +mg-20140220.ebuild:
+  Version bump. The dev-libs/clens dependency is replaced by dev-libs/libbsd.
+  Dropped some keywords again.
 
   13 Feb 2014; Jeroen Roovers <jer@g.o> mg-20131118.ebuild:
   Stable for HPPA (bug #501184).



1.1                  app-editors/mg/mg-20140220.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/mg-20140220.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/mg/mg-20140220.ebuild?rev=1.1&content-type=text/plain

Index: mg-20140220.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/mg/mg-20140220.ebuild,v 1.1 2014/03/01 22:53:40 ulm Exp $

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="MicroGnuEmacs, a port from the BSDs"
HOMEPAGE="http://homepage.boetes.org/software/mg/"
SRC_URI="http://homepage.boetes.org/software/mg/${P}.tar.gz"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="livecd"

RDEPEND="dev-libs/libbsd
	sys-libs/ncurses"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	epatch_user

	# remove OpenBSD specific easter egg
	sed -i -e 's/theo\.o//' GNUmakefile || die
	sed -i -e '/theo_init/d' main.c || die

	# fix path to tutorial in man page
	sed -i -e "s:doc/mg/:doc/${PF}/:" mg.1 || die
}

src_compile() {
	local pkgc=$(tc-getPKG_CONFIG)

	emake CC="$(tc-getCC)" \
		CPPFLAGS="-DFKEYS -DREGEX -DXKEYS -D__dead=__dead2 \
			$("${pkgc}" --cflags libbsd-overlay)" \
		CFLAGS="${CFLAGS}" \
		LIBS="$("${pkgc}" --libs ncurses) $("${pkgc}" --libs libbsd-overlay)"
}

src_install()  {
	einstall
	dodoc README tutorial
	# don't compress the tutorial, otherwise mg cannot open it
	docompress -x /usr/share/doc/${PF}/tutorial
}

pkg_postinst() {
	if use livecd; then
		[[ -e ${EROOT}/usr/bin/emacs ]] || ln -s mg "${EROOT}"/usr/bin/emacs
	fi
}