[gentoo-commits] gentoo-x86 commit in www-apps/wiliki: wiliki-0.6.1.ebuild metadata.xml ChangeLog

[TomAs Touceda (chiiph)]

chiiph      10/07/02 00:21:32

  Added:                wiliki-0.6.1.ebuild metadata.xml ChangeLog
  Log:
  WiLiKi initial commit. Thanks to vadimk
  (Portage version: 2.2_rc67/cvs/Linux i686)

Revision  Changes    Path
1.1                  www-apps/wiliki/wiliki-0.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/wiliki/wiliki-0.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/wiliki/wiliki-0.6.1.ebuild?rev=1.1&content-type=text/plain

Index: wiliki-0.6.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/wiliki/wiliki-0.6.1.ebuild,v 1.1 2010/07/02 00:21:32 chiiph Exp $

EAPI="3"

inherit webapp eutils

MY_PN="WiLiKi"
MY_P=${MY_PN}-${PV}

DESCRIPTION="WiLiKi is a lightweight Wiki engine written in and running on Gauche Scheme."
HOMEPAGE="http://practical-scheme.net/wiliki/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tgz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cgi fastcgi"

DEPEND="dev-scheme/gauche
	cgi? ( virtual/httpd-cgi )
	fastcgi? ( virtual/httpd-fastcgi )"
RDEPEND="${DEPEND}"

need_httpd_cgi

WEBAPP_MANUAL_SLOT="yes"

S="${WORKDIR}"/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-po-gentoo.patch
	epatch "${FILESDIR}"/${P}-cgi-gentoo.patch
}

src_install() {
	webapp_src_preinst
	emake DESTDIR="${D}" install || die "Install failed"

	insinto "${MY_CGIBINDIR}"
	doins -r src/wiliki.cgi src/wiliki2.cgi || die "doins failed"
	fperms +x "${MY_CGIBINDIR}"/wiliki.cgi || die "fperms failed"

	insinto "${MY_HTDOCSDIR}"
	doins src/wiliki.css src/wiliki2.css || die "doins failed"

	dodir "${MY_HOSTROOTDIR}"/${PF}/data || die "dodir failed"
	webapp_serverowned "${MY_HOSTROOTDIR}"/${PF}/data

	webapp_src_install
}

pkg_postinst() {
	einfo
	einfo "Quickstart:"
	einfo "	modify wiliki.cgi to customize the WiLiKi's behavior"
	einfo "	modify wiliki.css to customize the WiLiKi's look"
	einfo
	einfo " http://localhost/cgi-bin/wiliki.cgi"
	einfo

	webapp_pkg_postinst
}



1.1                  www-apps/wiliki/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/wiliki/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/wiliki/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>scheme</herd>
	<longdescription>
	WiLiKi is a lightweight Wiki Engine written in Scheme.

	WiLiKi is yet another Wiki-clone suitable for intra-net collaborative work
	in multilingual environment. The features include multiple back-end
	databases, permission and version control, and easy access from other
	programs.

	http://practical-scheme.net/wiliki/
	</longdescription>
</pkgmetadata>



1.1                  www-apps/wiliki/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/wiliki/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/wiliki/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for www-apps/wiliki
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/wiliki/ChangeLog,v 1.1 2010/07/02 00:21:32 chiiph Exp $

*wiliki-0.6.1 (02 Jul 2010)

  02 Jul 2010; Tomas Touceda <chiiph@g.o> +wiliki-0.6.1.ebuild,
  +files/wiliki-0.6.1-cgi-gentoo.patch, +files/wiliki-po-gentoo.patch,
  +metadata.xml:
  WiLiKi initial commit. Thanks to vadimk