[gentoo-commits] gentoo-x86 commit in dev-ruby/faraday: ChangeLog faraday-0.9.1.ebuild

[Hans de Graaff (graaff)]

graaff      15/03/03 06:54:41

  Modified:             ChangeLog
  Added:                faraday-0.9.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

Revision  Changes    Path
1.25                 dev-ruby/faraday/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/faraday/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/faraday/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/faraday/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/faraday/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	3 Jan 2015 01:16:00 -0000	1.24
+++ ChangeLog	3 Mar 2015 06:54:41 -0000	1.25
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/faraday
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/faraday/ChangeLog,v 1.24 2015/01/03 01:16:00 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/faraday/ChangeLog,v 1.25 2015/03/03 06:54:41 graaff Exp $
+
+*faraday-0.9.1 (03 Mar 2015)
+
+  03 Mar 2015; Hans de Graaff <graaff@g.o> +faraday-0.9.1.ebuild:
+  Version bump.
 
   03 Jan 2015; Manuel Rüger <mrueg@g.o>
   -files/faraday-0.4.5-gentoo.patch:



1.1                  dev-ruby/faraday/faraday-0.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/faraday/faraday-0.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/faraday/faraday-0.9.1.ebuild?rev=1.1&content-type=text/plain

Index: faraday-0.9.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/faraday/faraday-0.9.1.ebuild,v 1.1 2015/03/03 06:54:41 graaff Exp $

EAPI=5

USE_RUBY="ruby19 ruby20 ruby21"

RUBY_FAKEGEM_TASK_TEST="test"
RUBY_FAKEGEM_TASK_DOC=""

RUBY_FAKEGEM_EXTRADOC="README.md"

RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"

inherit ruby-fakegem eutils

DESCRIPTION="HTTP/REST API client library with pluggable components"
HOMEPAGE="http://github.com/lostisland/faraday"
SRC_URI="https://github.com/lostisland/faraday/archive/v${PV}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE=""

DEPEND+=" test? ( sys-process/lsof )"

ruby_add_rdepend ">=dev-ruby/multipart-post-1.2.0 <dev-ruby/multipart-post-3"
ruby_add_bdepend "test? (
		>=dev-ruby/test-unit-2.4
		dev-ruby/sinatra
		dev-ruby/net-http-persistent
		dev-ruby/patron
	)"

all_ruby_prepare() {
	# Remove bundler support.
	rm Gemfile || die
	sed -i -e '/[Bb]undler/d' Rakefile test/helper.rb || die
	sed -i -e '/bundler/,/^fi/ s:^:#:' script/test || die

	# Remove simplecov and coveralls support, not needed to run tests.
	sed -i -e '/simplecov/,/^  end/ s:^:#:' test/helper.rb || die

	# Remove tests for adapters that are not packaged for Gentoo.
	rm test/adapters/em_http_test.rb test/adapters/em_synchrony_test.rb test/adapters/excon_test.rb test/adapters/typhoeus_test.rb || die
}

each_ruby_prepare() {
	# Make sure the test scripts use the right ruby interpreter
	sed -i -e 's:ruby:'${RUBY}':' script/* || die
}

each_ruby_test() {
	each_fakegem_test

	# Sleep some time to allow the sinatra test server to die
	einfo "Waiting for test server to stop"
	sleep 10
}