[gentoo-commits] gentoo-x86 commit in dev-util/glade: glade-3.18.3.ebuild glade-3.8.5.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/05/31 06:04:50

  Modified:             ChangeLog
  Added:                glade-3.18.3.ebuild glade-3.8.5.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.215                dev-util/glade/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/ChangeLog?rev=1.215&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/ChangeLog?rev=1.215&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/ChangeLog?r1=1.214&r2=1.215

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v
retrieving revision 1.214
retrieving revision 1.215
diff -u -r1.214 -r1.215
--- ChangeLog	2 May 2014 08:45:51 -0000	1.214
+++ ChangeLog	31 May 2014 06:04:50 -0000	1.215
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/glade
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.214 2014/05/02 08:45:51 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/ChangeLog,v 1.215 2014/05/31 06:04:50 pacho Exp $
+
+*glade-3.8.5 (31 May 2014)
+*glade-3.18.3 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@g.o> +glade-3.18.3.ebuild,
+  +glade-3.8.5.ebuild:
+  Version bump
 
   02 May 2014; Pacho Ramos <pacho@g.o> glade-3.16.1.ebuild,
   glade-3.18.2.ebuild, glade-3.8.4.ebuild:



1.1                  dev-util/glade/glade-3.18.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/glade-3.18.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/glade-3.18.3.ebuild?rev=1.1&content-type=text/plain

Index: glade-3.18.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.18.3.ebuild,v 1.1 2014/05/31 06:04:50 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 )

inherit autotools eutils gnome2 python-single-r1 versionator virtualx

DESCRIPTION="A user interface designer for GTK+ and GNOME"
HOMEPAGE="http://glade.gnome.org/"

LICENSE="GPL-2+ FDL-1.1+"
SLOT="3.10/6" # subslot = suffix of libgladeui-2.so
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="+introspection python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

RDEPEND="
	dev-libs/atk[introspection?]
	>=dev-libs/glib-2.32:2
	>=dev-libs/libxml2-2.4.0:2
	x11-libs/cairo:=
	x11-libs/gdk-pixbuf:2[introspection?]
	>=x11-libs/gtk+-3.12:3[introspection?]
	x11-libs/pango[introspection?]
	introspection? ( >=dev-libs/gobject-introspection-1.32 )
	python? (
		${PYTHON_DEPS}
		>=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}] )
"
DEPEND="${RDEPEND}
	app-text/docbook-xml-dtd:4.1.2
	app-text/yelp-tools
	dev-libs/libxslt
	>=dev-util/gtk-doc-am-1.13
	>=dev-util/intltool-0.41.0
	virtual/pkgconfig

	dev-libs/gobject-introspection-common
	gnome-base/gnome-common
"
# eautoreconf requires:
#	dev-libs/gobject-introspection-common
#	gnome-base/gnome-common

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_prepare() {
	# To avoid file collison with other slots, rename help module.
	# Prevent the UI from loading glade:3's gladeui devhelp documentation.
	epatch "${FILESDIR}"/${PN}-3.14.1-doc-version.patch

	# https://bugzilla.gnome.org/show_bug.cgi?id=724104
	epatch"${FILESDIR}"/${PN}-3.16.1-underlinking.patch

	eautoreconf

	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		--disable-static \
		--enable-gladeui \
		--enable-libtool-lock \
		$(use_enable introspection) \
		$(use_enable python) \
		ITSTOOL=$(type -P true)
}

src_test() {
	Xemake check
}

src_install() {
	# modify Name in .desktop file to avoid confusion with other slots
	sed -e 's:^\(Name.*=Glade\):\1 '$(get_version_component_range 1-2): \
		-i data/glade.desktop || die "sed of data/glade.desktop failed"
	# modify name in .devhelp2 file to avoid shadowing with glade:3 docs
	sed -e 's:name="gladeui":name="gladeui-2":' \
		-i doc/html/gladeui.devhelp2 || die "sed of gladeui.devhelp2 failed"
	gnome2_src_install
}

pkg_postinst() {
	gnome2_pkg_postinst
	if ! has_version dev-util/devhelp ; then
		elog "You may want to install dev-util/devhelp for integration API"
		elog "documentation support."
	fi
}



1.1                  dev-util/glade/glade-3.8.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/glade-3.8.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/glade/glade-3.8.5.ebuild?rev=1.1&content-type=text/plain

Index: glade-3.8.5.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/glade/glade-3.8.5.ebuild,v 1.1 2014/05/31 06:04:50 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"
GNOME_ORG_MODULE="glade3"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_{6,7} )

inherit eutils gnome2 python-single-r1

DESCRIPTION="A user interface designer for GTK+ and GNOME"
HOMEPAGE="http://glade.gnome.org/"

LICENSE="GPL-2+ FDL-1.1+"
SLOT="3/11" # subslot = suffix of libgladeui-1.so
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="gnome python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

RDEPEND="
	>=dev-libs/glib-2.8:2
	>=x11-libs/gtk+-2.24:2
	>=dev-libs/libxml2-2.4:2
	gnome?	(
		>=gnome-base/libgnomeui-2
		>=gnome-base/libbonoboui-2 )
	python? (
		${PYTHON_DEPS}
		>=dev-python/pygtk-2.10:2 )
"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	>=dev-util/intltool-0.35
	virtual/pkgconfig
	sys-devel/gettext
	app-text/scrollkeeper
	>=app-text/gnome-doc-utils-0.9
	app-text/docbook-xml-dtd:4.1.2
"

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_configure() {
	gnome2_src_configure \
		--enable-libtool-lock \
		$(use_enable gnome) \
		$(use_enable python)
}