[gentoo-commits] gentoo-x86 commit in dev-libs/libpwquality: libpwquality-1.2.0-r2.ebuild ChangeLog libpwquality-1.2.0.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/12/29 19:29:15

  Modified:             ChangeLog
  Added:                libpwquality-1.2.0-r2.ebuild
  Removed:              libpwquality-1.2.0.ebuild
  Log:
  Do not install static library in /lib (bug #449224, thanks to BillWho). Update to python-r1.eclass.
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

Revision  Changes    Path
1.4                  dev-libs/libpwquality/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpwquality/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpwquality/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpwquality/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	5 Dec 2012 08:54:27 -0000	1.3
+++ ChangeLog	29 Dec 2012 19:29:15 -0000	1.4
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/libpwquality
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/ChangeLog,v 1.3 2012/12/05 08:54:27 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/ChangeLog,v 1.4 2012/12/29 19:29:15 tetromino Exp $
+
+*libpwquality-1.2.0-r2 (29 Dec 2012)
+
+  29 Dec 2012; Alexandre Rostovtsev <tetromino@g.o>
+  -libpwquality-1.2.0.ebuild, +libpwquality-1.2.0-r2.ebuild:
+  Do not install static library in /lib (bug #449224, thanks to BillWho).
+  Update to python-r1.eclass. Drop old.
 
 *libpwquality-1.2.0-r1 (05 Dec 2012)
 



1.1                  dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: libpwquality-1.2.0-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libpwquality/libpwquality-1.2.0-r2.ebuild,v 1.1 2012/12/29 19:29:15 tetromino Exp $

EAPI="5"
PYTHON_COMPAT=( python2_7 )

inherit eutils multilib pam python-r1 toolchain-funcs

DESCRIPTION="Library for password quality checking and generating random passwords"
HOMEPAGE="https://fedorahosted.org/libpwquality/"
SRC_URI="https://fedorahosted.org/releases/l/i/${PN}/${P}.tar.bz2"

LICENSE="|| ( BSD GPL-2 )"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pam python static-libs"

RDEPEND=">=sys-libs/cracklib-2.8:=
	pam? ( virtual/pam )
	python? ( ${PYTHON_DEPS} )"
DEPEND="${RDEPEND}
	sys-devel/libtool
	virtual/pkgconfig"

src_prepare() {
	# ensure pkgconfig files go in /usr
	sed -e 's:\(pkgconfigdir *=\).*:\1 '${EPREFIX}/usr/$(get_libdir)'/pkgconfig:' \
		-i src/Makefile.{am,in} || die "sed failed"
	use python && python_copy_sources
}

src_configure() {
	# Install library in /lib for pam
	configuring() {
		local sitedir
		econf \
			--libdir="${EPREFIX}/$(get_libdir)" \
			$(use_enable pam) \
			--with-securedir="${EPREFIX}/$(getpam_mod_dir)" \
			$(use_enable python python-bindings) \
			$(usex python "--with-pythonsitedir=$(use python && python_get_sitedir)" "") \
			$(use_enable static-libs static)
	}
	if_use_python_python_foreach_impl configuring
}

src_compile() {
	if_use_python_python_foreach_impl default
}

src_test() {
	if_use_python_python_foreach_impl default
}

src_install() {
	if_use_python_python_foreach_impl default
	if use static-libs; then
		# Do not install static libs in /lib
		mkdir -p "${ED}usr/$(get_libdir)"
		mv "${ED}$(get_libdir)/libpwquality.a" "${ED}/usr/$(get_libdir)/" || die
		gen_usr_ldscript libpwquality.so
	fi
	prune_libtool_files --modules
}

if_use_python_python_foreach_impl() {
	run_in_build_dir() {
		pushd "${BUILD_DIR}" > /dev/null || die
		"$@"
		popd > /dev/null
	}

	if use python; then
		python_foreach_impl run_in_build_dir "$@"
	else
		"$@"
	fi
}