[gentoo-commits] gentoo-x86 commit in app-mobilephone/bitpim: ChangeLog bitpim-1.0.6-r1.ebuild bitpim-1.0.6.ebuild

[Alin Nastac (mrness)]

mrness      09/06/20 21:39:29

  Modified:             ChangeLog
  Added:                bitpim-1.0.6-r1.ebuild
  Removed:              bitpim-1.0.6.ebuild
  Log:
  Migrate to EAPI 2. Update libusb dependency atom (#270039).
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.28                 app-mobilephone/bitpim/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/bitpim/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/bitpim/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/bitpim/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/bitpim/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	2 Nov 2008 18:13:30 -0000	1.27
+++ ChangeLog	20 Jun 2009 21:39:29 -0000	1.28
@@ -1,6 +1,12 @@
 # ChangeLog for app-mobilephone/bitpim
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/bitpim/ChangeLog,v 1.27 2008/11/02 18:13:30 mrness Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/bitpim/ChangeLog,v 1.28 2009/06/20 21:39:29 mrness Exp $
+
+*bitpim-1.0.6-r1 (20 Jun 2009)
+
+  20 Jun 2009; Alin Năstac <mrness@g.o> -bitpim-1.0.6.ebuild,
+  +bitpim-1.0.6-r1.ebuild:
+  Migrate to EAPI 2. Update libusb dependency atom (#270039).
 
 *bitpim-1.0.6 (02 Nov 2008)
 



1.1                  app-mobilephone/bitpim/bitpim-1.0.6-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/bitpim/bitpim-1.0.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/bitpim/bitpim-1.0.6-r1.ebuild?rev=1.1&content-type=text/plain

Index: bitpim-1.0.6-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/bitpim/bitpim-1.0.6-r1.ebuild,v 1.1 2009/06/20 21:39:29 mrness Exp $

EAPI="2"

inherit distutils fdo-mime multilib

DESCRIPTION="Program to view and manipulate data on LG VX4400/VX6000 and many Sanyo Sprint mobile phones"
HOMEPAGE="http://www.bitpim.org/"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# this needs fixing
#KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="crypt evo usb"

COMMON_DEPEND="=dev-python/wxpython-2.8*
	dev-python/python-dsv
	dev-python/pyserial
	dev-python/apsw
	crypt? ( >=dev-python/paramiko-1.7.1
		dev-python/pycrypto )
	usb? ( dev-libs/libusb:0 )"
DEPEND="${COMMON_DEPEND}
	usb? ( dev-lang/swig )"
RDEPEND="${COMMON_DEPEND}
	media-video/ffmpeg
	media-libs/netpbm
	>=dev-lang/python-2.5"

src_prepare() {
	epatch "${FILESDIR}/${P}-gentoo.patch"
	epatch "${FILESDIR}/${P}-ffmpeg_quality.patch"
	epatch "${FILESDIR}/${P}-gcc43.patch"
	sed -i "s/python2.3/${python}/" "${S}/src/native/usb/build.sh"
}

src_compile() {
	# USB stuff
	if use usb; then
	    cd "${S}/src/native/usb"
	    sh ./build.sh || die "compilation of native/usb failed"
	fi

	# strings
	cd "${S}/src/native/strings"
	${python} setup.py build || die "compilation of native/strings failed"

	# bmp2avi
	cd "${S}/src/native/av/bmp2avi"
	PLATFORM=linux make || die "compilation of native/bmp2avi failed"
}

src_install() {

	# Install files into right place
	#
	# BitPim is a self-contained app, so jamming it into
	# Python's site-packages might not be worthwhile.  We'll
	# Put it in its own home, and add the PYTHONPATH in the
	# wrapper executables below.
	distutils_python_version
	local RLOC=/usr/$(get_libdir)/${P}

	# Main Python source
	insinto ${RLOC}
	doins src/*.py

	# Phone specifics
	insinto ${RLOC}/phones
	doins src/phones/*.py

	# Native products
	insinto ${RLOC}/native
	doins src/native/*.py
	insinto ${RLOC}/native/qtopiadesktop
	doins src/native/qtopiadesktop/*.py
	insinto ${RLOC}/native/outlook
	doins src/native/outlook/*.py
	insinto ${RLOC}/native/egroupware
	doins src/native/egroupware/*.py
	if use evo ; then
		insinto ${RLOC}/native/evolution
		doins src/native/evolution/*.py
	fi

	# strings
	cd "${S}/src/native/strings"
	${python} setup.py install --root="${D}" --no-compile "$@" \
	    || die "install of native/strings failed"

	cd "${S}"
	insinto $RLOC/native/strings
	doins src/native/strings/__init__.py src/native/strings/jarowpy.py

	# usb
	if use usb; then
		insinto ${RLOC}/native/usb
		doins src/native/usb/*.py
		doins src/native/usb/*.so
	fi

	# Helpers and resources
	dobin src/native/av/bmp2avi/bmp2avi
	insinto ${RLOC}/resources
	doins resources/*

	# Bitfling
	if use crypt; then
		FLINGDIR="${RLOC}/bitfling"
		insinto $FLINGDIR
		cd "${S}/src/bitfling"
		doins *.py
		cd "${S}"
	fi

	# Creating scripts
	echo '#!/bin/sh' > "${T}/bitpim"
	echo "exec ${python} ${RLOC}/bp.py \"\$@\"" >> "${T}/bitpim"
	dobin "${T}/bitpim"
	if use crypt; then
		echo '#!/bin/sh' > "${T}/bitfling"
		echo "exec ${python} ${RLOC}/bp.py \"\$@\" bitfling" >> "${T}/bitfling"
		dobin "${T}/bitfling"
	fi

	# Desktop file
	insinto /usr/share/applications
	sed -i -e "s|%%INSTALLBINDIR%%|/usr/bin|" -e "s|%%INSTALLLIBDIR%%|${RLOC}|" \
		packaging/bitpim.desktop
	doins packaging/bitpim.desktop
}

pkg_postinst() {
	# Optimize in installed directory
	python_mod_optimize /usr/$(get_libdir)/${P}
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/${P}
	fdo-mime_desktop_database_update
}